Zeitdifferenz zwischen Spalten berechnen und anzeigen
#1
Hallo zusammen,

ich bin etwas am verzweifeln, weil ich es einfach nicht hinbekomme. Ich möchte Folgendes in dieser Excel Tabelle
.xlsx   Differenzen berechnen.xlsx (Größe: 30,98 KB / Downloads: 16) :
  • In Spalte K möchte ich gerne angezeigt bekommen, wie viele Minuten Differenz zwischen Spalte H und E besteht. Es sollen aber nur Minuten angezeigt werden, wenn es mehr als 60 Minuten früher ist damit es übersichtlicher bleibt! Ziel ist es zu prüfen, ob der Dienst in Spalte E nicht früher als 60 Minuten beginnt wie in Spalte H. Beispiel: in Spalte H beginnt der Dienst um 05:01 und in Spalte E würde 04:00 stehen - hier wären es 61 Minuten früher und somit unzulässig und in Spalte K sollte dann idealerweise 1 Minute stehen
  • In Spalte L möchte ich gerne angezeigt bekommen, wie viele Minuten Differenz zwischen Spalte I und F besteht. Es sollen aber nur Minuten angezeigt werden, wenn es mehr als 60 Minuten später ist, damit es übersichtlicher bleibt! Ziel ist es zu prüfen, ob der Dienst in Spalte F nicht später als 60 Minuten endet wie in Spalte I. Beispiel: in Spalte I endet der Dienst um 23:01 und in Spalte F würde dann 00:02 stehen - hier wären es 61 Minuten später und somit unzulässig und in Spalte L sollte dann idealerweise 1 Minute stehen . In Spalte I soll Excel zudem [+1] immer ignorieren - hat nur die Bedeutung, dass der Dienst in den nächsten Tag geht.

Wer kann mir hier helfen und die entsprechende Formel für die Spalten K und L bereitstellen? Liebe Grüße.
Antworten Top
#2
Hi,

ich bin mir nicht sicher ob es die kürzeste Lösung ist aber es würde funktionieren (glaube ich). Deine Rohdaten mit dem [+1]-Format und den verschiedenen Fällen sind schon tricky

K2 zum Runterziehen:
Code:
=WENN(UND((H2-E2)*24*60>60;E2<>"");(H2-E2)*24*60-60;"")
L2 zum Runterziehen:
Code:
=WENN(F2="";"";WENN((LINKS(TEXT(F2;"HH:MM");5)+(0&TEIL(TEXT(F2;"HH:MM");8;1))-LINKS(TEXT(I2;"HH:MM");5)-(0&TEIL(TEXT(I2;"HH:MM");8;1)))*24*60>60;(LINKS(TEXT(F2;"HH:MM");5)+(0&TEIL(TEXT(F2;"HH:MM");8;1))-LINKS(TEXT(I2;"HH:MM");5)-(0&TEIL(TEXT(I2;"HH:MM");8;1)))*24*60-60;""))
[-] Folgende(r) 1 Nutzer sagt Danke an BigJane für diesen Beitrag:
  • DaPicard
Antworten Top
#3
In K2

PHP-Code:
=IF($E2="";"";MOD(1440*ABS(H2-E2);60)) 

Numberformat "0"
Zum übersetzen von Excel Formeln:

http://dolf.trieschnigg.nl/excel/index.p...gids=en+de
Antworten Top
#4
Das funktioniert bei mir nicht, da kommt nur #NAME? als Antwort - bezieht sich auf den Beitrag von snb.
Antworten Top
#5
snb schreibt die Formeln auf Englisch.

Code:
=WENN($E2="";"";REST(1440*ABS(H2-E2);60))
Antworten Top
#6
(24.01.2025, 16:06)steve1da schrieb: snb schreibt die Formeln auf Englisch.

Code:
=WENN($E2="";"";REST(1440*ABS(H2-E2);60))

Japp, du hast völlig recht. Allerdings zeigt die Formel alle Differenzen an und ich wollte ja nur eine Anzeige, wenn der Dienst mehr als 60 Minuten beginnt.

(24.01.2025, 10:39)BigJane schrieb: Hi,

ich bin mir nicht sicher ob es die kürzeste Lösung ist aber es würde funktionieren (glaube ich). Deine Rohdaten mit dem [+1]-Format und den verschiedenen Fällen sind schon tricky

K2 zum Runterziehen:
Code:
=WENN(UND((H2-E2)*24*60>60;E2<>"");(H2-E2)*24*60-60;"")
L2 zum Runterziehen:
Code:
=WENN(F2="";"";WENN((LINKS(TEXT(F2;"HH:MM");5)+(0&TEIL(TEXT(F2;"HH:MM");8;1))-LINKS(TEXT(I2;"HH:MM");5)-(0&TEIL(TEXT(I2;"HH:MM");8;1)))*24*60>60;(LINKS(TEXT(F2;"HH:MM");5)+(0&TEIL(TEXT(F2;"HH:MM");8;1))-LINKS(TEXT(I2;"HH:MM");5)-(0&TEIL(TEXT(I2;"HH:MM");8;1)))*24*60-60;""))

Deine Formeln funktionieren super, da wäre ich NIE drauf gekommen, klasse!!!!! Vielen vielen Dank.
Antworten Top
#7
PHP-Code:
=IF($E2="";"";if(1440*ABS(H2-E2)>60;MOD(1440*ABS(H2-E2);60);"")) 

Es könnte lohnen Vorschläge zu analysieren.
Zum übersetzen von Excel Formeln:

http://dolf.trieschnigg.nl/excel/index.p...gids=en+de
Antworten Top
#8
Hi,

für K2:

Code:
=(E2<>"")*MAX(0;H2-E2-1/24)*1440

für L2:

Code:
=WENN(F2="";"";MAX(0;RUNDEN((LINKS(F2;5)+ISTZAHL(SUCHEN("+";F2))-LINKS(I2;5)-ISTZAHL(SUCHEN("+";I2)))*1440-60;0)))
Gruß

Edgar

Meine Antworten sind freiwillig und ohne Gewähr!
Über Rückmeldungen würde ich mich freuen.
Antworten Top


Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste