Zeilen aus anderer Tabelle übernehmen

[Pondus]

Liebes Forum,

ich arbeite mich langsam in Excel ein und ihr seid dabei schon öfters eine große Hilfe gewesen! Für folgendes Problem habe ich aber nichts gefunden.

Ich möchte alle Zeilen in denen eine gewisse Zeichenfolge vorkommt aus einem Tabellenblatt in ein anderes übernehmen. Im Beispiel wären das alle Zeilen bei denen in der ersten Spalte "Schokolade" steht

   

Mit folgender Formel klappt das auch ganz gut: 

{=WENN(ZEILE(Tabelle1!1:1)>ZÄHLENWENN(Tabelle1!$A$1:$A$5;"Schokolade");"";INDEX(Tabelle1!A:A;KKLEINSTE(WENN(Tabelle1!$A$1:$A$5="Schokolade";ZEILE(Tabelle1!$3:$23));ZEILE(A1))))}

...solange in der Zelle nur "Schokolade" und nicht noch weitere Zusätze stehen. Ich habe versucht die Suche mit einem Sternchen zu erweitern, sodass z.B. auch "Schokolade Milka" in die Zieltabelle übernommen wird, doch das klappt nicht!?

Hat irgend jemand eine Idee? 

Ganz vielen Dank auf jeden Fall schon mal im Voraus!

[Jockel]

Hallo, ab XL2010 kannst du AGGREGAT() verwenden. Ab XL2007 gibt's WENNFEHLER()... Schade, dass du ein Bild gepostet hast. Ich baue das nicht nach...
Wenn Schokolade immer vorne steht brauchst du ja nur aus "Schokolade" "Schokolade*" - also mit * hinter Schokolade - machen

[Pondus]

Hallo Jockel,

ganz vielen Dank! Das werde ich ausprobieren!!! Mit dem Bild ist es irgendwie doof, das habe ich jetzt auch gemerkt ;) Im Anhang habe ich nochmal die Ausgangstabelle  


  Beispiel.xlsx (Größe: 8,95 KB / Downloads: 4)

[Jockel]

Naja mit dem Sternchen hatte ich mich wohl geirrt... ... wenn Schokolade immer links steht, geht z. B.:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G	H
1	Schokolade Milka 35531	254-2021	Lager	Erledigt				Schokolade Milka 35531
2	Eiscreme 587345	781-996	Bestellt	Offen				Schokolade Gubor 47
3	Würze Maggi 015277	245-301	Ausverkauft	Offen				Schokolade Milka 7774
4	Schokolade Gubor 47	806-742	Bestellt	Offen
5	Schokolade Milka 7774	308-963	Lager	Erledigt

Zelle	Formel
H1	=WENNFEHLER(INDEX($A$1:$A$5;AGGREGAT(15;6;ZEILE($A$1:$A$5)/(LINKS($A$1:$A$5;10)="Schokolade");ZEILE(A1)));"")

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[Jockel]

Hallo, wenn Schokolade irgendwo in der Zelle vorkommen kann geht auch..:

PHP-Code:

=WENNFEHLER(INDEX($A$1:$A$5;AGGREGAT(15;6;ZEILE($A$1:$A$5)/ISTZAHL(SUCHEN("schokolade";$A$1:$A$5));ZEILE(A1)));"") 


[Pondus]

Hallo Jörg,

du bist super! das funktioniert einwandfrei! Jetzt muss ich nur noch den Rest der Zeilen irgendwie mit in die neue Tabelle kriegen, doch das sollte nicht das größte Problem sein! Weißt du wieso man das Sternchen hier nicht zur Trunkierung verwenden kann?

Wie auch immer, ganz vielen Dank und einen schönen Abend!

[Jockel]

Hallo Jörg,

... Jetzt muss ich nur noch den Rest der Zeilen irgendwie mit in die neue Tabelle kriegen ...

Hallo, welchen Rest..? Meinst du so..? Dann würde ich mit ner Hilfsspalte arbeiten... (die kann man ja ausblenden...)

Arbeitsblatt mit dem Namen 'Tabelle2'
	A	B	C	D	E
2	1	Schokolade Milka 35531	254-2021	Lager	Erledigt
3	4	Schokolade Gubor 47	806-742	Bestellt	Offen
4	5	Schokolade Milka 7774	308-963	Lager	Erledigt

Zelle	Formel
A2	=WENNFEHLER(AGGREGAT(15;6;ZEILE($A$1:$A$5)/ISTZAHL(SUCHEN("schokolade";Tabelle1!$A$1:$A$5));ZEILE(A1));"")
B2	=WENNFEHLER(INDEX(Tabelle1!A:A;$A2);"")
C2	=WENNFEHLER(INDEX(Tabelle1!B:B;$A2);"")
D2	=WENNFEHLER(INDEX(Tabelle1!C:C;$A2);"")
E2	=WENNFEHLER(INDEX(Tabelle1!D:D;$A2);"")

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[Pondus]

Oh ja, genau so meinte ich das! Wie einfach doch alles sein kann... Da hätte ich ordentlich Hirnschmalz reinstecken müssen! Ein kleines Problem gibt es aber noch, da ich mein Beispiel etwas unglücklich gewählt habe... Leider geht es bei mir nicht um Schokolade sondern um Buchstaben-Zahlen-Kombinationen. Z.B. "LN: B 3" und "LN: B 35". Nutze ich die Formel wie folgt

=WENNFEHLER(AGGREGAT(15;6;ZEILE($A$1:$A$5)/ISTZAHL(SUCHEN("LN: B 3";Tabelle1!$A$1:$A$5));ZEILE(A1));"")

bekomme ich leider auch Ergebnisse die "LN: B 35" beinhalten. Kennt hier jemand eine Möglichkeit die Ergebnisse auf die exakte Zeichenfolge zu beschränken?

Danke und Grüße

[Jockel]

Hallo, das wird schwieriger... Aber nicht wenn LN: B 3 links steht dann nimm die erste Formel..:

Code:

=WENNFEHLER(INDEX($A$1:$A$5;AGGREGAT(15;6;ZEILE($A$1:$A$5)/(LINKS($A$1:$A$5;7)="LN: B 3");ZEILE(A1)));"")

... oder für die Hilfsspalte...

Code:

=WENNFEHLER(AGGREGAT(15;6;ZEILE($A$1:$A$5)/(LINKS($A$1:$A$5;7)="LN: B 3");ZEILE(A1));"")