summwenns funktion mit zwei Bedingungen plus WENN-Bedingung

[halihalöle]

Hallo zusammen,
ich bin schon länger am probieren, aber komme leider nicht auf die finale Lösung.

Im Anhang die Beispiel-Excel.

Mit einer Formel sollen die gelb-markierten Zellen ausgefüllt werden, die Tabelle rechts muss dafür genutzt werden.
Die Tabelle unten mit den grün-markierten Zellen zeigt die Lösung/Soll-Bild.

Es soll für jeden der drei Status (Neu / In Progress / Resolved) die Anzahl der Tickets je Thema (1 bis 5) aufsummiert werden. Falls in der rechten Tabelle die Zelle in "Anzahl Tickets" leer ist, soll "8" addiert werden. Diese letzte Bedingung bekomme ich aber nicht hin bzw. eingebettet in meine bisherige Formel. Hier meine Formel für die Zelle B1 soweit:
=SUMMEWENNS($I$2:$I$10;$G$2:$G$10;$A2;$H$2:$H$10;B$1)
Hier fehlt mir dann aber noch die Bedingung, dass wenn "Anzahl Tickets" leer ist, noch "8" addiert werden soll. Ergebnis sollte also 17 statt 9 für Zelle B1 sein.

Vielen Dank vorab!

[steve1da]

Hola,
und wenn du einfach ab J2 eine Hilfspalte nutzt:
=WENN(I2="";8;I2)
Und diese dann als Summenbereich einsetzt?
Gruß,
steve1da

[halihalöle]

Hallo steve1da,
würde ich sehr ungern machen.

• in Original ist die rechte Tabelle ein Excel-Export, den ich in regelmäßigen Abständen machen muss. Würde bedeuten ich muss dann immer diese Hilfsspalte einfügen.
  
• Der Excel-Export bzw. die Tabelle hat in Original noch mehr "Status" und bei denen muss ich nicht die "8" ergänzen (aber das würde ja noch einfach umzusetzen sein).
  

VG Tobias

[steve1da]

Code:

=SUMMENPRODUKT(($G$2:$G$10=$A2)*($H$2:$H$10=B$1)*(WENN($I$2:$I$10="";8;$I$2:$I$10)))

Kann sein dass du die Formel in deiner Version mit Strg-Shift-Enter anstatt nur Enter abschließen musst.

[halihalöle]

Das ist die Formel steve1da - Klasse!
Hatte auch schon mit SUMMENPRODUKT etwas ausprobiert, aber auch nicht hinbekommen, vielen Dank!

[slowboarder]

Hi
wenn mit Summenprodukt und Wenn wie von SF gezeigt, dann in deiner Excelversion mit Matrixformelabschluss STRG+SHIFT+ENTER.
das Summenprodukt allein würde ohne funktionieren, aber das WENN macht ihn erforderlich.

alternativ gibt es auch noch folgende Möglichkeiten:
a) die Leerzellen seperat zählen und die Anzahl mit 8 multiplizieren:

Code:

=SUMMEWENNS($I$2:$I$10;$G$2:$G$10;$A2;$H$2:$H$10;B$1)
+ZÄHLENWENNS($I$2:$I$10;"";$G$2:$G$10;$A2;$H$2:$H$10;B$1)*8

b) ein Summenprodukt ohne wenn (Achtung, funktioniert nur mit echten Leerzellen in Spalte I, nicht mit einem Formelergebnis "")

Code:

=SUMMENPRODUKT(($G$2:$G$10=$A2)*($H$2:$H$10=B$1);8*($I$2:$I$10="")+$I$2:$I$10)

Gruß Daniel