Zeilen ausblenden

[mumpel]

Hallo!

    For i = rngVert To 151
       If Range("J" & i).Value = "0" Then Range("J" & i).EntireRow.Hidden = True
    Next i

VBA/HTML-CodeConverter, AddIn für Office 2002-2016 - in VBA geschrieben von Lukas Mosimann. Projektbetreuung:RMH Software & Media
Code erstellt und getestet in Office 16 - mit VBAHTML 12.6.0

Kann man das Ausblenden ohne sie in einer Schleife zu durchlaufen? Oder kann man das Ausblenden verbessern oder "beschleunigen"?

Gruß, René

[maninweb]

Hallo,

die m.E. aus Performance-Sicht schnellste Methode wäre die Verwendung eines Autofilters, den Du auch in einer ausgeblendeten Spalte + Formel ablegen kannst.
Alternativ könnte man auch einen Algo entwickeln, der blockweise ausblendet, liefert etwas mehr Performance aber erreicht nicht den Autofilter.

Gruß

[RPP63]

Moin René!
Warum filterst Du Spalte J nicht einfach nach <>0
Du kannst es ja per VBA machen und VisibleDropDown:=False setzen.
Dann sieht man nicht, dass eigentlich gefiltert wurde.

Gruß Ralf

[mumpel]

Filter sollen nicht verwendet werden. Es soll schon eine VBA-Lösung sein (Nullzeilen ausblenden, Drucken, Zeilen wieder einblenden). Nur finde ich es nicht fein Zellen in Schleife zu durchlaufen.

[RPP63]

Dann mal per temp. Array:

Sub RPP()
Dim cnt&, tmpArr
Dim rngZeilen As Range
tmpArr = Range(Cells(1, "J"), Cells(1, "J").End(xlDown)).Value
For cnt = 1 To Ubound(tmpArr)
   If tmpArr(cnt, 1) = 0 Then
      If rngZeilen Is Nothing Then
         Set rngZeilen = Rows(cnt)
      Else
         Set rngZeilen = Union(rngZeilen, Rows(cnt))
      End If
   End If
Next
rngZeilen.EntireRow.Hidden = True
End Sub

Gruß Ralf

[mumpel]

Behandelt "tmpArr" nicht die gesamte Spalte? Es sollen aber nur bestimmte Zeilen (z.B. von 10 bis 151) berücksichtigt werden.
Und ist das nicht auch eine Schleife? ;)

[RPP63]

Behandelt "tmpArr" nicht die gesamte Spalte?

Nö, nur den gefüllten Bereich in J.

Es sollen aber nur bestimmte Zeilen (z.B. von 10 bis 151) berücksichtigt werden.

Dann starte halt ab Cells(10, "J") oder code hart: RAnge("J10:J151")

Und ist das nicht auch eine Schleife?

Ja, aber eine wahrscheinlich 100mal schnellere als Deine. ;)
Im Arbeitsspeicher (also ohne langsame Zellzugriffe) wird der Range zusammengesetzt.
Das Wichtigste: Der Bereich wird auf einen Schlag ausgeblendet.

Gruß Ralf

[RPP63]

Noch was:

Es soll schon eine VBA-Lösung sein (Nullzeilen ausblenden, Drucken, Zeilen wieder einblenden).

Gerade dann solltest Du meinen ersten Tipp beherzigen: Autofilter!
So ganz ohne Schleifchen.  :05:

Gruß Ralf

[mumpel]

Ich komme damit nicht zurecht. Es soll z.B. nur J10 bis J20 berücksichtigt werden. Alles davor und danach nicht. Da ist meine Schleife schon einfacher.

[chris-ka]

Hi,

Code:

Sub RPP_and_ck()
Dim cnt&, tmpArr
Dim int_start As Integer, int_Ende As Integer, za As Integer
Dim rngZeilen As Range
int_start = 10
int_Ende = 20
tmpArr = Range(Cells(int_start, "J"), Cells(int_Ende, "J"))
For cnt = int_start To int_Ende
    za = za + 1
   If tmpArr(za, 1) = 0 Then
      If rngZeilen Is Nothing Then
         Set rngZeilen = Rows(cnt)
      Else
         Set rngZeilen = Union(rngZeilen, Rows(cnt))
      End If
   End If
Next
If Not rngZeilen Is Nothing Then
    rngZeilen.EntireRow.Hidden = True
End If
End Sub