Zeichenfolge suchen und Wert aus Spalte daneben ausgeben

[andrea_adk]

Hallo ihr Lieben,

schön, dass es dieses Forum gibt. Ich habe hier schon oft Lösungen gefunden, ohne selbst schreiben zu müssen. Aber jetzt komme ich nicht weiter.

ich würde gern Kontoauszüge (Excel-Format) nach Rechnungsnummern durchsuchen. Dafür habe ich zwei Tabellen nach folgenden Schemata:

1. Kontoauszug:

Buchungsdatum - Verwendungszweck - Auftraggeber - Buchungsbetrag

2. Zahlungsliste

Rechnungsnummer - Kundennummer - Kundenname - Rechnungsdatum - Zahlungsdatum

Ich möchte nun in der der Spalte "Zahlungsdatum" aus Tabelle 2 eine Formel haben, die die Spalte "Verwendungszweck" aus Tabelle 1 dahingehend überprüft, ob die "Rechnungsnummer" aus Tabelle 2 dort auftaucht (es stehen weitere Zeichen in den Zellen der Spalte "Verwendungszweck") und dann das "Buchungsdatum" aus Tabelle 1 ausgibt.

Geht das???

Und wenn ja, ginge es auch, dass über ODER überprüft wird, ob, wenn die Rechnungsnummer nicht vorkommt, die Kundennummer oder der Kundenname vorkommen?

Versteht ihr, was ich meine? Ich suche seit drei Tagen nach einer Lösung. Aber ich komme einfach nicht weiter.

Liebe Grüße
Andrea

[shift-del]

Hallo Andrea,

Code:

=VERWEIS(42;1/ISTZAHL(SUCHEN([@Rechnungsnummer];tbl_Kontoauszug[Verwendungszweck]));tbl_Kontoauszug[Buchungsdatum])

[andrea_adk]

Hallo Shift-Del,

danke für deine schnelle Antwort. Du bist super!! :18: :05: Ich habe [@Rechnungsnummer] allerdings durch die jeweilige Zelle ersetzt. Dann bekomme ich, was ich brauche.

Was bedeuten die Zahlen am Anfang der Formel?

=VERWEIS(42;1/ISTZAHL(SUCHEN([@Rechnungsnummer];tbl_Kontoauszug[Verwendungszweck]));tbl_Kontoauszug[Buchungsdatum])

Und kann ich auch weitere Suchbedingungen über ODER einfügen? Mein Versuch ist zumindest gescheitert.

Viele Grüße Andrae

[shift-del]

Und kann ich auch weitere Suchbedingungen über ODER einfügen? Mein Versuch ist zumindest gescheitert.

ODER() und UND() ergeben in Matrixformeln nicht das erwartete Ergebnis.
Dann in diesem Fall eher verschachtelte Formeln mit WENNFEHLER().

Code:

=WENNFEHLER(WENNFEHLER(VERWEIS(42;1/ISTZAHL(SUCHEN([@Rechnungsnummer];tbl_Kontoauszug[Verwendungszweck]));tbl_Kontoauszug[Buchungsdatum]);VERWEIS(42;1/ISTZAHL(SUCHEN([@Kundennummer];tbl_Kontoauszug[Verwendungszweck]));tbl_Kontoauszug[Buchungsdatum]));VERWEIS(42;1/ISTZAHL(SUCHEN([@Kundenname];tbl_Kontoauszug[Verwendungszweck]));tbl_Kontoauszug[Buchungsdatum]))