Dieses Forum nutzt Cookies
Dieses Forum verwendet Cookies, um deine Login-Informationen zu speichern, wenn du registriert bist, und deinen letzten Besuch, wenn du es nicht bist. Cookies sind kleine Textdokumente, die auf deinem Computer gespeichert werden. Die von diesem Forum gesetzten Cookies werden nur auf dieser Website verwendet und stellen kein Sicherheitsrisiko dar. Cookies aus diesem Forum speichern auch die spezifischen Themen, die du gelesen hast und wann du zum letzten Mal gelesen hast. Bitte bestätige, ob du diese Cookies akzeptierst oder ablehnst.

Ein Cookie wird in deinem Browser unabhängig von der Wahl gespeichert, um zu verhindern, dass dir diese Frage erneut gestellt wird. Du kannst deine Cookie-Einstellungen jederzeit über den Link in der Fußzeile ändern.

Wenn dann mit Ergebnis "FALSCH" wenn Bedingung nicht zutrifft
#1
Hallo zusammen,

ich hab eine verschachtelte wenn dann und Excel spuckt mir den Wert korrekt aus, wenn die erste Bedingung zutrifft, wenn sie nicht zutrifft, dann schreibt er immer falsch. Hier die Formel, bitte nicht erschlagen lassen:

=WENN(SUMME(N3:O3)<8;O3*WENN(B3="Wochentag";SVERWEIS(C3;'Rates Arbeitszeit'!A:J;2;FALSCH);WENN('Berechnung NEU'!B3="Wochenende";SVERWEIS('Berechnung NEU'!C3;'Rates Arbeitszeit'!A:J;5;FALSCH);WENN('Berechnung NEU'!B3="Feiertag";SVERWEIS('Berechnung NEU'!C3;'Rates Arbeitszeit'!A:J;8;FALSCH);WENN(SUMME(N3:O3)>8<10;O3*WENN(B3="Wochentag";SVERWEIS(C3;'Rates Arbeitszeit'!A:J;3;FALSCH);WENN('Berechnung NEU'!B3="Wochenende";SVERWEIS('Berechnung NEU'!C3;'Rates Arbeitszeit'!A:J;6;FALSCH);WENN('Berechnung NEU'!B3="Feiertag";SVERWEIS('Berechnung NEU'!C3;'Rates Arbeitszeit'!A:J;9;FALSCH);WENN(SUMME(N3:O3)>=10;O3*WENN(B3="Wochentag";SVERWEIS(C3;'Rates Arbeitszeit'!A:J;4;FALSCH);WENN('Berechnung NEU'!B3="Wochenende";SVERWEIS('Berechnung NEU'!C3;'Rates Arbeitszeit'!A:J;7;FALSCH);WENN('Berechnung NEU'!B3="Feiertag";SVERWEIS('Berechnung NEU'!C3;'Rates Arbeitszeit'!A:J;10;FALSCH)))))))))))))

Ich habe die Formel testhalber in folgende drei Teile aufgeteilt:

=WENN(SUMME(N3:O3)<8;O3*WENN(B3="Wochentag";SVERWEIS(C3;'Rates Arbeitszeit'!A:J;2;FALSCH);WENN('Berechnung NEU'!B3="Wochenende";SVERWEIS('Berechnung NEU'!C3;'Rates Arbeitszeit'!A:J;5;FALSCH);WENN('Berechnung NEU'!B3="Feiertag";SVERWEIS('Berechnung NEU'!C3;'Rates Arbeitszeit'!A:J;8;FALSCH)))))

=WENN(SUMME(N3:O3)>8<10;O3*WENN(B3="Wochentag";SVERWEIS(C3;'Rates Arbeitszeit'!A:J;3;FALSCH);WENN('Berechnung NEU'!B3="Wochenende";SVERWEIS('Berechnung NEU'!C3;'Rates Arbeitszeit'!A:J;6;FALSCH);WENN('Berechnung NEU'!B3="Feiertag";SVERWEIS('Berechnung NEU'!C3;'Rates Arbeitszeit'!A:J;9;FALSCH)))))

und

=WENN(SUMME(N3:O3)>=10;O3*WENN(B3="Wochentag";SVERWEIS(C3;'Rates Arbeitszeit'!A:J;4;FALSCH);WENN('Berechnung NEU'!B3="Wochenende";SVERWEIS('Berechnung NEU'!C3;'Rates Arbeitszeit'!A:J;7;FALSCH);WENN('Berechnung NEU'!B3="Feiertag";SVERWEIS('Berechnung NEU'!C3;'Rates Arbeitszeit'!A:J;10;FALSCH);""))))

Die dritte Bedingung (die Summe N3 bis O3 ist größer 10), insofern spuckt Excel da einen Wert raus, bei den ersten beiden kommt als Ergebnis "FALSCH" - ich denke, es ist ein Klammerproblem, aber ich weiß nicht, welches. Kann jemand helfen?

Ich danke euch!
Antworten Top
#2
=WENN(SUMME(N3:O3)<8;
O3*WENN(B3="Wochentag";SVERWEIS(C3;'Rates Arbeitszeit'!A:J;2;FALSCH);
WENN('Berechnung NEU'!B3="Wochenende";SVERWEIS('Berechnung NEU'!C3;'Rates Arbeitszeit'!A:J;5;FALSCH);
WENN('Berechnung NEU'!B3="Feiertag";SVERWEIS('Berechnung NEU'!C3;'Rates Arbeitszeit'!A:J;8;FALSCH);

WENN(SUMME(N3:O3)>8<10;
O3*WENN(B3="Wochentag";SVERWEIS(C3;'Rates Arbeitszeit'!A:J;3;FALSCH);
WENN('Berechnung NEU'!B3="Wochenende";SVERWEIS('Berechnung NEU'!C3;'Rates Arbeitszeit'!A:J;6;FALSCH);
WENN('Berechnung NEU'!B3="Feiertag";SVERWEIS('Berechnung NEU'!C3;'Rates Arbeitszeit'!A:J;9;FALSCH);

WENN(SUMME(N3:O3)>=10;
O3*WENN(B3="Wochentag";SVERWEIS(C3;'Rates Arbeitszeit'!A:J;4;FALSCH);
WENN('Berechnung NEU'!B3="Wochenende";SVERWEIS('Berechnung NEU'!C3;'Rates Arbeitszeit'!A:J;7;FALSCH);
WENN('Berechnung NEU'!B3="Feiertag";SVERWEIS('Berechnung NEU'!C3;'Rates Arbeitszeit'!A:J;10;FALSCH)))))))))))))

kann man so (zusammen kursiv!) auch mit den optischen Hilfen als Absätze in eine Zelle eingeben (!).
  • SUMME(N3:O3)>8<10 ist jedoch unzulässig: ABS(SUMME(N3:O3)-9)<1 wäre korrekt
  • =8 kommt bei Dir nicht vor! (ist unten ebenfalls repariert)
Nun zur Abkürzung 1:

=O3*WENN(B3="Wochentag";SVERWEIS(C3;'Rates Arbeitszeit'!A:J;1+VERGLEICH(SUMME(N3:O3);{0.8.10}););
WENN('Berechnung NEU'!B3="Wochenende";SVERWEIS('Berechnung NEU'!C3;'Rates Arbeitszeit'!A:J;4+VERGLEICH(SUMME(N3:O3);{0.8.10}););
WENN('Berechnung NEU'!B3="Feiertag";SVERWEIS('Berechnung NEU'!C3;'Rates Arbeitszeit'!A:J;7+VERGLEICH(SUMME(N3:O3);{0.8.10});)))
  • Dein B3 sieht uneinheitlich aus. 
  • Außerdem geht noch mehr Verkürzung (Abkürzung 2):
=O3*SVERWEIS(C3;'Rates Arbeitszeit'!A$1:J$9999;3*VERGLEICH(B3;{"WT"."WE"."FT"};)+VERGLEICH(SUMME(N3:O3);{0.8.10})-2;)
  • ich habe die Wochentag-Beschriftungen hier als verkürzbar angenommen (WT statt Wochentage)
  • ich habe A:J verkürzt für Performance; nötig wegen SVERWEIS(;;;FALSCH)
[-] Folgende(r) 1 Nutzer sagt Danke an LCohen für diesen Beitrag:
  • tessa
Antworten Top
#3
ist ja der Knaller! Total verrückt - und so schnell - Chapeau!!!
Vielen herzlichen Dank!
Antworten Top


Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste