Wieviel Wochen hat ein bestimmter Monat?

[ABZO]

Hallo,

Ich will herausfinden, wie viel Wochen, einschließlich angefangenen Wochen ein Monat hat.
Beispiel: 09.2024 beginnt mit Sonntag, 01.09.2024 und geht bis Montag, 30.09.2024. Er soll aber den Sonntag, 01.09.2024 sowie den Montag, 30.09.2024 als einzelne Wochen zählen. Somit komme ich für den Monat auf 6 Wochen.
Das Datum, aus welchem er den Monat beziehen soll, steht in A1.

Kennt einer eine gute Formel?

Danke
LG Mathias

[shift-del]

Moin

Für diese und weitere Fragen:
https://www.herber.de/excelformeln/src/e...la_list.pl

[ABZO]

Ehrlich gesagt finde ich da nichts.

---

Ich glaube, ich habe es.

Code:

=WAHL((DATUM(JAHR(A1);MONAT(A1)+1;1)-A1+TAG(A1)-16+REST(A1-TAG(A1)-1;7))/7;4;5;6)

Gerne können die Profis hier mal schauen, ob ich richtig liege oder ob es möglicherweise noch einen Fehler gibt.

LG Mathias

[RPP63]

Moin!
Auch ich finde Excelformeln gut.
Allerdings behaupte ich, dass die Entwicklung des Bandwurms
=WAHL((DATUM(JAHR(A1);MONAT(A1)+1;1)-A1+TAG(A1)-16+REST(A1-TAG(A1)-1;7))/7;4;5;6)
Stunden gekostet hat.
Außerdem kann man sich sowas doch niemals merken, sondern muss es entweder kopieren oder mühsam entwickeln.
Hingegen hat mich die Entwicklung meiner Formel 1 Minute gekostet.
Ihr könnt mich nachts wecken und ich ich bekomme sie immer noch auf die Kette:
=ANZAHL(EINDEUTIG(ISOKALENDERWOCHE(SEQUENZ(TAG(MONATSENDE(A1;0));;A1))))

	A	B	C
1	So 1.09.2024	6	6
2	Do 1.06.2023	5	5
3	Mo 1.02.2021	4	4

Zelle	Formel
B1	=ANZAHL(EINDEUTIG(ISOKALENDERWOCHE(SEQUENZ(TAG(MONATSENDE(A1;0));;A1))))
C1	=WAHL((DATUM(JAHR(A1);MONAT(A1)+1;1)-A1+TAG(A1)-16+REST(A1-TAG(A1)-1;7))/7;4;5;6)

Gruß Ralf

[LCohen]

Nette Formel!

Zugunsten von Excelformeln.de sei angemerkt, dass die schwierigen Formeln oft mathematisch, die einfachen abzählend formuliert sind.

[RPP63]

Danke fürs Lob!
Uns ist ja bekannt, dass alle Datum/Uhrzeit/Wochen-Formeln "simple" Mathematik darstellen.
Ich habe Hochachtung vor den Leuten, die dies in Formeln umsetzen, die es auch vor 40 Jahren schon gab.
(Du gehörst ja auch dazu!)
Dennoch prima, dass es viele neue Funktionen dem "Otto-Normal-User" einfacher machen.
Schließlich gilt "der Weg ist das Ziel" eher Philosophen.

[schauan]

Hallöchen - Ralf,

probiere mal beide Formeln mit einem aktuellen Datum, z.B. dem 17.12.2023 ... Ich bin für füneff

Arbeitsblatt mit dem Namen 'Tabelle1'
	A
11	Anzahl KW im Monat:
12	5
13	6

Zelle	Formel
A12	=WAHL((DATUM(JAHR(A1);MONAT(A1)+1;1)-A1+TAG(A1)-16+REST(A1-TAG(A1)-1;7))/7;4;5;6)
A13	=ANZAHL(EINDEUTIG(ISOKALENDERWOCHE(SEQUENZ(TAG(MONATSENDE(A1;0));;A1))))

Verwendete Systemkomponenten: [Windows (64-bit) NT 10.00] / MS Excel 365

Diese Tabelle wurde mit Tab2Html (v2.7.2) erstellt. ©Gerd alias Bamberg

[RPP63]

Das ist klar, André!
Ich nehme halt bewusst den Monatsersten als Startdatum in A1.
Natürlich kann man den auch in der Formel ermitteln.
Statt auf A1 zu verweisen, nimmt man den Ersten mittels
MONATSENDE(A1;-1)+1
also
=ANZAHL(EINDEUTIG(ISOKALENDERWOCHE(SEQUENZ(TAG(MONATSENDE(A1;0));;MONATSENDE(A1;-1)+1))))
Die Formel ist zwar länger, aber mE erheblich lesbarer als das Excel-Formeln-Pendant.

Gruß Ralf

[schauan]

Moin Ralf,

alles klar. Ich hatte gestern nur mal fix die Formel ausprobiert und das Ergebnis gesehen. Hätte ich das anderthalb Stunden später gemacht, wäre alles ok gewesen - heute ist das Ergebnis auch bei der alten Variante 5

[HKindler]

Hi,

ich wollte eigentlich gerade einwerfen, wieso man hier EINDEUTIG(...SEQUENZ(...)...) verwendet, wo es doch reicht die KW vom Monatsersten von der KW vom Monatsletzten abzuziehen. Bis mir auffiel, dass es ja noch den Jahreswechsel gibt.