WENNS Formel verkürzen?

[falkenhorst72]

Hallo zusammen,

ich würde gerne wissen, ob man eine "WENNS" Formel auch verkürzter darstellen kann. Beispiel Datei hab ich angehängt.

Thema ist: 

Im Reiter "Tabelle 1" in A5 wähle ich eine Überschrift und in der Spalte C erscheinen die jeweiligen Kontrollpunkte zu diesem Thema.

In der Zelle "C5" ist die WENNS-Formel, die mir aber zu lang wird.

Im Reiter "Tabelle 2" hab ich die Auswahl.

Gibt es da 'ne Möglichkeit, die ich auch verstehe? Ich bin nicht so versiert mit Excel, als dass ich jetzt VBA oder Pivot könnte 

Wäre dankbar für jede brauchbare Hilfe 

MfG - Falke

[HKindler]

Hi,

du gibst zwar als Version 2010 an, benutzt aber WENNS und Spilling. Daher gehe ich davon aus, dass du ein aktuelles Excel hast.

Dann geht z.B.
=XVERWEIS(A5;Tabelle2!$A$1:$X$1;Tabelle2!$2:$100)

Wenn dich die vielen Nullen am Ende stören, geht auch
=WEGLASSEN(EINDEUTIG(XVERWEIS(A5;Tabelle2!$A$1:$X$1;Tabelle2!$2:$100));-1)

[falkenhorst72]

Servus HKindler,

sorry aber muss ich noch irgendwo in deinen zwei Formelmöglichkeiten etwas eintragen? Denn wenn ich es so eingebe bekomme ich in C5 das Ergebnis "#WERT!" 

[HKindler]

Hi,

wenn ich die zweite Formel in meinem Excel365 in deiner Beispieltabelle in C5 eingeben, bekomme ich genau die selben Werten wie sie deine WENNS-Formel ausspukt.
Welche Excelversion hast du denn?

Sorry Kommando zurück. Die Formel muss lauten
=WEGLASSEN(EINDEUTIG(XVERWEIS(A5;Tabelle2!$A1:$X1;Tabelle2!$A$2:$X$100));-1)

So was kommt vor, wenn man zunächst ganze Zeilen vorgibt und sich dann überlegt, dass das nur unnötig viel Rechenkapazität verbraucht.
Ich würde dir sowieso vorschlagen in deiner Tabelle2 mit einer Strg-T-Tabelle zu arbeiten. Dann erledigt sich das Bereichsproblem von selbst.

[falkenhorst72]

Cool, hat geklappt. Jetzt hab ich die Tabelle formatiert und der Tabelle den Namen "Sanitär1" gegeben (siehe Anhang).

Inwiefern kann ich die Bereichswerte ändern?

[HKindler]

Hi,

=WEGLASSEN(EINDEUTIG(XVERWEIS(A5;Sanitär1[#Kopfzeilen];Sanitär1));-1)

Allerdings solltest du deiner Sanitär-Tabelle am Ende eine Leerzeile verpassen, da sonst bei "Brunnenanlagen" der letzte Punkt fehlt. Oder du verwendest einfach nur den XVERWEIS und formatierst die Ausgabe-Zellen mit dem Format ";;;@"

[BoskoBiati]

Hi,

da reicht bei Deiner Version auch diese Formel:

Code:

=FILTER(Sanitär1;Sanitär1[#Kopfzeilen]=A5)

Bei der Art von Tabelle passt sich die Formel dem Bereich an.

[falkenhorst72]

Top, danke dir Helmut, das passt super grad 

Ich wusste doch, dass ich hier Hilfe finde, ihr seid alle TOP 

[HKindler]

da reicht bei Deiner Version auch diese Formel:

Code:

=FILTER(Sanitär1;Sanitär1[#Kopfzeilen]=A5)

Auch wieder wahr. Gefällt mir besser.
Allerdings hat die Formel dasselbe Problem wie die reine XVERWEIS-Formel: Die leeren Zellen am Ende werden mit dem Wert 0 ausgegeben. Aber das ist ein allgemeines Excel-Problem.

Noch ein kleiner Trick: einfach die 0-en wegfiltern:
=LET(x;FILTER(Sanitär1;Sanitär1[#Kopfzeilen]=A5);FILTER(x;x<>0))

Oder sogar die Leerzellen:
=LET(x;FILTER(Sanitär1;Sanitär1[#Kopfzeilen]=A5);FILTER(x;x<>""))

[EA1950]

Hallo,

das Problem mit den Nullen am Ende der Auflistung kann leicht beseitigt werden:
=ABSCHNBEREICH(XVERWEIS($A$5;Sanitär1[#Kopfzeilen];Sanitär1);2)
oder
=ABSCHNBEREICH(FILTER(Sanitär1;Sanitär1[#Kopfzeilen]=$A$5);2)