Zeile nach 2 Variablen prüfen, kopieren und einfügen(Formel/kein Makro)

[cienrxs]

Hi Leute ich bin am verzweifeln vielleicht liegt es auch an der Uhrzeit aber ich denke mal das es an meinem Mangel der kenntnisse liegt.

Was will ich tun:

Ich möchte aus der Tabelle Transferübersicht, mit hilfe 2 Werte überprüfen ob diese zutreffen, wenn ja in die einzufügende Tabelle  wo die Formel eingetragen wird, den Wert aus Transferübersicht erhalten.


Siehe bei meiner Formel mit 1 Variable, diese Funktioniert.

Code:

=WENN(ZEILE(Transferübersicht!1:1)>ZÄHLENWENN(Transferübersicht!$C$2:$C$334;"DV");"";INDEX(Transferübersicht!E:E;KKLEINSTE(WENN(Transferübersicht!$C$2:$C$334="DV";ZEILE(Transferübersicht!$2:$334));ZEILE(E1))))

Mit Shift und STRG Enter drücken. Ja das hab ich und es funktioniert

Wenn ich die Formel anpassen möchte das eine weitere Variable hinzugefügt wird zum überprüpfen, bekomme ich zwar ein Ergebnis angezeit, aber nicht das richtige.

Code:

=WENN(ZEILE(Transferübersicht!1:1)>ZÄHLENWENNS(Transferübersicht!$C$2:$C$334;"DV";Transferübersicht!$D$2:$D$334;"TW");"";INDEX(Transferübersicht!E:E;KKLEINSTE(WENN(UND(Transferübersicht!$C$2:$C$334="DV";Transferübersicht!$D$2:$D$334="TW");ZEILE(Transferübersicht!$2:$334));ZEILE(E1))))

Tabelle Transferübersicht
[url=
Dateiupload bitte im Forum! So geht es: Klick mich!
]

Tabelle wo die Formel eingefügt wird
[url=
Dateiupload bitte im Forum! So geht es: Klick mich!
]



Falls ich zu viel Wirres Zeug geschrieben haben tut es mir leid.
Stehe aber nach meinem Schlaf gerne für Fragen bereit und Beantworte diese.

Hoffe ihr könnt mir helfen.

Gruß Cienrxs

[WillWissen]

Moin,

schau dir mal INDEX() in Verbindung mit AGGREGAT() an. Wenn der Tipp nicht reicht, lade bitte eine anonymisierte Beispieldatei hoch.

[cienrxs]

Hi WillWissen,

schon mal Danke für deine Antwort.
Habe die Datei Angehängt und wäre schön, wenn du mir das mal zeigen könntest.
Der erste treffer der Rot markiert ist ist der Falsche, dort müsste Baumann stehen.


Gruß Cienrxs

[WillWissen]

Moin,

Arbeitsblatt mit dem Namen 'Mannschaftsübersicht'
	A	B
1	DV	Spieler
2	TW	Baumann

Zelle	Formel
B2	=INDEX(Transferübersicht!E:E;AGGREGAT(15;6;ZEILE(Transferübersicht!$E$2:$E$400)/(Transferübersicht!$C$2:$C$400="DV")/(Transferübersicht!$D$2:$D$400="TW");ZEILE(A1)))

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[cienrxs]

Moin, Super Vielen Dank. Das funzt Super.