Über Datum Jahr die Stunden von Personen aufsummieren

[Driver]

Hallo zusammen,

anbei ist eine Liste links gegeben und rechts die Liste die ich gerne daraus generieren möchte. Hierbei sollen die Personen auf Jahr mit aufaddierten Stunden gelistet werden.

Viele Grüße und einen guten Start in die Woche

Driver


  test-datum.xlsx (Größe: 9,47 KB / Downloads: 12)

[derHoepp]

Moin,

das löst eine einfache Pivottabelle. Namen in die Zeilen, Datum in die Spalten, ggf. Gruppieren, Stunden in die Werte und fertig.

Viele Grüße
derHöpp

Nachtrag: ich hatte die Datei nicht vollständig gesehen, für das gewünschte Bild muss das Datum auch in die Zeilen. für die wiederholten Werte dann einfach bei den Feldeinstellungen die Tabellenansicht wählen und Teilergebnisse nicht anzeigen.

[{Boris}]

Hi,

mit Formeln (xl365 - aber noch nicht die Beta-Funktionen):

In D2:
=JAHR(A2:A25)

M1:
=LET(e;EINDEUTIG(HSTAPELN(D2#;B2:B25));VSTAPELN({"Jahr"."Name"."Stunden"};HSTAPELN(e;SUMMEWENNS(C2:C25;D2#;INDEX(e;;1);B2:B25;INDEX(e;;2)))))

[Driver]

Hi,

vielen Dank für die schnelle Rückmeldung. Aber irgendwie funktioniert es nicht richtig. Hast du eine Lösung dafür?

   


  test-datum.xlsx (Größe: 10,24 KB / Downloads: 5)

[Cadmus]

Hallo,

deine Formel war unvollständig. richtig: Bereich D2:D25

Mit Pivot lässt sich das ohne Formeln ganz schnell erstellen.

[Luschi]

Hallo Excel-365 Fan's,

ich habe die Formel in Zelle 'M1' von {Boris} noch etwas allgemeiner gefaßt, so das nur noch an 1 Stelle der zu berücksichtigende Bereich geändert werden muß (a;A2:C25):

Code:

=LET(a;A2:C25;e;EINDEUTIG(HSTAPELN(JAHR(INDEX(a;;1));INDEX(a;;2)));VSTAPELN({"Jahr"."Name"."Stunden"};HSTAPELN(e;SUMMEWENNS(INDEX(a;;3);D2#;INDEX(e;;1);INDEX(a;;2);INDEX(e;;2)))))

Gruß von Luschi
aus klein-Paris

[{Boris}]

Hi,

na dann bringen wir die "Pivotauswertung" formelmäßig doch noch ganz zu Ende

=LET(a;A2:C25;e;EINDEUTIG(HSTAPELN(D2#;INDEX(a;;2)));Std;SUMMEWENNS(INDEX(a;;3);D2#;INDEX(e;;1);INDEX(a;;2);INDEX(e;;2));VSTAPELN(VSTAPELN({"Jahr"."Name"."Stunden"};HSTAPELN(e;Std));HSTAPELN("Gesamt";"";SUMME(Std))))

[Luschi]

Hallo {Boris},

Danke für Deine 2. Lösung, aber das Überprüfen ist schon ganz schön "anstrengend" , da tue ich es mir in Power Query etwas leichter; siehe meine PQ-Lösung.

Gruß von Luschi
aus klein-Paris