Zählen in gefilterter Tabelle

[elamigo]

Guten Tag zusammen,

ich habe eine Tabelle. In dieser Tabelle möchte ich in Spalte BP gewisse Textinhalte zählen z.B. (T1, Z5, U3...).
Nun kommt meine Zählenwenn Funktion 

Code:

=SUMME(ZÄHLENWENN(BP6:BP15;{"T2"."U3"}))

(Also Matrix Formel mit Shift+Enter)
nicht mehr hinter her.
Alternativ habe ich diese Funktion gefunden, aber wie erweitere ich diese sodass ich mehr verschiedene Dinge zählen kann?

Code:

=SUMMENPRODUKT(TEILERGEBNIS(3;INDIREKT("C"&ZEILE(6:1200)))*(BP6:BP1200="T3"))

wenn ich diese wie das gewohnte Summenprodukt erweitere bekomme ich immer 0 als Ergebnis 

Code:

=SUMMENPRODUKT(TEILERGEBNIS(3;INDIREKT("C"&ZEILE(6:1200)))*(BP6:BP1200="T3")*(BP6:BP1200="U3"))

Jemand eine Idee?

[steve1da]

Hola,

die 0 kommt, weil *  als UND Bedingung angesehen wird. Und in einer Zelle kann nicht U3 und T3 gleichzeitig stehen.
Mach aus dem * ein +.

Deine erste Formel muss übrigens nicht mit Strg-Shift-Enter abgeschlossen werden.

Gruß,
steve1da

[elamigo]

just simple as that. Danke <3

---

@stev1da 

 Er zählt doch noch die nicht sichtbaren Zellen mit. 

Code:

=SUMMENPRODUKT(TEILERGEBNIS(3;INDIREKT("BP"&ZEILE(6:1200)))*(BP6:BP1200="P1")+(BP6:BP1200="P1/T2+")+(BP6:BP1200="T2")+(BP6:BP1200="P2+")+(BP6:BP1200="T2+")+(BP6:BP1200="T1"))

[steve1da]

Hola,

da fehlen noch Klammern:

Code:

=SUMMENPRODUKT(TEILERGEBNIS(3;INDIREKT("BP"&ZEILE(6:1200)))*((BP6:BP1200="P1")+(BP6:BP1200="P1/T2+")+(BP6:BP1200="T2")+(BP6:BP1200="P2+")+(BP6:BP1200="T2+")+(BP6:BP1200="T1")))

Gruß,
steve1da