Wettkampf-Tabelle - Probleme mit ZÄHLENWENN und KGRÖSSTE

[Bödefeld]

Hallo,
ich benötige für unseren Sportverein ein einfaches Excel-Programm zur Auswertung der Wettkämpfe.
Meine unfertige Tabelle (Tableau.xlsx) habe ich hier zum Verständnis mal angehangen.
Spalte E bis K ab Zeile 4 = Ergebnisse der einzelnen Teilnehmer
Feld E2 bis K2 = Anzahl der Teilnehmer
Spalte L = Gesamtergebnis des Teilnehmers

Jeder Teilnehmer kann an insgesamt 7 Wettkämpfen teilnehmen, von denen die besten 5 als Gesamtwertung addiert werden.
Hat er an weniger als an 5 Wettkämpfen teilgenommen, so werden nur die Ergebnisse der teilgenommenen Wettkämpfe addiert.
Leider funktioniert das nicht mit KGRÖSSTE, wenn er an nur 4 oder weniger Wettkämpfen teilnahm - Siehe Zeile 6.
Die Formel =KGRÖSSTE(E6:K6;1)+KGRÖSSTE(E6:K6;2)+KGRÖSSTE(E6:K6;3)+KGRÖSSTE(E6:K6;4)+KGRÖSSTE(E6:K6;5) versagt hier.

In den Feldern E2 bis K2 werden die Anzahl der Teilnehmer gezählt.
k.W. in den Feldern mit den Einzelergebnissen bedeutet, dass er teilgenommen, aber keine Wertung bekommen hat. Er muss als Teilnehmer aber gezählt werden und auf G2 müsste 3 stehen.
Die Formel =ZÄHLENWENN(G4:G20;">0") funktioniert bei Text in Feldern einfach nicht.

Wichtig ist noch, dass die Tabelle hinsichtlich der Anzahl der Starter beliebig erweiterbar sein sollte.
Da habe ich noch gar keine Lösung gefunden. Den Bereich von ZÄHLENWENN z.B. mit C:C festzulegen, scheitert an den Zeilen 1-3.

Kann mir bitte jemand helfen?

Vorab schon vielen Dank

[WillWissen]

Hi,

hier mal eine Hilfsspaltenlösung:

Tabelle2

	L	M	N	O	P	Q
3	Ges.	Hilfsspalten (ausblenden)
4	553	120	114	111	105	103
5	549	118	116	108	105	102
6	231	120	111
7	572	120	117	114	113	108
8	102	102
9	341	118	112	111

Formeln der Tabelle

Zelle Formel L4 =SUMME(M4:Q4) M4 =WENNFEHLER(KGRÖSSTE($E4:$K4;SPALTE(A1));"") N4 =WENNFEHLER(KGRÖSSTE($E4:$K4;SPALTE(B1));"") O4 =WENNFEHLER(KGRÖSSTE($E4:$K4;SPALTE(C1));"") P4 =WENNFEHLER(KGRÖSSTE($E4:$K4;SPALTE(D1));"") Q4 =WENNFEHLER(KGRÖSSTE($E4:$K4;SPALTE(E1));"")

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

Neben der Gesamtsummen-Spalte legst du die Hilfsspalten an und blendest sie einfach aus, damit sie nicht stören. Oder du legst sie auf einen Bereich außerhalb des sichtbaren. Oder auf ein separates Tabellenblatt. Die Formel schreibst du in M4 rein, ziehst sie nach rechts und nach unten.

[Bödefeld]

Danke, das ging aber schnell.

Die Hilfsspalten sind kein Problem und die Ergebnisse stimmen jetzt.
Aber leider habe ich noch keine Lösung für die Anzahl der Teilnehmer (Felder E2-K2)
Kannst Du mir da bitte auch helfen?

Vielen Dank nochmals.

[BoskoBiati]

Hallo,

zwei Möglichkeiten ohne Hilfsspalten:

Arbeitsblatt mit dem Namen 'Tabelle2'
	A	B	C	D	E	F	G	H	I	J	K	L	M
1	Ergebnisliste
2			Anzahl Wettkämpfer:		5	5	3	3	2	2	3
3	Name	Vorname	Mitgl.-Nr.	Mannschaft	01.01.	01.02.	01.03.	42475	13.05.	24.09.	05.11.	Ges.
4	AA				120	114	111	105	103		102	553	553
5	BB				116	118	102	105		108		549	549
6	CC				111	120						231	231
7	DD				114	117	k.W.		120	113	108	572	572
8	EE					102						102	102
9	FF				111			112			118	341	341

Zelle	Formel
E2	=ANZAHL2(E$4:E$500)
L4	{=SUMME(KGRÖSSTE(E4:K4;ZEILE($A$1:INDEX(A:A;MIN(5;ANZAHL(E4:K4))))))}
M4	=SUMMENPRODUKT(KGRÖSSTE(E4:K4;ZEILE($A$1:INDEX(A:A;MIN(5;ANZAHL(E4:K4)))))*1)

Achtung, Matrixformel enthalten!

Die geschweiften Klammern{} werden nicht eingegeben.

Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Edit: Dein zweites Problem auch gelöst.

[Bödefeld]

SUPER!

Alles funktioniert, wie es soll - DANKE!

PS Ich hatte zuvor schon aus den Formeln der Hilfsspalten eine ellenlange Summenformel gemacht.
Aber die ist bei weitem nicht so elegant, wie die beiden von Dir!

Dank nochmal an alle.