Zählen von nicht zusammenhängenden Zellen

[Rabe]

Hallo,

ich stehe gerade formelmäßig voll auf dem Schlauch.

Wie kann ich die Zellen  (H21, J21, L21, N21, P21, ...) zählen, deren Inhalt größer als 2 ist?

Die Formel soll in AY21 stehen.

Ebenso die Zellen, in denen die Zahl kleiner ist als die in der Spalte vorher (rot markiert).

Arbeitsblatt mit dem Namen 'Test'
	G	H	I	J	K	L	M	N	O	P	Q	R	S	T
21	3	3	3	3	3	3	2	2	1	3	1	4	2	3
22	2	3	3	4	3	4	1	1	1	0	1	1	2	0

Zelle	bedingte Formatierung...	Format
H21	1: Zellwert ist kleiner =G21	abc
H21	2: Zellwert ist größer gleich =G21	abc
H22	1: Zellwert ist kleiner =G22	abc
H22	2: Zellwert ist größer gleich =G22	abc

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

Danke!
Gruß Ralf

[steve1da]

Hola,

Code:

=SUMMENPRODUKT((REST(SPALTE(G21:T21);2)=0)*(G21:T21>2))

Code:

=SUMMENPRODUKT((H21:T21<G21:S21)*1)

Edit: die 2. Formel wirkt noch nicht bei nur jeder 2. Zelle. 

Gruß,
steve1da

[snb]

Array Formel

PHP-Code:

=SUM((A21:N22>2)*(MOD(COLUMN(A21:N22);2)=0)) 


[Rabe]

Hallo Steve,

passt noch nicht so ganz.
AY: Anzahl jeweils rechte Spalte größer 2 => stimmt
AZ: Anzahl jeweils linke Spalte größer 2 => stimmt
BA: Anzahl rechts kleiner links, da müsste oben 0 stehen und unten 2.

Arbeitsblatt mit dem Namen 'Test'
	G	H	I	J	K	L	M	N	O	P	Q	R	S	T	AY	AZ	BA
21	3	3	3	3	3	3	2	2	1	3	1	4	2	3	6	3	4
22	2	3	3	4	3	4	1	1	1	0	1	1	2	0	3	2	4

Zelle	Formel
AY21	=SUMMENPRODUKT((REST(SPALTE(G21:T21);2)=0)*(G21:T21>2))
AZ21	=SUMMENPRODUKT((REST(SPALTE(G21:T21);2)=1)*(G21:T21>2))
BA21	=SUMMENPRODUKT((H21:T21<G21:S21)*1)

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

Gruß Ralf

[slowboarder]

Hi Ralf

beachte, dass Steve geschrieben hat:  "Edit: die 2. Formel wirkt noch nicht bei nur jeder 2. Zelle."
dh in der Formel fehlt noch das Element, dass bewirkt, dass nur jede zweite Spalte in die Rechnung mit eingeht.
das wäre der Formelteil:  (REST(SPALTE(G21:T21);2)=0) welchen du noch in die Formel mit einbauen müsstest.

also als ganzes dann:
=SUMMENPRODUKT((H21:T21 < G21:S21)*(REST(SPALTE(H21:T21);2)=0))


Gruß Daniel

[Rabe]

Hallo Daniel,

aah, da hatte ich noch kein Refresh gemacht und das edit war noch nicht da.

Nun passt es.

Danke.

Gruß Ralf

[HKindler]

Hi,

ich hatte Lust etwas mit den Spill-Formeln zu Spielen:
AY21: =LET(a;$G21:$T21;b;SEQUENZ(SPALTEN(a)/2;;2;2);c;SPALTENWAHL(a;b);d;c>2;SUMME(--d))
AZ21: =LET(a;$G21:$T21;b;SEQUENZ(SPALTEN(a)/2;;1;2);c;SPALTENWAHL(a;b);d;c>2;SUMME(--d))
BA21: =LET(a;$G21:$T21;b;SEQUENZ(SPALTEN(a)/2;;1;2);bb;SEQUENZ(SPALTEN(a)/2;;2;2);c;SPALTENWAHL(a;b);cc;SPALTENWAHL(a;bb);d;c>cc;SUMME(--d))

Geht sicherlich noch eleganter...