englisches Datum in der Form "8/8/1988"

[Joerg_de]

Hallo,

ich möchte ein englisches Datumsformat in der Schreibweise 8/8/1988 umwandeln ins deutsche Datumformat und hab dazu die Formel
 WENN(ISTZAHL(SUCHEN("/";B2));DATUM(RECHTS(B2;4)*1;LINKS(B2;2);TEIL(B2;4;2));B2)
im Internet gefunden, die aber nur mit einer der vier möglichen Untervarianten (1/8/1988, 1/28/1988, 12/1/1988 oder 12/28/1988) klar kommt.

Jemand eine Idee?

Vielen Dank und

schönen Gruß
Jörg

[{Boris}]

Hi,

ich geh mal davon aus, dass Deine angegebene Excelversion nicht (mehr) stimmt.
Für das neueste Excel z.B.:

=LET(x;TEXTTEILEN(B2;"/");DATUM(INDEX(x;3);INDEX(x;1);INDEX(x;2)))

Alternativ:

=--TEXTVERKETTEN(".";;SPALTENWAHL(TEXTTEILEN(B2;"/");2;1;3))

[LCohen]

{Boris} abgewandelt: =LET(x;TEXTTEILEN(B2;"/");--TEXTVERKETTEN(".";;INDEX(x;{3.1.2}))) EDIT: überschnitten

[RPP63]

Moin!
Zelle*1
?

	C	D
1	8/8/1988	08.08.1988

Zelle	Formel
D1	=C1*1

Gruß Ralf

[{Boris}]

Hi Ralf,

geht nur, wenn Monat und Tag gleich sind ?

[LCohen]

Sein Bsp. zeigt leider nicht sein M/T/J an. Erst im weiteren Verlauf.

[RPP63]

Ihr habt ja Recht!
Wobei man sich ja (mal wieder) die Frage stellt, wie die Texte in die Tabelle kommen.
Ich lehne mich ganz weit aus dem Fenster und behaupte, dass es sich um einen fehlerhaften Import einer CSV handelt.

[Stephan]

Hallo,

als weiteren Schritt mit dieser Formel (ginge auch etwas kürzer) ---- wobei hier das Leerzeichen am Ende des Datums berücksichtigt wurde--


=TEIL(B2;FINDEN("/";B2)+1;LÄNGE(B2)-(LÄNGE(K2)+2)-(F2))&"."&LINKS(B2;FINDEN("/";B2)-1)&"."&RECHTS(B2;5)
sorry, hier waren noch die beiden Übungszellen enthalten.

=TEIL(B2;FINDEN("/";B2)+1;LÄNGE(B2)-(LÄNGE(RECHTS(B2;5))+2)-(FINDEN("/";B2)-1))&"."&LINKS(B2;FINDEN("/";B2)-1)&"."&RECHTS(B2;5)

Gruß Stephan

[LCohen]

=--TEXT(SUMME(TEXTTEILEN(B2;"/")*10^{2.0.4});"0\.00\.00")

[Kuwer]

Hallo Jörg,

mein Vorschlag wäre:

=WENN(ISTZAHL(SUCHEN("/";B2));DATUM(WECHSELN(RECHTS(B2;5);"/";"");LINKS(B2;SUCHEN("/";B2)-1);WECHSELN(TEIL(B2;SUCHEN("/";B2)+1;2);"/";""));B2)

Gruß, Uwe