Verschachtelte Logik!

[lapunta]

Ich sitze gerade an einem Problem.

Ich habe eine Tabelle mit immer 5 Werten (x1 bis x5). Jetzt soll mir Excel für einen Wertebereich eine bestimmte Ziffer in eine Zelle ausgeben die anschliessend zu einer 5 stelligen Kennzahl zusammengefügt werden sollen.

Klingt vielleicht eiin bißchen abstrakt. Deshalb habe ich das Ganze, zur besseren Erläuterung, mal als Bild angehängt und zwei Reihen "zu Fuß" gemacht. Ich denke wer ein bißchen mathematisch versiert ist, wird das Problem erkennen.

Läuft ja im Prinzip auf eine wenn-dann-sonst Abfrage hinaus.

Jetzt erst einmal zwei prinzipielle Fragen dazu:

1. VBA oder Funktion. Was ist besser? Wobei ich zur VBA-Lösung tendierte.

2. Gibt es irgenwo im Netz Beispieldateien zum herunterladen, damit man sich das Ganze mal prakzisch anschauen kann?

Im Voraus vielen Dank!

[Käpt'n Blaubär]

Hallo,

Gibt es irgenwo im Netz Beispieldateien zum herunterladen, damit man sich das Ganze mal prakzisch anschauen kann?

ja, gibt es .... das ganze WEB ist voller Bilder. :05:

Mit Bildern will hier eigentlich niemand arbeiten. Aus Bildern läßt sich auch keine Exceldatei erstellen. Folglich ist sowas
nicht wirklich hilfreich beim Helfen.

[Rabe]

Ich habe eine Tabelle mit immer 5 Werten (x1 bis x5). Jetzt soll mir Excel für einen Wertebereich eine bestimmte Ziffer in eine Zelle ausgeben die anschliessend zu einer 5 stelligen Kennzahl zusammengefügt werden sollen.

und welche Zahl soll für z gelten, wenn der Wert genau auf Deiner Grenze liegt?
Du hast immer nur < oder > genommen und nicht auf einer Grenze <= oder >=

[lapunta]

ja, gibt es .... das ganze WEB ist voller Bilder. [img]
Dateiupload bitte im Forum! So geht es: Klick mich!
]

Mit Bildern will hier eigentlich niemand arbeiten. Aus Bildern läßt sich auch keine Exceldatei erstellen. Folglich ist sowas
nicht wirklich hilfreich beim Helfen.

Ich hab das ja nur so reingestellt, um das Problem zu verdeutlichen.
Ich will ja auch kein Bild sehen, sondern suche nach einer Excel-Datei zum herunterladen,an der man, wie schon gesagt, sehen kann, wie das Ganze praktisch aussieht und mit der man auch ein bißchen herumprobieren kann.

und welche Zahl soll für z gelten, wenn der Wert genau auf Deiner Grenze liegt?

Du hast immer nur < oder > genommen und nicht auf einer Grenze <= oder >=

...das ist jetzt gerade nur eiin sekundäres problem. Ist auch ziemlich egal, wierum man es letztendlich macht.

[BoskoBiati]

Hallo,

ich hab da mal was vorbereitet :19: :

Arbeitsblatt mit dem Namen 'Tabelle1'
	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R
1	-15	-10	-5	-1	0		1	2	3	4	5	12345	12345	12345	12345
2	0	1	5	10	100		5	6	7	8	8	56788	56788	56788	56788
3	-15	-10	-5	-1	0		1	1	2	3	4	11234	11234	11234	11234
4	0	1	5	10	100		4	5	6	7	8	45678	45678	45678	45678

Zelle	Formel
J1	=VERWEIS(D1;{-9999;-10;-5;-1;0;1;5;10};{1;2;3;4;5;6;7;8})
J2	=VERWEIS(D2;{-9999;-10;-5;-1;0;1;5;10};{1;2;3;4;5;6;7;8})
J3	=VERWEIS(D3-1%;{-9999;-10;-5;-1;0;1;5;10};{1;2;3;4;5;6;7;8})
J4	=VERWEIS(D4-1%;{-9999;-10;-5;-1;0;1;5;10};{1;2;3;4;5;6;7;8})
O1	=J1*10^4+K1*10^3+L1*10^2+M1*10^1+N1*10^0
P1	=J1&K1&L1&M1&N1
Q1	=SUMMENPRODUKT((J1:N1)*10^(5-SPALTE($A$1:$E$1)))
R1	=SUMMENPRODUKT(VERWEIS(D1:H1;{-9999;-10;-5;-1;0;1;5;10};{1;2;3;4;5;6;7;8})*10^(5-SPALTE($A$1:$E$1)))
O3	=J3*10^4+K3*10^3+L3*10^2+M3*10^1+N3*10^0
P3	=J3&K3&L3&M3&N3
Q3	=SUMMENPRODUKT((J3:N3)*10^(5-SPALTE($A$1:$E$1)))
R3	=SUMMENPRODUKT(VERWEIS(D3:H3-1%;{-9999;-10;-5;-1;0;1;5;10};{1;2;3;4;5;6;7;8})*10^(5-SPALTE($A$1:$E$1)))

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[lapunta]

Wow!
Ich hab das gerade auf meine Tabelle übertragen - und es scheint zu funktionieren. Auf die Idee mit dem Verweis wäre ich wahrscheinlich gar nicht gekommen.

Du hast mr eine Menge Arbeit erspart.

Vielen Dank :18: