Übersetzung von komplexen Formel auf Deutsch

[Kingz]

Hallo zusammen,

ich habe einen Formel (siehe unten) auf englisch die ich in Excel deutsch übersetzen möchte. Dadurch dass es ziemlich komplexist, weiß ich nicht wie ich das übersetzen soll.

Code:

=IF([@Level]=4,
    LET(dataKnots,TAKE([Knots],ROW()-1),
    dataLevels,TAKE([Level],ROW()-1),
    d,REDUCE("",SEQUENCE(5,1,4,-1),
            LAMBDA(r,l,HSTACK(r,TAKE(FILTER(dataKnots,dataLevels=l),-1)))),
    TEXTJOIN(",",TRUE,d)),
"")

Danke für jegliche Hilfe.

MFG
K

[steve1da]

Hola,
https://excelhero.de/excel-funktionen-deutsch-englisch/
Gruß,
steve1da

[shift-del]

Oder:
https://de.excel-translator.de/translator/

[Ralf A]

...naja... [@Level] ist 'ne Zelladresse und dataKnots, dataLevels und d sind Variablennamen... die solltest und brauchst Du nicht zu übersetzen... 
Und let wird auch nichtübersetzt...

[EA1950]

Hallo,

Code:

=WENN(
    [@Level] = 4;
    LET(
        dataKnots; ÜBERNEHMEN([Knots]; ZEILE() - 1);
        dataLevels; ÜBERNEHMEN([Level]; ZEILE() - 1);
        d; REDUCE(
            "";
            SEQUENZ(5; 1; 4; -1);
            LAMBDA(r; l;
                HSTAPELN(r; ÜBERNEHMEN(FILTER(dataKnots; dataLevels = l); -1))
            )
        );
        TEXTVERKETTEN(","; WAHR; d)
    );
    ""
)

[HKindler]

Hi,

wenn man sich in VBA auskennt, dann gibt man die englische Formel im Direktfenster so ein:

Code:

[A1].Formula = "DeineFormel"

Wobei A1 die gewünschte Zelle und DeineFormel die Formel mit verdoppelten Anführungszeichen ist. In deinem Fall also

Code:

[A1].Formula = "=IF([@Level]=4,LET(dataKnots,TAKE([Knots],ROW()-1),dataLevels,TAKE([Level],ROW()-1),d,REDUCE("""",SEQUENCE(5,1,4,-1),LAMBDA(r,l,HSTACK(r,TAKE(FILTER(dataKnots,dataLevels=l),-1)))),TEXTJOIN("","",TRUE,d)),"""")"

Wenn du jetzt die Zelle anklickst, siehst du die deutsche Formel.