Unterschiedliche werte mit komma und leerzeichen trennen

[excel2007]

Hallo liebes Forum,

ich habe zwei Listen und folgende Werte mit Adressen aus Großbritannien:

Liste 1

Unit 3 Stable Barn Home Farm, Thorganby, York, North Yorkshire, United Kingdom, YO19 6DE
Adresse 1, Adresse2, Ort, Bundesland, Land, PLZ
oder
30 Kneller Walk, Oldham, Lancashire, United Kingdom, OL1 4PF
Adresse 1, Ort, Bundesland, Land, PLZ

Manche haben eine, manche zwei Adresszeilen.

Liste 2

Unit 15 Bellringer Road, Trentham Lakes South, Stoke-On-Trent, Staffs ST4 8LJ
Adresse 1, Adresse2, Ort, Bundesland UND PLZ
oder
87 High Street, Burton Upon Trent, Staffordshire, DE14 1LJ
Adresse 1, Adresse2, Ort, Bundesland, PLZ
oder
7 Western View, Billericay, Essex CM12 9GE
Adresse 1, Ort, Bundesland UND PLZ

Hier gibt es 3 Varianten.

Ich bräuchte Formeln, um die Werte in zusammenhänge Gruppen zu trennen.

[LCohen]

a) Manche haben eine, manche zwei Adresszeilen.

b) Ich bräuchte Formeln, um die Werte in zusammenhängende Gruppen zu trennen.

a) Aha. Und nun? Das ist eine extrem erläuterungsbedürftige Info.

b) Wie die genau lauten sollen, sollen wir uns also überlegen? Adresse1, Adresse2, Ort, Bundesland, Land, PLZ?

https://www.office-fragen.de/index.php/t...274.0.html
http://www.herber.de/forum/archiv/1652to...tm#1652242
https://www.clever-excel-forum.de/thread-17643.html
Crossposting kurz vor Feierabend; "die Foren-Guys werden es mir über Nacht schon richten" ...

[excel2007]

Entschuldigt mein "Crossposting". Ich bin heute das erste Mal überhaupt in einem Forum.

Ich bräuchte alle "Adresse 1" in einer Spalte, alle "Adresse 2" in einer Spalte usw. Vielleicht kann man die Adresse umdrehen und dann trennen.

[WillWissen]

Hallo,

es ist entschuldigt; ich hoffe jedoch, du hast den Link, den dir LCohen geschrieben hat, angesehen. Und es wäre fair, wenn du, egal in welchem Forum du zu einer Lösung kommst, diese beim jeweils anderen Nachbarn verlinkst.

Nun zu deinem Problem.

Stelle uns bitte eine Beispieldatei vor, wie sie bei dir im Original aussieht; sensible Daten bitte anonymisieren. Es reichen etwa 5 komplette Datensätze; zwei bis drei Wunschergebnisse händisch eingetragen, helfen beim Helfen. Alleine aufgrund deiner Beschreibung weiß ich nicht, was du benötigst.

So kannst du eine Datei hochladen: https://www.clever-excel-forum.de/thread-326.html

[LCohen]

Deine Daten in A2:A999 und A1002:A1999.
_____________________________________________________________________________________
Liste 1 (hier ab Zeile 2):

F2[:K999]:
=WENN(LÄNGE($A2)-LÄNGE(WECHSELN($A2;",";))=5;
GLÄTTEN(TEIL(WECHSELN($A2;",";WIEDERHOLEN(" ";99));SPALTE(A2)*99-98;99));WENN(KÜRZEN((SPALTE(A2)*0,9)-0,8)=KÜRZEN((SPALTE(B2)*0,9)-0,8);"";
GLÄTTEN(TEIL(WECHSELN($A2;",";WIEDERHOLEN(" ";99));KÜRZEN((SPALTE(B2)*0,9)-0,8)*99-98;99))))
_____________________________________________________________________________________
Liste 2 (hier ab Zeile 1002):

E1002[:E1999]: 
=WENN(ISTZAHL(SUCHEN(",";TEIL(RECHTS($A1002;10);1;3)));$A1002;
WECHSELN($A1002;RECHTS($A1002;8);)&","&RECHTS($A1002;8)) 
(als Hilfsspalte)

F1002[:K1999]:
=WENN(LÄNGE($E1002)-LÄNGE(WECHSELN($E1002;",";))=4;
WENN(KÜRZEN((SPALTE(A1002)*0,9)-0,5)=KÜRZEN((SPALTE(B1002)*0,9)-0,5);"";
GLÄTTEN(TEIL(WECHSELN($E1002;",";WIEDERHOLEN(" ";99));KÜRZEN((SPALTE(B1002)*0,9)-0,5)*99-98;99)));
WENN(KÜRZEN((SPALTE(A1002)*0,7)-0,4)=KÜRZEN((SPALTE(B1002)*0,7)-0,4);"";
GLÄTTEN(TEIL(WECHSELN($E1002;",";WIEDERHOLEN(" ";99));KÜRZEN((SPALTE(B1002)*0,7)-0,4)*99-98;99))))
_____________________________________________________________________________________

[LCohen]

Datei doch besser angefügt (der zweite Datensatz ist zu kontrollieren bez. Ort und Adresse 2; die Beschriftung war falsch vom TE):

  181018 CEF17643 CSV-Felder verschiedener Datensaetze inkl Leerspalten per Formel ans Ziel setzen.xlsx (Größe: 15,55 KB / Downloads: 1)