Zählen Wenns Datums Bereich

[Ancalon]

Hallo zusammen, 

Ich habe ein Problem ich will eine Übersicht erschaffen in der ich ein Kalender habe ( 365 Tage ). 
Ich will Zählen wie viele Hunde Katzen usw. an Tag x da sind dazu habe ich Hunde in Hund, Hündin , Katze und Kater in der Kalender Übersicht geteilt. 
In der Tabelle Termine gebe ich ein Tier namen an Von Datum und ein Bis Datum ein viertes Feld sagt mir ob es ein Hund Hündin Katze oder Kater ist. 

Zu meiner Frage wie kann ich zählen wie viele der einzelnen Kategorie an dem Tag da sind. 

Meine Aktuelle abfrage funktioniert nur bedingt da sie nur den ersten und letzten Tag Zählt.

Code:

=ZÄHLENWENN(Termine!$B$2:$C$13;Übersicht!A3)

Ich hoffe es ist verständlich.

[steve1da]

Hola,

dann schau dir mal Zählenwenns() an.

Gruß,
steve1da

[Ancalon]

Hola,

dann schau dir mal Zählenwenns() an.

Gruß,
steve1da

Das hab ich schon gemacht aber da finde ich nix das aus 2 einzelnen datums feldern eine Datumsrange macht.

[steve1da]

Hola,

Code:

=zählenwenns(A1:A10;">="&D1;A1:A10;"<="&D2)

Zählt alle Daten zwischen D1 und D2.

Gruß,
steve1da

[Ancalon]

Hola,

Code:

=zählenwenns(A1:A10;">="&D1;A1:A10;"<="&D2)

Zählt alle Daten zwischen D1 und D2.

Gruß,
steve1da

Vielen Dank schon mal, ich bekomme als Antwort das ich zu wenig Argumente angebe.

Code:

=ZÄHLENWENNS(Termine!B2:B125;">="&Termine!C2:C125;"<="&Übersicht!C2)

Die B Spalte ist das von C bis Datum Übersicht C ist Hündin aber ich muss ja auch noch das Datum für den tag im Kalender angeben. Stehe grade etwas auf dem Schlauch ?

[Jockel]

Hallo, was sagt denn die online-Hilfe dazu..?

[RPP63]

Moin!
Steve übergibt vier Argumente.
Du nur drei!
Zur Not gibt es aber auch eine Hilfe für die Funktion:
https://support.office.com/de-de/article/Z%C3%84HLENWENNS-Funktion-dda3dc6e-f74e-4aee-88bc-aa8c2a866842?NS=EXCEL&Version=16&SysLcid=1031&UiLcid=1031&AppVer=ZXL160&HelpId=xlmain11.chm60529&ui=de-DE&rs=de-DE&ad=DE

Gruß Ralf

[Ancalon]

Ich verstehe es nicht  :22:

Ich glaube es ist einfacher wenn ich meine Datei mal zeige. 
Ich will es ehrlich verstehen!

[Jockel]

Hallo, wenn du die Kriterien vergleichbar machst geht..: (ziehbar) 

Code:

=SUMMENPRODUKT((($A3>=Termine!$B$2:$B$6)*($A3<=Termine!$C$2:$C$6))*(Termine!$D$2:$D$6=C$2))

oder..:

Code:

=ZÄHLENWENNS(Termine!$B$2:$B$6;"<="&$A3;Termine!$C$2:$C$6;">="&$A3;Termine!$D$2:$D$6;B$2)

...

Arbeitsblatt mit dem Namen 'Übersicht'
	A	B	C
2	Tag	Rüde	Hündin
3	01.01.2017	0	1
4	02.01.2017	0	1

Zelle	Formel
B3	=SUMMENPRODUKT((($A3>=Termine!$B$2:$B$6)*($A3<=Termine!$C$2:$C$6))*(Termine!$D$2:$D$6=B$2))

[Ancalon]

Hallo, wenn du die Kriterien vergleichbar machst geht..: (ziehbar) 

Code:

=SUMMENPRODUKT((($A3>=Termine!$B$2:$B$6)*($A3<=Termine!$C$2:$C$6))*(Termine!$D$2:$D$6=C$2))

oder..:

Code:

=ZÄHLENWENNS(Termine!$B$2:$B$6;"<="&A3;Termine!$C$2:$C$6;">="&A3;Termine!$D$2:$D$6;Übersicht!C$2)

...

Arbeitsblatt mit dem Namen 'Übersicht'
	A	B	C
2	Tag	Rüde	Hündin
3	01.01.2017	0	1
4	02.01.2017	0	1

Zelle	Formel
B3	=SUMMENPRODUKT((($A3>=Termine!$B$2:$B$6)*($A3<=Termine!$C$2:$C$6))*(Termine!$D$2:$D$6=B$2))

Klasse das war genau das was ich gebraucht hab !!!!  :15: