Dieses Forum nutzt Cookies
Dieses Forum verwendet Cookies, um deine Login-Informationen zu speichern, wenn du registriert bist, und deinen letzten Besuch, wenn du es nicht bist. Cookies sind kleine Textdokumente, die auf deinem Computer gespeichert werden. Die von diesem Forum gesetzten Cookies werden nur auf dieser Website verwendet und stellen kein Sicherheitsrisiko dar. Cookies aus diesem Forum speichern auch die spezifischen Themen, die du gelesen hast und wann du zum letzten Mal gelesen hast. Bitte bestätige, ob du diese Cookies akzeptierst oder ablehnst.

Ein Cookie wird in deinem Browser unabhängig von der Wahl gespeichert, um zu verhindern, dass dir diese Frage erneut gestellt wird. Du kannst deine Cookie-Einstellungen jederzeit über den Link in der Fußzeile ändern.

suche Formellösung
#1
Hallo Forum,

ich habe eine Tabelle mit mehrfachvorkommenden Artikeln in SpalteA deneben in SpalteB steht das Lieferdatum dazu.
Nun suche ich eine Möglichkeit das Lieferdatum zu einen Artikel daneben im den nächsten Spalten(zellen) anzuzeigen,
läst sich das mit einer Formel lösen?
Eine Beispiel Mappe findet Ihr im Anhang.

Besten Dank im Voraus
omron2003


Angehängte Dateien
.xlsx   Demo05.10.22.xlsx (Größe: 8,4 KB / Downloads: 16)
Antworten Top
#2
Hi,

für E3:

Code:
=WENNFEHLER(INDEX($B:$B;AGGREGAT(15;6;ZEILE($A$1:$A$500)/($A$1:$A$500=$D3);SPALTE(A1)));"")


Dann nach rechts und nach unten tiehen.

CU
Oberon
Antworten Top
#3
Hi,

Code:
=WENNFEHLER(INDEX($B:$B;AGGREGAT(15;6;ZEILE($A$1:$A$999)/($A$1:$A$999=$D3);SPALTE(A$1)));"")

in E3, nach rechts und unten ziehen!
Gruß

Edgar

Meine Antworten sind freiwillig und ohne Gewähr!
Über Rückmeldungen würde ich mich freuen.
Antworten Top
#4
Hi,

für alle mit aktuellem Excel geht es auch einfacher:
Code:
=MTRANS(FILTER($B$3:$B$14;$A$3:$A$14=D3))
Hier braucht man nicht nach rechts zu ziehen. Runter ziehen reicht.
Gruß,
Helmut

Win10 - Office365 / MacOS - Office365
Antworten Top
#5
Neues Excel! Hier zusätzlich auch ohne Runterziehen, also volldynamisch:

D3: =LET(aa;A3:B14;nn;EINDEUTIG(INDEX(aa;;1));HSTAPELN(nn;
WENNFEHLER(--GLÄTTEN(TEIL(WECHSELN(
NACHZEILE(nn;LAMBDA(a;TEXTVERKETTEN(" ";;WENN(INDEX(aa;;1)=a;INDEX(aa;;2);""))))
;" ";WIEDERHOLEN(" ";599));SEQUENZ(;50;1;599);599));"")))


Die Parameterkonstanten hier (änderbar):
599 = 99 Datümer (6 Zeichen inkl. Leerzeichen) pro Artikel
50 = 50 Datümer pro Artikel (limitierend)

Die fetten multipliziert dürfen maximal 32767 ergeben!

Die Limitation (73, wegen 73^2*6) kann dann wegfallen, wenn das GLÄWEXWDH durch NACHSPALTE...TEXTTEILEN ersetzt werden kann.

Wenn man statt GLÄWEXWDH nur TEIL verwendet, sind 32767/5 = 6553 Datümer nach dem 17.05.1927 (=9999) und vor dem 14.10.2173 (=100000) möglich:
D3: =LET(aa;A3:B14;nn;EINDEUTIG(INDEX(aa;;1));HSTAPELN(nn;
WENNFEHLER(--GLÄTTEN(TEIL(
NACHZEILE(nn;LAMBDA(a;TEXTVERKETTEN("";;WENN(INDEX(aa;;1)=a;INDEX(aa;;2);""))));
SEQUENZ(;6553;1;5);5));"")))
WIN/MSO schicken angeblich alle 5 Sekunden Deinen Screen heim zu Papa (recall-Klausel). 
Antworten Top
#6
Hallo,

Super Danke an alle!

mit dieser Formel habe ich es unter Excel2013 hin bekommen.
Code:
=WENNFEHLER(INDEX($B:$B;AGGREGAT(15;6;ZEILE($A$1:$A$999)/($A$1:$A$999=$D3);SPALTE(A$1)));"")

Nochmals besten Dank
LG omron2003
Antworten Top


Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste