Verschiedene Margen Sätze in Preiskalkulation einbauen

[Niki1001]

Liebe Leute, ich brauche wiedermal eure wertvolle Hilfe.

Ich habe ellenlange Händlerpreislisten mit Einkaufspreisen. Daraus errechne ich über die Marge meine End-verkaufs-preis.
Nun habe ich Artikel welche sehr günstig sind, da brauche ich eine Marge von 50%. Nun gibt es aber auch Produkte welche weit über 1000 Euro kosten, da genügt eine kleinere Marge.
Nun suche ich eine Formel mit 3 verschiedenen Margen

Marge 1 = bis 100 Euro Verkaufspreis (VP)= Marge 50 %
Marge 2 = ab 100 Euro VP = Marge 45 %
Marge 3 = ab 1000 Euro VP = Marge 40%

bis jetzt sieht meine Formel zum errechnen des VP inkl Mwst. so aus:

=RUNDEN((C2+(C2/100*$E$3)*2)*(1+$H$3/100)*2;1)/2

C= EP (Einkaufspreis)
E= Marge 1
H= MwSt. Satz

Schon die oben aufgeführte Formel war für mich eine riesen Herausforderung. wie nun dort auch noch eine "if this than what ever" Formel einzubauen geht definitiv weit über meine Fähigkeiten heraus.
Deshalb bitte ich Euch um Hilfe

Also wenn der VP bis 100 Euro ist dann Marge 1
wenn ab 100 Euro dann Marge 2
ab 1000 Euro Marge 3

Herzlichen Dank zum vorraus!

[steve1da]

Hola,

Code:

=wenn(Zelle_mit_VP<100;Marge1;wenn(Zelle_mit_VP<1000;Marge2;Marge3))

Gruß,
steve1da

[Dieter63]

Hallo ,

mach dir ne kleine Verweis Tabelle, dann bist du flexibler

VK Preis ab    Marge
      0            50%
    100          45%
   1000         40%

Marge =  Verweis(VkPreis, Tabelle)

[Niki1001]

Hallo steve1da

Vielen Dank für Dein Input. Meine grosse Schwierigkeit ist aber wie kombiniere ich deine Formel mit meiner bestehenden Formel:

=wenn(Zelle_mit_VP<100;Marge1;wenn(Zelle_mit_VP<1000;Marge2;Marge3))

mit

=RUNDEN((C2+(C2/100*$E$3)*2)*(1+$H$3/100)*2;1)/2

[Niki1001]

Hi

Habe ich das nicht schon gemacht mit meinen Spalten E F und G? Dort würde ich jeweils die entsprechenden Margen reinschreiben.

[Jockel]

Hallo, was erwartest du denn für die beiden Beispiele für Ergebnisse..? Also die 630 wie setzten die sich zusammen..? Deine Formel kann ich nicht nachvollziehen...

die Marge könnte man so berechnen..:

=C2*WVERWEIS(C2;E2:G3;2;1)%

hier mal zur Errechnung der MargenVorgabe mit steve1da's Formel und meiner ..:

Arbeitsblatt mit dem Namen 'Tabelle2'
	P	Q
2	45	45

Zelle	Formel
P2	=WENN(C2<100;E3;WENN(C2<1000;F3;G3))
Q2	=WVERWEIS(C2;$E$2:$G$3;2;1)

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[LCohen]

Mit

=A1*1,19*VERWEIS(A1;{0.57,95.600,24};{1,5.1,45.1,4})

gibt es Überlappungen an den Margenübergängen, also im Grunde 2 VKbrutto-Werte zu 1 EKnetto-Wert. 56 und 58 EK haben aufgrund des Margensprunges also fast den gleichen VK, und 57 ergibt einen höheren als beide.

Die folgende Funktion hingegen ist eineindeutig (also auch vom VK Richtung EK umstellbar)

=SUMMENPRODUKT((A1>{0.56.578})*(A1-{0.56.578})*({1,5.1,45.1,4}-{0.1,5.1,45})*1,19)

und weicht von Deinen Grenzen nur wenige Cent ab, die man aber auch noch killen kann:

=RUNDEN(SUMMENPRODUKT((A1>{0.56,024.577,61})*(A1-{0.56,024.577,61})*({1,5.1,45.1,4}-{0.1,5.1,45})*1,19);2)

Erläuterung: ({1,5.1,45.1,4}-{0.1,5.1,45}) gibt Deine Margen wieder. Das mögliche Zusammenschieben auf {1,5.-0,05.-0,05} bringt keine Punkte für Übersichtlichkeit - und man kann die Konstanten dann nicht selbstsprechend in Zellen auslagern!

[Jockel]

Hallo, ich habe so..:

PHP-Code:

=DM((C2*WVERWEIS(C2;$E$2:$G$3;2;1)%+C2)*(1+H3%))*1 


[LCohen]

Das entspricht meiner ersten Formel mit den genannten Nichteindeutigkeiten.

[Jockel]

Hallo, das mag ja sein, aber ist ja nicht abgeschrieben und evtl. leichter nachvollziehbar...