grafik einfügen wenn dropdown ausgewählt wird

[speckman2003]

moin,
wie kann ich eine grafik an einer bestimmten stelle eins arbeitsblattes automatisch einfügen, wenn ich auf einem anderen arbeitsblatt ein dropdownmenü nutze?

[Klaus-Dieter]

Hallo,

sicher kann man das mit einem Makro lösen. Für einen konkreten Vorschlag müsstest du aber schon etwas mehr über deine Datei verraten.

[UweD]

Hallo

meine Annahme
Bild soll in Tabelle1
Dropdownfeld ist auf Tabelle2 in A1

- Rechtsclick auf den Tabellenblattreiter von Tabelle2
- Code anzeigen
- Rechts das hier rein kopieren

Code:

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim Pfad As String, Ext As String, TB As Worksheet, Dateiname As String
    Dim QuellZelle As Range, ZielZelle As Range, BildLinks As Double, BildOben As Double
    Pfad = "E:\Temp\"
    Ext = ".jpg"
   
    Set QuellZelle = Me.Range("A1")
   
    Set TB = Sheets("Tabelle1")
    Set ZielZelle = TB.Range("B2") ' Beispiel: Bild wird in Zelle B2 eingefügt
   
    If Not Intersect(Target, QuellZelle) Is Nothing Then
        Dateiname = Pfad & Target & Ext
       
        If Dir(Dateiname) <> "" Then
            ' Koordinaten der Zielzelle abrufen
            BildLinks = ZielZelle.Left
            BildOben = ZielZelle.Top
           
            ' Vorhandenes Bild löschen
            On Error Resume Next
            TB.Shapes("Bild").Delete
            On Error GoTo 0
           
            ' Bild einfügen
            With TB.Shapes.AddPicture(Filename:=Dateiname, _
                    LinkToFile:=msoFalse, _
                    SaveWithDocument:=msoCTrue, _
                    Left:=BildLinks, _
                    Top:=BildOben, _
                    Width:=-1, _
                    Height:=-1)
               
                .Name = "Bild"
            End With
        Else
            MsgBox Target & " nicht gefunden!"
        End If
    End If
End Sub

Bei Änderungen in A1 wird das alte Bild auf Tab1 gelöscht und ein Neues gemäss der Auswahl eingefügt und als "Bild" benannt


LG UweD

[speckman2003]

Moin,
ich möchte in einer datei, z.b. tabelle 2 neben einer tabelle bilder ablegen. wenn ich dann in tabelle 1 ein dropdown benutze um daten aus der tabelle in tabelle 2 abzurufen auch gleichzeitig ein bild mit auf tabelle 1 eingefügt wird. hoffe aus der beispieldatei wird es klar

[Fred11]

Hallo speckman2003,

dazu gibt es im Internet sehr viele Anleitungen.
Stichwort für Internet-Recherche:
Excel Dropdown Grafik

zum Beispiel:
https://www.tabellenexperte.de/bildauswa...own-liste/
https://office-lernen.com/excel-bilderau...-dropdown/
(359) Bildwechsel per Dropdown - Formulare in Excel - YouTube

Gruß
Fred