vba in allen Blättern ausführen

[ari-2001]

Hallo nocheinmal,

ich habe eine Datei mit vielen Blättern.
In jedem Blatt soll in Spalte A aus dem bestehenden Text der Textteil "Montag" entfernt werden.

Wie schaffe ich es mit einem Makro, dass das  Makro nacheinander alle Blätter abarbeitet?

Ich habe zwar etwas geschrieben, aber das löscht mir immer nur aus dem Blatt, auf dem ich es grade ausführe.

Hier der Code:

Sub Montag()
Dim ws As Worksheet
For Each ws In Worksheets
  If ws.Index > 0 Then
            Columns("A:A").Select
    Selection.Replace What:=" Montag", Replacement:="", LookAt:=xlPart, _
        SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
        ReplaceFormat:=False
  End If
Next
End Sub



Wo habe ich den Fehler gemacht?

Vielen Dank im Voraus.

Grüße
Andreas

[Klaus-Dieter]

Hallo,

versuche es mal so:

Code:

Option Explicit

Sub Montag()
Dim ws As Worksheet
For Each ws In Worksheets
  If ws.Index > 0 Then
            Sheets(ws.Name).Range("A2:A" & Sheets(ws.Name).Range("A" & Rows.Count).End(xlUp).Row).Replace What:="Montag", Replacement:="", LookAt:=xlPart, _
        SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
        ReplaceFormat:=False
  End If
Next
End Sub

Hinweis: die Select-Anweisung ist überflüssig. Es ist nicht so optimal, ganze Spalten abzuarbeiten.

[RPP63]

Moin!
Zunächst mal beginnt der Index der Worksheets-Auflistung mit 1, so dass die If-Abfrage relativ überflüssig ist.
Der Rest ist korrekte Referenzierung:
Columns("A:A")
bezieht sich IMMER auf das aktuelle Sheet
Ws.Columns("A:A")
ist richtig!
Obwohl Klaus-Dieter schon geantwortet hat:

Code:

Sub Montag()
Dim ws As Worksheet
For Each ws In Worksheets
  ws.Columns("A").Replace " Montag", "", LookAt:=xlPart
Next
End Sub

Gruß Ralf

[ari-2001]

Vielen lieben Dank,

funktioniert wie verrückt!

Kann man noch sagen, dass er ALLE Tabellenblätter bis auf das Tabellenblatt "Abrechnung" bearbeitet?

Vielen lieben Dank im Voraus!

Andreas

[ari-2001]

Habe es hinbekommen:

Sub SchultageEntfernen()
Dim ws As Worksheet
For Each ws In Worksheets
 If ws.Name <> "Auswertung" Then
  ws.Columns("A").Replace " S/S", "", LookAt:=xlPart
  ws.Columns("A").Replace " F/F", "", LookAt:=xlPart
 End If
Next
End Sub


Vielen lieben Dank an alle!

Gruß
Andreas