Werte aus einer Matrix mit Bedingungen in Liste kopieren

[AnnaBauer92]

Hallo zusammen,

leider bin ich nicht so geschickt im Umgang mit Excel wie die meisten hier und nun habe ich das folgende Problem:
Ich habe zwei Blätter, im ersten Blatt soll man drei Variablen auswählen können, daraufhin soll dann eine Liste erstellt werden.
Diese Liste soll sich auf die Matrix in Blatt 2 beziehen, das heißt überall dort wo ein "x" gesetzt ist, soll der Eintrag der in Spalte c ist, in die Liste auf Blatt 1 übernommen werden.
Kann mir hierbei jemand helfen? Hoffentlich habe ich das jetzt nicht zu kompliziert geschrieben, aber eine Beispieldatei hängt an.

Wäre echt toll wenn mich jemand in die richtige Richtung leiten könnte.

Vielen Dank
Eure Anna

[Elex]

Hi Anna,

aber eine Beispieldatei hängt an.

Bitte noch auf Attachment hinzufügen klicken.

Gruß Elex

[AnnaBauer92]

Hups, sorry :)

[steve1da]

Hola,

Code:

=WENNFEHLER(INDEX(Matrix!$C$6:$C$9;AGGREGAT(15;6;ZEILE($A$6:$A$9)-5/((Matrix!$D$3:$F$3=$D$4)*(Matrix!$D$4:$F$4=$D$5)*(Matrix!$D$5:$F$5=$D$6)*(Matrix!$D$6:$F$9="x"));ZEILE(A1)));"")

Gruß,
steve1da

[AnnaBauer92]

Hey steve1da,

sehr cool, danke für die schnelle Rückmeldung, funktioniert einwandfrei :)
Eine Frage zum Verständniss, wofür sind die Zellen ohne Inhalt in der Formel enthalten?
Zellen A6:A9 und A1?

Nochmal vielen Dank :)

LG
Anna

[Elex]

Hi

wofür sind die Zellen ohne Inhalt in der Formel enthalten?

hier in #30 findest du etwas Erklärung dazu.
https://www.clever-excel-forum.de/thread...#pid136442

Gruß Elex

[neopa]

Hallo Anna,

eine Erklärung zu Deiner letzten Fragestellung hat Dir Elex schon geliefert. Wenn Du Dich damit etwas mehr auseinandersetzt, könntest Du möglicherweise auch darauf stoßen, dass die Formel von steve1da voraussetzt, dass Deine Datenstruktur in Deinem Tabellenblatt "Auswahltabelle" immer genauso erhalten bleibt, wie von Dir aufgezeigt. D.h. dass Du z.B. keine Zeile vor Zeile 6 einfügst oder löschst. Aber wer will/kann dass schon immer von vornherein ausschließen?

Ich würde deshalb z.B. zu folgender Formel in C11 raten:

Code:

=WENNFEHLER(INDEX(Matrix!C:C;AGGREGAT(15;6;ZEILE(Matrix!C$6:C$9)/
(Matrix!D$3:F$3&Matrix!D$4:F$4&Matrix!D$5:F$5=D$5&D$6&D$7)/(Matrix!D$6:F$9="x");ZEILE()-ZEILE(C$10)));"")

Darin ergibt der Formelteil...ZEILE(Matrix!C$6:C$9)... die gleiche Zahlenmatrix {6;7;8;9} wie sie auch ... ZEILE(A$6:A$9) ...ergibt, aber sie bleibt konstant erhalten, auch wenn eine Zeile vor Zeile 6 eingefügt wird und wird somit auch dann noch ein korrektes Ergebnis liefern, was bei der anderen Formel nicht gegeben ist.

Analog zu betrachten ist, dass ich in meiner Formel den "Zähler" ZEILE(A1) durch ZEILE()-ZEILE(C$10) ersetzt habe.  Der Formelteil =ZEILE() in eine beliebige Zelle eingesetzt, ergibt immer die aktuelle Zellennummer der Zelle. Also in Deinem Fall eingesetzt in C11 also die 11. Davon ZEILE(C$10) subtrahiert ergibt in C11 also =11-10  ...  in C13= 13-10.

Mein diesbzgl. Formelteil hat zwar den kleinen Nachteil, dass diese 2mal die Funktion ZEILE benötigen und somit auch etwas länger als nur ZEILE(A1) ist. Sie bietet aber den Vorteil, dass Du auch ohne Formeländerung nachträglich vor Zeile 1 Zeilen einfügen oder gar die Zeile 1 problemlos löschen kannst, was bei der anderen Formel nicht gewährleistet ist.

Meine Empfehlung also: Probier es einfach selbst aus und entscheide danach, ob es für Dich wichtig ist oder nicht.