Workflows als zeitliche Übersicht

[Celtic]

Hallo zusammen,

ich möchte eine Projektübersicht (Blatt: Aufgaben) in einer zeitlichen Übersicht (Blatt: TimeSheet) abbilden.

Die Projektinformation (Projektbezeichnung und zugehöriger Task) werden mit einem eindeutigen Filter vorgegeben.
In der zeitlichen Übersicht sollen die Workflows anhand der Tasknummer und des Startdatum (Monat und Jahr) abgebildet werden.

Ich bekomme leider immer nur den ersten Workflow angezeigt und komme nicht richtig weiter.

Wie kann man das lösen, dass ein Workflow mindestens zu dem entsprechenden Startdatum (= Monat/Jahr in Überschrift) oder auch zu einem Bereich (wie im Beispiel) angezeigt wird?

Vorlage ist im Anhang.

Gruß
HaPe

[Klaus-Dieter]

Hallo,

so etwas würde ich per VBA mit einem Makro lösen, darf es so etwas sein?

[steve1da]

Hola,
in E6:

Code:

=WENNFEHLER(INDEX(Aufgaben!$E$5:$E$21;AGGREGAT(15;6;ZEILE(Aufgaben!$E$5:$E$21)-4/((Aufgaben!$C$5:$C$21=$B6)*(MONAT(Aufgaben!$F$5:$F$21)=MONAT(E$3))*(JAHR(Aufgaben!$F$5:$F$21)=JAHR(E$3)));1));"")

Nach rechts und nach unten ziehen.
Gruß,
steve1da

[slowboarder]

Hi

das hier wäre eine Möglichkeit:
Formel in TimeSheet!E6 einfügen und dann nach rechts und unten ziehen:

=TEXTVERKETTEN(";";1;FILTER(tblAufgaben[[Workflows]:[Workflows]];
(tblAufgaben[[Projektbezeichnung]:[Projektbezeichnung]]=$B6)*
(TEXT(tblAufgaben[[Start]:[Start]];"JJJJMM")<=TEXT(E$3;"JJJJMM"))*
(TEXT(tblAufgaben[[Fällig]:[Fällig]];"JJJJMM")>=TEXT(E$3;"JJJJMM"));""))

mit dieser Formel würdest du auch sehen, wenn es in einem Monat mehrere Tasks gibt.

Gruß Daniel

[Celtic]

Hallo zusammen,

besten Dank.
Wieder top hilfreiche Unterstützung.

@Klaus Dieter
VBA ist leider nicht so toll, da solche Arbeitsmappen in der Cloud Probleme machen.
Eventuell wäre die Scriptaufzeichnung mit "Automatisieren" eine Option.


Vielen Dank
Hape