Wert aus Bereich einer Tabelle auslesen?

[Busfahrer]

Hallo!

zur Analyse von Artikelnummern möchte ich gerne einen bestimmten Wert aus einem Bereich einer Tabelle herauslesen.

In anliegender Datei ist Tabelle 1 die Liste der Artikelnummern. Die Länge der Nummern ist konstant 20 Zeichen.

Nun möchte ich aus der Tabelle 2 einen Wert heraussuchen, der in einem "Bereich" von Tabelle 2 ist. Der "Bereich" von Tabelle 2 wird bestimmt durch die ersten 3 Ziffern der Artikelnummer in Tabelle 1 (ein Beispiel hab ich mal farbig markiert). Der genaue Wert wird dann durch die Stellen 14-17 der Artikelnummer bestimmt.

Hintergrund: die Zahlen in Spalte B kommen öfter vor, sprich: sind nicht eindeutig. Sie werden nur in Zusammenhang mit der Buchstabenkombination in Spalte A eindeutig.

Gibt es hierfür eine Funktion? Ich habe mich schonmal in die Hilfe eingelesen, aber fand nichts passendes...

Ich hoffe, dass diese Informationen ausreichen - falls ich was übersehen habe, bitte Bescheid geben, werd ich umgehend nachreichen.


Danke und Grüsse, Busfahrer

[steve1da]

Hola,

Code:

=SVERWEIS(TEIL(A9;14;4);Tabelle2!B:C;2;0)

Gruß,
steve1da

[Busfahrer]

Hallo!

das würde ja nur den allerersten Wert aus der Tabelle holen - wie bereits erwähnt, wiederholen sich diese Werte aber.
Ich muss sicherstellen, dass nur in dem durch die ersten 3 Buchstaben der Artikelnummer definierten Bereich von Tabelle 2 gesucht wird.

Danke und Grüsse, Busfahrer

[steve1da]

Hola,

sorry, überlesen:

Code:

=VERWEIS(2;1/(Tabelle2!$A$1:$A$49&Tabelle2!$B$1:$B$49=LINKS(A9;3)&TEIL(A9;14;4));Tabelle2!$C$1:$C$49)

Gruß,
steve1da

[Busfahrer]

Hallo!

danke, so scheints zu klappen.
Könnte ich dich bitten, noch 1-2 erklärende Worte zur Syntax loszuwerden? Ich würde gerne schlauer werden, statt nur blöde abzuschreiben, und die Hilfe ist in diesem Fall recht dürftig. Sie sagt zur Syntax nur:

VERWEIS(Suchkriterium, Suchvektor, [Ergebnisvektor])


Dein Code:
=VERWEIS(2;1/(Tabelle2!$A$1:$A$49&Tabelle2!$B$1:$B$49=LINKS(A9;3)&TEIL(A9;14;4));Tabelle2!$C$1:$C$49)


"Tabelle2!$C$1:$C$49" scheint der Ergebnisvektor zu sein, das ist mir soweit klar, was das macht, denke ich.


"1/(Tabelle2!$A$1:$A$49&Tabelle2!$B$1:$B$49=LINKS(A9;3)&TEIL(A9;14;4))" ist scheinbar der Suchvektor. Oder?

- was macht das "1/" am Anfang?
- "Tabelle2!$A$1:$A$49" verstehe ich, aber warum ist das mit einem "&" mit "Tabelle2!$B$1:$B$49" verkettet?
- "LINKS(A9;3)&TEIL(A9;14;4)" scheint mir eher das Suchkriterium zu sein?


Was ist mit der "2" ganz am Anfang? sollte das nicht das Suchkriterium sein?


Für ein paar erklärende Worte wäre ich sehr dankbar! Komme mir grad recht doof vor...
Grüsse, Busfahrer

[steve1da]

Hola,

hier ist das gut erklärt:
http://www.herber.de/forum/archiv/1224to...ktion.html

Gruß,
steve1da

[BoskoBiati]

Hi,

oder  so:

Code:

=WENNFEHLER(INDEX(Tabelle2!C:C;AGGREGAT(15;6;ZEILE($C$1:$C$100)/(Tabelle2!$A$1:$A$100=LINKS(A3;3))/(Tabelle2!$B$1:$B$100=TEIL(A3;14;4));1));"")

[Busfahrer]

Hallo zusammen!

@steve1da : vielen Dank für den Link. Ich habs gelesen, aber bin mir noch nicht 100%ig sicher, ob ich s auch korrekt verstanden habe. Meine derzeitige Vermutung ist, dass man die "2" am Anfang sozusagen als "Universalreferenz" nimmt, weil in den Feldern, in denen die Formel nach Ergebnissen sucht, eh keine Zahlen drin sind, und die VERWEIS-Funktion daher nur die "2" finden würde, weil die "kleiner" als die Buchstaben sind (?).

Macht aber nix - da komme ich schon noch dahinter, Danke auf jeden Fall für diese Lösung. ;)

@BoskoBiati : danke für deinen Vorschlag. Mit INDEX und AGGREGAT hatte ich bisher noch nicht so viel zu tun - werde ich mir bei Gelegenheit aber mal zu Gemüte führen, schadet mir sicher auch nicht.



Grüsse, Busfahrer

[BoskoBiati]

Hi,

statt 2 könnte da jede beliebige Zahl größer 1 stehen, da 1/ entweder eine Zahl <1 oder #Div/0 ergibt. Der Verweis sucht dann nach der 2 oder was auch immer, wenn er sie nicht findet, nimmt er die letzte Zahl aus dem Ergebnisvektor. Formelauswertung hilft!

[Busfahrer]

Hallo!

hier noch ergänzende Info zu diesem Thema:

1. Im Prinzip funktioniert die vorgeschlagene Lösung mit dem VERWEIS wunderbar - sogar, wenn man statt 2 mehr Kriterien abfragen möchte, Formel dann halt entsprechend anpassen.

2. Es gibt auch noch eine andere, "einfachere" Möglichkeit: man muss lediglich neben der Tabelle, in der man die 2 oder mehr Werte suchen will, eine neue Spalte einfügen, in die man mit einem "&" die zu durchsuchenden Spalten zusammenfasst. Daraus wird dann eine Spalte mit längeren, aber eindeutigen Werten - und diese Spalte kann man dann mit einem gewöhnlichen SVERWEIS ansprechen.

3. Schwerzhaft musste ich erfahren, dass VERWEIS ein Limit hat - diese Funktion kann nur 40.000 Zeilen oder so verarbeiten. Sind es mehr (so wie bei mir ca. 50.000 Zeilen), wirft die Funktion nur Blödsinn (#NV) aus, und man sucht sich einen halben Tag lang die Augen wund, was man denn wieder verbockt hat - weil es ja in mit der gleichen Formel in einer Beispieldatei (mit nur mal schnell cecopypasteten 2000 Werten) wunderbar klappte. Vielen Dank an den wie üblich einprogrammierten, nichtabschaltbaren Idiotenmodus von Microsoft, der immer schlauer sein will als der Benutzer und nicht wie ein vernünftiges Programm auch mal eine verwendbare Fehlermeldung ausgibt... ;)

Nochmals danke für die Hilfe!
Grüsse, Busfahrer