Zeiten automatisch errechnen - Stundenzettel

[Mikelold1]

Liebe Leute,

das hier ist meine erste Frage und ich hoffe, dass sie nicht allzu dumm ist. Ich möchte bei einem Stundenzettel automatisch die Zeit errechnen. Ich habe eine Zelle mit dem Wert "09:00-15:30" und hätte gerne das Ergebnis in einer anderen Zelle. Alle Wege, die ich ich über Google und KI gefunden habe, scheinen nicht zu funktionieren. Ich wende mich auch lieber an Menschen. Danke im Voraus! Ich hab die Tabelle angehängt.

LG
Mikel

[RPP63]

Moin!
"09:00-15:30" ist halt kein Zeitraum, sondern schnöder Text.
Viel besser ist es, Anfang und Ende zwei Zellen zu gönnen.
Schließlich hat jedes Blatt mehr als 9.000.000.000 davon …
Egal!
Neue Excel-Versionen können tricksen:

	B	E
1	Uhrzeit
2	09:15-10:45	1,5
3	20:15-21:45	1,5
4	18:00-22:30	4,5
5	16:00-16:30	0,5
6	18:00-22:00	4

Zelle	Formel
E2	=LET(a;TEXTTEILEN(B2;"-";);(INDEX(a;2)-INDEX(a;1))*24)

Gruß Ralf

[Mikelold1]

Lieber Ralf,

Du hast mir den Tag gerettet und ich danke Dir sehr! :)
Blöderweise ist bei leeren Tagen natürlich in der Ergebniszeile der Fehler "#WERT!", was die Summierung unmöglich macht. Wie umgehe ich das denn?

LG
Mikel

[RPP63]

=WENNFEHLER(meineFormel;"")

Edit:
Da ich gerade sehe, dass du auch "bis 0:00" in der Datei hast, muss die Formel erweitert werden:
=WENNFEHLER(LET(a;TEXTTEILEN(B2;"-";);REST((INDEX(a;2)-INDEX(a;1));1)*24);"")

[Mikelold1]

Lieber Ralf,

Du bist Bombe! Für Dich bräuchte man einen Waffenschein. Du hast mein Noobproblem derartig gut und schnell gelöst. Alles funktioniert und ich bin Dir sehr dankbar.



LG
Mikel

[slowboarder]

Hi

prinzipiell geht das auch mit einem alten Excel
es wird dann nur etwas aufwendiger.

=WENN(B2="";"";(TEIL(B2;FINDEN("-";B2)+1;6)-LINKS(B2;FINDEN("-";B2)-1)+((1*TEIL(B2;FINDEN("-";B2)+1;6))<(1*LINKS(B2;FINDEN("-";B2)-1))))*24)

der blaue Formelteil ist für den Fall, dass die Endzeit genau um Mitternacht oder danach, dh eigentlich am Folgetag liegt.

Gruß Daniel