Zellinhalt in eckiger Klammer summieren

[gitmichi]

Hallo,

ich habe eine Beispieldatei eingefügt in der eine Tabelle ist.

In den Zellen dieser Tabelle stehen Wörter, hinter denen eine ekige Klammer ist.

Wenn ich jetzt in diese Tabelle egal in welcher Spalte Fanartikel eintrage und dahinter eine eckige Klammer mit einer Zahl drin erscheint. Dann soll/sollen die Zahlen in eckiger Klammer vor der das Wort Fanartikel steht unten summiert werden.

Geht das mit einer Formel zu machen??

Dies dann natürlich auch noch mit anderen Wörtern die man in die Zelle D31 einträgt.

Vielen Dank für die Hilfe

gitmichi

[Klaus-Dieter]

Hallo,

Berechnungen auf der Grundlage von Zellformaten sind immer eine schlechte Idee. In deinem Fall sind das noch nicht einmal richtige Zahlen, weil daraus durch die Sonderzeichen immer ein Text wird. Es wird sich für mich nie erschließen, warum man verschiedene Datentypen in eine Zelle (Spalte) quetscht, obwohl rund sechzehntausend Spalten zur Verfügung stehen.

[gitmichi]

Hallo,

in der richtigen Zelle sind noch mehr daten.

macht es das einfacher wenn zwischen Klammer und Zahl Leerzeichen sind??

[steve1da]

Hola,
ne, es macht es einfacher wenn in einer Zelle der Text steht und in der Zelle daneben die Zahl. Ohne Klammern oder anderem schnick schnack.
Gruß,
steve1da

[ws-53]

in der richtigen Zelle sind noch mehr daten.

Eine Mustermappe sollte immer die gesamte Komplexität enthalten, da sonst die Gefahr besteht, dass Lösungen auf ungenügender Grundlage erarbeitet werden !!!

[ws-53]

Mit einem neueren Excel geht es mit:

Code:

=LET(
zus;ZUSPALTE(D13:H17);
flt;FILTER(zus;ISTZAHL(SUCHEN("Fanartikel";zus)));
spl;TEXTNACH(flt;"[");
erg;SUMME(TEXTVOR(spl;"]")*1);
erg)

[BoskoBiati]

Hi,

z.B. so (korrigiert):

Code:

=SUMME(WENN(ISTZAHL(SUCHEN(D31;$D$11:$H$17));--WECHSELN(TEIL($D$11:$H$17;SUCHEN("[";$D$11:$H$17)+1;99);"]";"")))

[EA1950]

Hallo,

und hier eine weitere Version für Excel365:

Code:

=LET(
    Art; "Fanartikel";
    v; ZUSPALTE($D$10:$H$17);
    vart; FILTER(v; REGEXTESTEN(v; Art));
    SUMME(--WENNFEHLER(REGEXEXTRAHIEREN(vart; "\[(\d+)\]$"; 2); 0))
)

[gitmichi]

Danke das ist schon das was ich brauche...
Einzig wenn Fanartikel in der Tabelle ohne die Klammer auftaucht und schon einmal mit Klammer und Zahl vertreten war, wird in der Zelle " Wert" angezeigt

LG und Danke

[cysu11]

Hi,

probiere das mal: =SUMME(WENNFEHLER(WENN(ISTZAHL(SUCHEN(D31;B8:I19));WERT(TEIL(B8:I19;FINDEN("[";B8:I19)+1;FINDEN("]";B8:I19)-FINDEN("[";B8:I19)-1));0);0))

BR, Alexandra