Dieses Forum nutzt Cookies
Dieses Forum verwendet Cookies, um deine Login-Informationen zu speichern, wenn du registriert bist, und deinen letzten Besuch, wenn du es nicht bist. Cookies sind kleine Textdokumente, die auf deinem Computer gespeichert werden. Die von diesem Forum gesetzten Cookies werden nur auf dieser Website verwendet und stellen kein Sicherheitsrisiko dar. Cookies aus diesem Forum speichern auch die spezifischen Themen, die du gelesen hast und wann du zum letzten Mal gelesen hast. Bitte bestätige, ob du diese Cookies akzeptierst oder ablehnst.

Ein Cookie wird in deinem Browser unabhängig von der Wahl gespeichert, um zu verhindern, dass dir diese Frage erneut gestellt wird. Du kannst deine Cookie-Einstellungen jederzeit über den Link in der Fußzeile ändern.

Das Update ist abgeschlossen, Ihr könnt unser Forum jetzt wieder wie gewohnt nutzen. Eventuelle Bugs und Auffälligkeiten postet Ihr bitte im entsprechenden Forum im Bereich Forumstechnik. x


Zeile mit neustem Datum kopieren
#1
Hallo Forum

Ich bin neu hier. Bin nach jahrelanger Pause wieder mal mit Excel konfrontiert. 

Ich habe folgendes:
Tabelle 1:
In Spalte A habe ich Namen von Ländern, die meisten mehrfach. (Diese Liste muss komplett bleiben. Dublikate entfernen ist nicht erlaubt)
In Spalte B steht ein Datum
In den anderen Spalten weitere Daten

Tabelle 2:
In Spalte A Namen von Ländern, aber jedes nur ein Mal.

Ich möchte jetzt gerne, dass mit einer Formel von der Tabelle 1 von jedem Land die Zeile mit dem neusten Datum bei der Tabelle 2 zum entsprechenden Land kopiert wird. Tabelle 2 sollte natürlich aktualisiert werden, wann immer ich bei Tabelle 1 eine neue Zeile mit neuem Datum erfasse?

Ich bin dankbar für jeder Hilfe.
Marc
Antworten Top
#2
Hi,

aus Tabelle1 machst du eine intelligente Tabelle mit dem Namen tab_Tabelle1.
In Tabelle2!A2 steht das gesuchte Land
in Tabelle2!B2 kommt die Formel
Code:
=LET(a;FILTER(tab_Tabelle1;tab_Tabelle1[Land]=A2);
b;SPALTENWAHL(a;2);
c;SPALTENWAHL(a;2;3;4);
d;MAX(b);
e;FILTER(c;b=d);
e)
a filtert die Tabelle und lässt nur die Zeilen mit dem gewünschten Land stehen
b ist die Datumsspalte daraus
c sind die Spalten, die angezeigt werden sollen
d berechnet das max. Datum
e filtert die anzuzeigenden Spalten auf das max. Datum
Gruß,
Helmut

Win10 - Office365 / MacOS - Office365
[-] Folgende(r) 1 Nutzer sagt Danke an HKindler für diesen Beitrag:
  • ExcelMarc
Antworten Top
#3
Hallo Helmut

Vielen Dank für die Antwort. 
Leider funktioniert das bei mir aber nicht so wie es sollte. Ich erhalte nur ein #NAME?
Ich habe das Dokument angehängt. Vielleicht könntest du ein Auge darauf werfen. 

Vielen Dank!

Gruss
Marc


Angehängte Dateien
.xlsx   Länder Formel.xlsx (Größe: 13,43 KB / Downloads: 6)
Antworten Top
#4
Hallöchen,

mal bisschen umgebaut
=LET(a;FILTER(tab_Tabelle1;tab_Tabelle1[Land]=A2);b;SPALTENWAHL(a;2);c;MAX(b);d;FILTER(a;b=c);e;SPALTENWAHL(d;2;3;4);e)
.      \\\|///      Hoffe, geholfen zu haben.
       ( ô ô )      Grüße, André aus G in T  
  ooO-(_)-Ooo    (Excel 97-2019+365)
[-] Folgende(r) 1 Nutzer sagt Danke an schauan für diesen Beitrag:
  • ExcelMarc
Antworten Top
#5
Guten Morgen

Danke für die neue Formel. Leider habe ich mit beiden Formeln das gleiche Problem. Wenn ich die Formel überprüfe, scheint sie bis zu ;b;SPALTENWAHL zu funktionieren, danach erhalte ich ein #NAME?.
Das ist bei beiden Formeln so. 

Ich habe die Datei und den Screenshot der Überprüfung der Formel angehängt.

Vielen Dank im Voraus für eure Hilfe.

Gruss
Marc


Angehängte Dateien Thumbnail(s)
   

.xlsx   Länder Formel.xlsx (Größe: 13,45 KB / Downloads: 2)
Antworten Top
#6
Hi,

dann kennt dein Excel wohl noch kein SPALTENWAHL. Also entweder updaten (was ich empfehlen würde, da dieser Befehl mittlerweile im halbjährlichen Enterprise-Kanal angekommen ist), oder das SPALTENWAHL() durch eine andere Formel ersetzen.

Statt SPALTENWAHL(a;2) könntest du z.B. ÜBERNEHMEN(WEGLASSEN(a;;1);;1) verwenden - sofern dein Excel diese beiden Befehle kennt. Falls nicht dann müsste auf alle Fälle FILTER(a;tab_Tabelle1[#Kopfzeilen]="Datum") funktionieren. Oder bei mehreren Spalten FILTER(a;(tab_Tabelle1[#Kopfzeilen]="Spaltenüberschrift1")+(tab_Tabelle1[#Kopfzeilen]="Spaltenüberschrift2")+(tab_Tabelle1[#Kopfzeilen]="noch 'ne Überschrift")) Allerdings kannst so dann nicht die Reihenfolge beeinflussen.
Gruß,
Helmut

Win10 - Office365 / MacOS - Office365
[-] Folgende(r) 1 Nutzer sagt Danke an HKindler für diesen Beitrag:
  • ExcelMarc
Antworten Top


Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste