Zunahme / Abnahme von Werten über Spalten je Zeile

[Geschweifter]

Hallo Gemeinde

In einer Liste habe ich neben dem Datum zwei Spalten mit Werten.
Jeden Tag kommt eine neue Zeile dazu.
Damit lese ich in einem weiteren Blatt die Mittelwerte und Max/Min Werte aus.

Für mich relevant ist auch die max. Zunahme (nur der Wert) vom 1. Wert (1.Spalte) zu dem 2. Wert (2.Spalte).
Das Zunahme / Abnahme  je Zeile ist soweit ok. Wie aber bekomme ich das für die ganze Spalte hin?
Ich habe es auf verschiedene Arten ausprobiert, scheitere aber jedes mal.

{=MAX('Messwerte 2017'!$H$3-'Messwerte 2017'!$G$3)}   Korrektes Ergebnis für die Zeile

{=MAX('Messwerte 2017'!$H$3-'Messwerte 2017'!$G$3;" ";'Messwerte 2017'!$H$100-'Messwerte 2017'!$G$100)} 
Für die Spalte ergibt sich ein Fehler #WERT!
Auch habe ich es versucht in Klammern zu setzen aber ...

Sieht hier jemand eine Lösung?
Besten Dank mal vorab für jede Hilfestellung. :100:

[neopa]

Hallo,

Deine Fragestellung ist etwas irritierend. Ich vermute mal Du suchst folgendes?

=AGGREGAT(14;6;('Messwerte 2017'!H1:H999-'Messwerte 2017'!G1:G999);1)

Diese Formel benötigt keines spez. Formelabschluss, wie eine klassische MATRIXformel.

Alternativ auch ohne {} für ältere Excelversionen:

=MAX(INDEX('Messwerte 2017'!H1:H999-'Messwerte 2017'!G1:G999;))

[Geschweifter]

Hallo Werner

In beiden Fällen ist die Lösung zutreffend.
Herzlichen Dank. Werde AGGREGAT und INDEX genauer betrachten.

Tom

[Geschweifter]

Nachtrag:

Wie schliesse ich die Zeilen aus bei denen kein Eintrag (Wert) in einer der Zellen ist. Also in einer der beiden Spalten.
Wahr ist in diesem Falle, dass nur wenn beide Werte in den beiden Spalten vorhanden sind eine Berechnung stattfindet.

Ist dies mit der WENN Funktion möglich oder gibt es hier auch eine "einfachere" Lösung?

Hoffe es ist nachvollziehbar. Besten Dank vorab für eine neue Erkenntnis.

[neopa]

Hallo,

dazu bedarf es mit AGGREGAT() keines zusätzlichen WENN()

Wenn keine negativen Zahlenwerte in Spalte G stehen dann reicht:

=AGGREGAT(14;6;('Messwerte 2017'!H1:H999-'Messwerte 2017'!G1:G999)/('Messwerte 2017'!G1:G999<>"");1)

Sollten negative Zahlen in Spalte G möglich sein, dann zusätzlich:   .../('Messwerte 2017'!H1:H999<>"")...

[Geschweifter]

Hallo Werner

Herzlichen Dank zum 2.
Negative Werte als Resultat sind möglich. Die Zahlen in G sind Positiv.

Verstanden habe ich dene Lösung noch nicht. Sie funktioniert aber.
Mit einer aufgestossenen Tür folgt die nächste. Und so suche ich nun den Ansatz zu der max. Zunahme,
auch die max. Abnahme bzw. deren min. festzustellen

Ich probier die Angel mal aus. : )


Hatte den Weg mit WENN ausprobiert und bin schon froh dass keine Fehlermeldung kam.
Brauchbar ist es leider nicht.


=WENN(ISTLEER('Messwerte 2017'!H3:H400);('Messwerte 2017'!I3:I400))*MAX(INDEX('Messwerte 2017'!I3:I400-'Messwerte 2017'!H3:H400;))

Gruss
Tom

[neopa]

Hallo Tom,

wenn in Spalte G die Werte positiv sind, brauchst Du zur Ermittlung des max Zuwachses die Spalte H nicht zu prüfen, ob da auch Werte stehen.

Anders sieht es aus, wenn Du den max "Verlust" ermitteln willst.  In diesem Fall nutze anstelle 14 die 15 als erstes Argument der Funktion AGGREGAT()

Natürlich kann man das ganze auch mit MAX() und MIN() berechnen. Aber mE geht es mit AGGREGAT() einfacher.

[Geschweifter]

Hallo Werner

Danke schön. Das hab ich mal getestet und die Funktion gefällt mir gut.

Was ich noch nicht verstehe ist, dass bei Funktion 15 (KKLEINSTE)
leere Zellen in Spalte I  als Wert verwendet werden.

Max. Abnahme von H zu I

=AGGREGAT(15;6;('Messwerte 2017'!H3:H400-'Messwerte 2017'!I3:I400)/('Messwerte 2017'!I3:I400<>"");1)

Wenn ich mit  'Messwerte 2017'!I3:I400<>""   spiele bekomme ich aber
nur einen falschen Wert aus der Liste wieder. Mit Funktion 16 (max. Zunahme) passt es.
Wo stehe ich da auf dem Schlauch?


Gruss
Tom

[neopa]

Hallo Tom,

lade doch bitte anstelle eines Bildes ein Datei hier hoch. Ich kann es mir dann allerdings frühestens heute am Abend anschauen, weil ich momentan etwas im Stress bin.

[Geschweifter]

Hallo Werner

Besten Dank für dein Engagement.

Gruss
Tom