mehrere gleiche zeilen mit verschiedenen zugehörigen Spalten sotieren

[Miika]

Hallo,

Ich habe trotz ewigem Probieren folgendes Problem: :s

So sieht meine Liste in etwa aus...

A         B         C        D
xxx      a
xxx                b
xxx                           c
yyy     a
yyy                           c
zzz      a
zzz                b
zzz                           c

Die anzahl der gleichen Zeilen kann varieren (1-5)

Und so sollte es aussehen:

xxx     a        b           c
yyy               b           c
zzz     a         b           c

Kann mir jemand helfen?

Viele Grüße
Miika

[BoskoBiati]

Hallo,

entweder so:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G	H	I	J
1	Name	Spalte1	Spalte2	Spalte3
2	xxx	a			1	a	xxx	a	b	c
3	xxx		b		1	b	yyy	a	c
4	xxx			c	1	c	zzz	a	b	c
5	yyy	a			2	a
6	yyy			c	2	c
7	zzz	a			3	a
8	zzz		b		3	b
9	zzz			c	3	c

Zelle	Formel
E2	=WENN(ZÄHLENWENN($A$1:A2;A2)=1;MAX($E$1:E1)+1;SVERWEIS(A2;A:E;6;0))
F2	=VERWEIS(9;1/(B2:D2<>"");B2:D2)
G2	=WENNFEHLER(INDEX(A:A;VERGLEICH(ZEILE(A1);E:E;0));"")
H2	=WENN((SPALTE(A1)>ZÄHLENWENN($A:$A;$G2))+($G2="");"";INDEX($F:$F;AGGREGAT(15;6;ZEILE($A$1:$A$10)/($E$1:$E$10=ZEILE(A1));SPALTE(A1))))
I2	=WENN((SPALTE(B1)>ZÄHLENWENN($A:$A;$G2))+($G2="");"";INDEX($F:$F;AGGREGAT(15;6;ZEILE($A$1:$A$10)/($E$1:$E$10=ZEILE(B1));SPALTE(B1))))
J2	=WENN((SPALTE(C1)>ZÄHLENWENN($A:$A;$G2))+($G2="");"";INDEX($F:$F;AGGREGAT(15;6;ZEILE($A$1:$A$10)/($E$1:$E$10=ZEILE(C1));SPALTE(C1))))

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

oder so:

Arbeitsblatt mit dem Namen 'Tabelle2'
	A	B	C	D	E	F	G	H	I	J
1	Name	Spalte1	Spalte2	Spalte3
2	xxx	a			1		xxx	a	b	c
3	xxx		b		1		yyy	a		c
4	xxx			c	1		zzz	a	b	c
5	yyy	a			2
6	yyy			c	2
7	zzz	a			3
8	zzz		b		3
9	zzz			c	3

Zelle	Formel
E2	=WENN(ZÄHLENWENN($A$1:A2;A2)=1;MAX($E$1:E1)+1;SVERWEIS(A2;A:E;6;0))
G2	=WENNFEHLER(INDEX(A:A;VERGLEICH(ZEILE(A1);E:E;0));"")
H2	=WENNFEHLER(INDEX($B$1:$D$12;AGGREGAT(15;6;ZEILE($A$2:$A$12)/($A$2:$A$12=$G2)/(B$2:B$12<>"");1);SPALTE(A1));"")
I2	=WENNFEHLER(INDEX($B$1:$D$12;AGGREGAT(15;6;ZEILE($A$2:$A$12)/($A$2:$A$12=$G2)/(C$2:C$12<>"");1);SPALTE(B1));"")
J2	=WENNFEHLER(INDEX($B$1:$D$12;AGGREGAT(15;6;ZEILE($A$2:$A$12)/($A$2:$A$12=$G2)/(D$2:D$12<>"");1);SPALTE(C1));"")

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[BoskoBiati]

gelöscht, doppelt!