Werte Ermitteln und Ausgeben

[Lennox]

Hallo Andreas,

super das ist genau das was ich gesucht habe. 

Ich habe versucht den Bereich zu erweitern, kann es sein das dieses über Zeile 1000 nicht möglich ist? Ich habe die Formel folgendermaßen abgeändert da mein Bereich bis 1300 geht.



{=WENNFEHLER(INDEX($B$943:$B$1300;KKLEINSTE(WENN($D$943:$D$1300=$BD$943;ZEILE($1:$57));ZEILE(A1)));"")}

Leider ohne Erfolg.

Auch diese Variante habe ich ausprobiert auch ohne Erfolg. 

{=WENNFEHLER(INDEX($B$143:$B$999;KKLEINSTE(WENN($D$143:$D$999=$BD$943;ZEILE($1:$57));ZEILE(A1)));"")}

Mach ich was falsch oder sehe ich den Wald vor Bäumen nicht?


Vielen Dank für deine Mühe.

Gruß
Michael

[steve1da]

Hola,

Code:

=WENNFEHLER(INDEX($B$943:$B$1300;KKLEINSTE(WENN($D$943:$D$1300=$BD$943;ZEILE($1:$358));ZEILE(A1)));"")

Wichtig ist, den Teil bei Zeile(.....) mit anzupassen! Von B943 bis B1300 sind es 358 Zeilen, dass wird duch ZEILE($1:$358) mitgeteilt. Veränderst du den Bereich, musst du das auch anpassen.

Gruß,
steve1da

[Lennox]

Hallo steve1da,

stimmt, da hab ich tatsächlich den Wald vor Bäumen nicht gesehen. Danke für deine Mühe. 

Zur Zeit überlege ich ob es möglich ist das ganze andersherum anzugehen. Ich glaube aber das dieses meiner Meinung nach nicht zu realisieren ist. Nun meine Tabelle ist ja hier hochgeladen! Wäre es möglich eine Formel so zu schreiben das wenn ich einen Datumsbereich eingebe mir alle Namen die in diesen Bereich fallen ausgeben zu lassen? Meine Kenntnisse sind da eher bescheiden. 

Gruß 
Michael

[Schachspieler]

Hallo Michael,

funktioniert nach dem gleichen Prinzip (gleicher Link) - nur, dass du nun eine Hilfsspalte brauchst, um die Fälle identisch zu markieren (BC) - Frage ist, ob du die Namen mehrfach gelistet werden sollen (Ergebnis1) oder nicht (Ergebnis2). Formeln wie immer Bereiche anpassen  - auch Zeile() - und nach unten ziehen.
Es weiß übrigens nur der Himmel, warum du in Zeile 943 anfängst.



Blatt1

	BC	BD	BE	BF	BG	BH
1					Beginn	Ende
2	HilfFormel	Ergbnis1	Ergebnis2		09.01.2018	14.01.2018
943		Willems	Willems
944		Edrich	Edrich
945		Edrich	Klöfer
946		Klöfer
947		Klöfer

Formeln der Tabelle

Zelle Formel BC943 =WENN(UND(B943>=$BG$2;B943<=$BH$2);"x";"") BD943 {=WENNFEHLER(INDEX($D$943:$D$999;KKLEINSTE(WENN($BC$943:$BC$999="x";ZEILE($1:$57));ZEILE(A1)));"")} BE943 =INDEX($D$943:$D$999;VERGLEICH("x";$BC$943:$BC$999;)) BE944 {=WENN(MAX(WENN(ISTNV(VERGLEICH($D$943:$D$999;BE$943:BE943;))*($BC$943:$BC$999="x");ZEILE($1:$57)))=0;"";INDEX($D$943:$D$999;MIN(WENN(ISTNV(VERGLEICH($D$943:$D$999;BE$943:BE943;))*($BC$943:$BC$999="x");ZEILE($1:$57)))))} BE945 {=WENN(MAX(WENN(ISTNV(VERGLEICH($D$943:$D$999;BE$943:BE944;))*($BC$943:$BC$999="x");ZEILE($1:$57)))=0;"";INDEX($D$943:$D$999;MIN(WENN(ISTNV(VERGLEICH($D$943:$D$999;BE$943:BE944;))*($BC$943:$BC$999="x");ZEILE($1:$57)))))} BE946 {=WENN(MAX(WENN(ISTNV(VERGLEICH($D$943:$D$999;BE$943:BE945;))*($BC$943:$BC$999="x");ZEILE($1:$57)))=0;"";INDEX($D$943:$D$999;MIN(WENN(ISTNV(VERGLEICH($D$943:$D$999;BE$943:BE945;))*($BC$943:$BC$999="x");ZEILE($1:$57)))))} BE947 {=WENN(MAX(WENN(ISTNV(VERGLEICH($D$943:$D$999;BE$943:BE946;))*($BC$943:$BC$999="x");ZEILE($1:$57)))=0;"";INDEX($D$943:$D$999;MIN(WENN(ISTNV(VERGLEICH($D$943:$D$999;BE$943:BE946;))*($BC$943:$BC$999="x");ZEILE($1:$57)))))}

Enthält Matrixformel: Umrandende { } nicht miteingeben, sondern Formel mit STRG+SHIFT+RETURN abschließen!

Matrix verstehen

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4

[Lennox]

Hallo Andreas,

super vielen Dank dafür. 

Ich fange in Zelle 943 an weil die Zellen darüber die sogenannten Altlasten (Daten aus früheren Jahren) enthalten. Ich geh da am WE mal ran und lösch die alten Daten.



Gruß
Michael