Werte in letzte Zeile schreiben und teile aus vorletzter Zeile kopieren

[antagon]

Moin zusammen,

Ich habe wöchentlich eine Tabelle gleicher Breite aber wechselnder Länge und ich möchte auf Knopfdruck folgende Funktion realisieren:

-> In die erste freie Zeile in der Tabelle möchte ich in A/B/I bestimmte, aber immer gleiche Werte einfügen. 
-> Aus der letzten gefüllten Zeile der Tabelle möchte ich die Werte aus M/N/O/U/X/Y/Z/AA in die erste freie Zeile kopieren/ übernehmen

In der Beispieldatei ist die Schrift in der Zeile die auf Knopfdruck erstellt werden soll rot gefärbt.

Ich habe bisher leider nur einen Code gefunden mit dem ich Werte unter meine Tabelle einfügen kann:

Cells(Cells(Rows.Count, "A").End(xlUp).Row + 1, "A").Value = "Dein neuer Wert"

[Werner.M]

Hallo,

z.B. so:

Code:

Public Sub aaa()
Dim raFund As Range

With Worksheets("Tabelle1")
   Set raFund = .Columns("A").Find(what:="*", LookIn:=xlValues, lookat:=xlWhole, searchdirection:=xlPrevious)
   If Not raFund Is Nothing Then
       .Cells(raFund.Row + 1, "A") = "00000"
       .Cells(raFund.Row + 1, "B") = "Vorschlag"
       .Cells(raFund.Row + 1, "I") = "Testvorschlag"
       .Cells(raFund.Row + 1, "M") = .Cells(raFund.Row, "M")
       .Cells(raFund.Row + 1, "N") = .Cells(raFund.Row, "N")
       .Cells(raFund.Row + 1, "O") = .Cells(raFund.Row, "O")
       .Cells(raFund.Row + 1, "U") = .Cells(raFund.Row, "U")
       .Cells(raFund.Row + 1, "X") = .Cells(raFund.Row, "X")
       .Cells(raFund.Row + 1, "Y") = .Cells(raFund.Row, "Y")
       .Cells(raFund.Row + 1, "Z") = .Cells(raFund.Row, "Z")
       .Cells(raFund.Row + 1, "AA") = .Cells(raFund.Row, "AA")
   End If
End With

Set raFund = Nothing
End Sub

Gruß Werner

[antagon]

Super, funktioniert :). Vielen Dank!

[antagon]

Gibt es die Möglichkeit im gleichen Atemzug die Zelle "A" als Text zu formatieren, so dass die gesamte Anzahl der Nullen erhalten bleibt und nicht nur eine?

[Werner.M]

Hallo,

so:

Code:

If Not raFund Is Nothing Then
   .Cells(raFund.Row + 1, "A").NumberFormat = "00000"
   .Cells(raFund.Row + 1, "A") = 0

Gruß Werner

[antagon]

Super, vielen Dank und frohes Fest