VBA umfriemeln

[Mehrzweck]

Hallo Leute!
Ich bastel gerade an der Arbeit an einer Excel-Tabelle rum.
Ich hätte gerne, dass wenn man in eine Zelle klickt, der Inhalt einer anderen Zelle als Popup auftaucht. Habe dazu was im Internet gefunden und versuche es auf meine Bedürnisse anzupassen. Leider habe ich 0 Ahnung davon, hab jetzt ein bisschen rumprobiert, aber ich komme einfach nicht drauf in welchem Bereich man festlegt, welche Zelle als Popup aufplopt.

Option Explicit
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Dim rngUnion As Range, rngUBereich As Range
' Abfangen mehr als eine Zelle
If Target.Count > 1 Then Exit Sub
Unload UserForm1
' nur für einen bestimmten Bereich.
Set rngUBereich = Range("A1:A20")  ' Oder auch "A1:A20,C1:C20" oder "A1:A100" ...
Set rngUnion = Application.Union(Range(Target.Address), rngUBereich)
If rngUnion.Address = rngUBereich.Address Then
    strText = Target.Offset(0, 3).Value
    UserForm1.Show vbModeless
End If
End Sub

In dem Programm ploppen immer die Zellen aus Spalte D auf, ich hätte aber gerne Spalte C.

Ich hoffe mir kann jemand weiter helfen, werde beruflich gerade etwas ins kalte Wasser geschubst

[Werner.M]

Hallo,

so:

Code:

Option Explicit
Private Sub Worksheet_SelectionChange(ByVal Target As Range)

If Target.Count > 1 Then Exit Sub
If Not Intersect(Range("A1:A20"), Target) Is Nothing Then
   If Target.Offset(, 2) <> "" Then
       MsgBox Target.Offset(, 2).Value
   End If
End If

End Sub

Gruß Werner

[Mehrzweck]

Das ist total genial! Vielen Dank schonmal. Kann man das noch so ändern, dass der Inhalt im Popup aus Spalte C, aber (Name vom Tabellenblatt) "Bemerkungen" genommen wird?
In welchem Bereich wird die Ziel-Zelle da festgelegt? Finde das hoch interessant :17:

[Werner.M]

Hallo,

wenn ich dich richtig verstanden habe:

Code:

Option Explicit
Private Sub Worksheet_SelectionChange(ByVal Target As Range)

If Target.Count > 1 Then Exit Sub
If Not Intersect(Range("A1:A20"), Target) Is Nothing Then
  If Worksheets("Bemerkungen").Cells(Target.Row, 3) <> "" Then
      MsgBox Worksheets("Bemerkungen").Cells(Target.Row, 3).Value
  End If
End If

End Sub

Gruß Werner