Zellinhalte mit VBA löschen

[moselfuchs]

Hallo zusammen,
ich habe keinen blassen Schimmer von VBA. Deshalb meine Frage an die Spezialisten.
Kann ich den Inhalt einer Zelle nach der Eingabe von 1 oder 2 oder 3 nach der Eingabe automatisch nach z.B. 1 Sekunde löschen?

LG "moselfuchs"

[Kuwer]

Hallo,

' **************************************************************

'  Modul:  Tabelle1  Typ = Element der Mappe(Sheet, Workbook, ...)

' **************************************************************



Option Explicit



Private Sub Worksheet_Change(ByVal Target As Range)

 Set rngZ = Target

 Application.OnTime EarliestTime:=Now + TimeValue("00:00:01"), _

                       Procedure:="ZelleWiederLeeren"

End Sub

' **************************************************************

'  Modul:  Modul1  Typ = Allgemeines Modul

' **************************************************************



Option Explicit



Public rngZ As Range



Sub ZelleWiederLeeren()

 If Not rngZ Is Nothing Then

   On Error Resume Next

   Application.EnableEvents = False

   rngZ = ""

   Set rngZ = Nothing

   Application.EnableEvents = True

   On Error GoTo 0

 End If

End Sub

Gruß Uwe

[moselfuchs]

Hallo Uwe,

vielen Dank für die schnelle Hilfe. Entschuldige, dass ich erst jetzt antworte, aber wie bei vielen Rentners ist Zeit ein Problem.
Dein VBA script funtioniert einwandfrei, nur wie kann ich dieses Script auf die Zelle C1 beschränken. Sonst werden auch alle Texteinträge mitgelöscht.
Ich habe eine Beispieldatei angehängt. Im Original gibt man in C1 eine Zahl ein, nur dann funktioniert die Anzeige der Kommentare nicht mehr.(siehe Eintrag von mir vor ein paar Tagen).
Wenn ich aber den Zellwert in C1 lösche, bleibt das ausgewählte Bild zu sehen und die Kommentare funktionieren wieder.
Das war meine laienhafte Überlegung, das Problem zu lösen.
Gruß Moselfuchs

[schauan]

Hallöchen,

nur wie kann ich dieses Script auf die Zelle C1 beschränken

Code:

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Address="$C$1" Then
Set rngZ = Target
Application.OnTime EarliestTime:=Now + TimeValue("00:00:01"), _
                      Procedure:="ZelleWiederLeeren"
End If
End Sub

[moselfuchs]

Hallo André ("schauan"),

vielen Dank für Deine schnelle Hilfe. Alles funktioniert nach ein paar Versuchen einwandfrei. Jetzt kann ich meine Vorlage fertig stellen, auch das Problem unter dem Eintrag Excel 2013 Kommentare, sieh Dein Eintrag, wurde mit dieser Lösung beseitigt.
Ich mache alles ehrenamtlich und wenn alles funktioniert, sparen andere Funktionäre bei uns im Verband, die ebenfalls ehrenamtlich tätig sind, viel Zeit.

LG moselfuchs