Zeiterfassung im vorbestimmten Ramen, bestimmter Tage

[Anderl]

Hallo Zusammen,
ich bin neu im Forum und bräuchte mal Hilfe bei einer Formel beziehungsweise einem Lösungsvorschlag für meine „selbstgebaute“ Zeiterfassung. Habe bisher im Internet leider keine Lösungsvorschläge gefunden. Meine Excel Kenntnisse beruhen auf Excel Grundkurse und Internet Recherchen.
In Zelle C35 soll das Ergebnis der gesamt Stunden aller Samstage zwischen 14:00 und 20:00 wieder gegeben werden.
Wenn in Spalte B2 – B32  "Sa" steht, dann die Stunden zwischen 14:00 und 20:00 aus Spalte C2 : D32 zählen
Vielen Dank schon mal
Anderl

[steve1da]

Hola,
du kannst dir eine Hilfsspalte anlegen:

Code:

=(MIN(D2;20/24)-MAX(C2;14/24))*(B2="sa")

Die Formel ziehst du nach unten und daraus dann die Summe ermitteln.
Die Formel in Spalte N kann man übrigens mit einem Sverweis erledigen, in dem man die Dienste und die Zeiten untereinander in eine Hilfstabelle schreibt. Das macht Anpassungen extrem einfach.

Das du in der Tabelle das 1904 Datumsformat verwendest und was das bedeutet weißt du?

Gruß,
steve1da

[Anderl]

Hallo steve1da,

erstmal danke für die schnelle Antwort.
Ich habe die Formel eingegeben (jetzt auf C41, zur besserer Übersicht) und er gibt mir die Fehlermeldung #Überlauf an.
Das ich das Datumsformat verwende wusste ich, was es wirklich bedeute nicht. War ein Lösungsvorschlag aus dem Internet als eine Tabelle mal nicht funktionierte.
und danke für den Tipp mit dem Sverweis. Werde ich als nächstes ausprobieren
Gruß
Anderl

[steve1da]

Das ist nicht meine Formel!

Warum hast du sie verändert (und daraus automatisch eine Spillformel gemacht?)

Die Formel kommt, wie gesagt, in eine Hilfsspalte. ZB ab R2 und wird dann heruntergezogen bis R32.

Edit: außerdem sehe ich nur das du händisch #ÜBERLAUF in eine Zelle geschrieben hast. Den Fehler selber sehe ich nicht.

[Egon12]

ja das ist ab O2021 so. Da brauchts kein runterziehen mehr. Es werden in diesem Falle die Bereiche als Matritzen behandelt.

Gruß Uwe

[Sigi.21]

Hallo,

Anderl hat auch 2 Pausen vorgesehen, die ggf. ja auch noch berücksichtigt werden müssten.
Was ist mit Feiertagen?
Was ist, wenn die Arbeitszeit über Mitternacht geht? Kommt das vor, Anderl?

Gruß Sigi

[EA1950]

Hallo,

da ich mit der Versionsangabe 15 nichts anfangen kann, eine Formel für Excel365:

=SUMME( MAP($B$2:$B$32; $C$2:$C$32; $D$2:$D$32; LAMBDA(w; k; g; (MIN(g; 20/24) - MAX(k; 14/24)) * (w = "Sa"))))

Als Resultat müsste dann 08:20 herauskommen (bzw. 0,34722222 mit Standardformatierung).
Vorgenannte Formel benötigt keine Hilfsspalte und kann daher direkt in Zelle C35 eingegeben werden.

Anmerkung: Der Fehler #ÜBERLAUF! entsteht dann, wenn die Formel einen Resultatbereich besitzt, wobei dieser Resultatbereich bereits Daten enthält. Damit dieser Fehler verschwindet, muss zuerst dieser Resultatbereich geleert werden!

[Anderl]

Vielen lieben Dank steve1da,

jetzt habe ich es kapiert, funktioniert einwandfrei.

Auch allen Anderen vielen lieben Dank, für die Tipps und Anregungen.

@Sigi, die Zweite Pause werde ich wieder rausnehmen da sie bei meinen neuen Dienstzeiten nicht mehr gebraucht werden. Feiertage zählt er mir durch Eingabe F-Früh bez. F-Spät. Und die Zeiten über Mitternacht sind Gott sei Dank vorbei 

Grüße 
Anderl

[slowboarder]

Hi

passend für alle Excelversionen:

=SUMMENPRODUKT((B2:B32="Sa")*(C2:C32<(20/24))*(D2:D32>(14/24))*(WENN(D2:D32>(20/24);20/24;D2:D32)-WENN(C2:C32<(14/24);14/24;C2:C32)))

die Formel arbeitet auch dann korrekt, wenn das Arbeitsende vor 14:00 und der Arbeitsbeginn nach 20:00 liegt
die Formel ist nicht für ein Arbeitsende nach Mitternacht ausgelegt

Gruß Daniel

---

Hola,
du kannst dir eine Hilfsspalte anlegen:

Code:

=(MIN(D2;20/24)-MAX(C2;14/24))*(B2="sa")

Die Formel ziehst du nach unten und daraus dann die Summe ermitteln.
Die Formel in Spalte N kann man übrigens mit einem Sverweis erledigen, in dem man die Dienste und die Zeiten untereinander in eine Hilfstabelle schreibt. Das macht Anpassungen extrem einfach.

Das du in der Tabelle das 1904 Datumsformat verwendest und was das bedeutet weißt du?

Gruß,
steve1da

Die Formel liefert negative Werte, wenn die Arbeitszeit komplett außerhalb des angegebenen Zeitbereichs liegt, also wenn das Arbeitsende vor 14:00 oder der Arbeitesbeginn nach 20:00 liegt.
daher besser:

=Max(0;MIN(D2;20/24)-MAX(C2;14/24))*(B2="sa")

Gruß Daniel