Text aus Zelle extrahieren und separat wiedergeben

[KathaDD]

Liebe Community, 
nach verschiedenen Versuchen komme ich nicht weiter. Aus mehreren Zellen soll Text extrahiert werden und zusammengefasst mit einmaligen Werten wiedergegeben werden. Mit der Eindeutig-Formel oder Filter-Formel habe ich es noch nicht geschafft. Habt ihr eine Idee?
LG Katharina

[schauan]

HAllöchen,

hier mal eine Formel für B4

=TEXTVERKETTEN(",";;EINDEUTIG(TEXTTEILEN(TEXTVERKETTEN(",";;C4:G4);;",")))

[EA1950]

Hallo,

man kann die Formel von André in 2 Array-Formeln verschachteln (für jeden Orange-Bereich je 1 Formel):

in Zelle B4: 
=LET(tr;","; NACHZEILE($C$4:$G$8;LAMBDA(zl; TEXTVERKETTEN(tr;;EINDEUTIG(TEXTTEILEN(TEXTVERKETTEN(tr;;zl);;tr)))))) 
mit Resultatbereich B4:B8

in Zelle C3: 
=LET(tr;",";NACHSPALTE($C$4:$G$8;LAMBDA(sp; TEXTVERKETTEN(tr;;EINDEUTIG(TEXTTEILEN(TEXTVERKETTEN(tr;;sp);;tr)))))) 
mit Resultatbereich C3:G3

und für die Schnittzelle B3:
=LET(tr;",";NACHZEILE(C3#;LAMBDA(sp; TEXTVERKETTEN(tr;;EINDEUTIG(TEXTTEILEN(TEXTVERKETTEN(tr;;sp);;tr))))))

[KathaDD]

Hallo André, 
in G habe ich mal fünf Jahre gewohnt, Grüße in die alte Heimat   
Vielen Dank für die Formel, sie hilft mir sehr! Hast du noch einen Tipp für mich, wie ich den "#Wert!" bei einer Leerzeile wegbekomme?
LG Katharina

[EA1950]

Hallo,

einfach die bisherige Formel in diese Funktion einfügen: =WENNFEHLER(Formel;"")

[KathaDD]

Hallo Anton, Danke, habe ich so übernommen! 
Mit Array werde ich mich definitiv näher beschäftigen :)

[EA1950]

Hallo,

in meinem Posting #3 kann man 1 Formel einsparen, indem man

in Zelle C3: 
=LET(tr;",";WENNFEHLER(NACHSPALTE($C$4:$G$8;LAMBDA(sp; TEXTVERKETTEN(tr;;EINDEUTIG(TEXTTEILEN(TEXTVERKETTEN(tr;;sp);;tr)))));""))

und in Zelle B3: 
=LET(tr;",";WENNFEHLER(NACHZEILE(VSTAPELN($C$3#;$C$4:$G$8); LAMBDA(zl; TEXTVERKETTEN(tr;;EINDEUTIG(TEXTTEILEN(TEXTVERKETTEN(tr;;zl);;tr)))));""))

die Formeln eingibt.

[Egon12]

Hallo,

hier noch eine LAMBDA für den Namensmanager.

Formel in Zelle B4: =UniWerte(C4:G8;",")

in den Namensmanager 
Name:  UniWerte

Code:

=LAMBDA(Bereich; Seperator;LET(xZ; SEQUENZ(ZEILEN(Bereich));MAP(xZ;LAMBDA(iZ;TEXTVERKETTEN(Seperator; WAHR;EINDEUTIG(TEXTTEILEN(TEXTVERKETTEN(Seperator; WAHR; INDEX(Bereich; iZ; ));Seperator);WAHR))))))

Gruß Uwe

[Egon12]

zu Übungszwecken nun noch für die Formel für Zeile 3:

Zelle B3: =UniWerteSp(B4:G8;",")

Namensmanager:
Name: UniWerteSp
Formel:

Code:

=LAMBDA(Bereich;Separator;LET(xA;Bereich;iSp;SEQUENZ(SPALTEN(xA));xB;MAP(iSp;LAMBDA(pSp;TEXTVERKETTEN(Separator;WAHR;EINDEUTIG(TEXTTEILEN(TEXTVERKETTEN(Separator;WAHR;INDEX(xA;;pSp));Separator);WAHR))));MTRANS(xB)))

  Formelsuche_Text.xlsx (Größe: 12,2 KB / Downloads: 1)

Gruß Uwe