Text aufteilen

[GaMiSha]

Moin Gemeinde!

Wie lauten die Formeln in B2, C2, D2, und E2, wenn man den Text aus der Spalte A aufteilen möchte?

(Siehe Anhang)

LG MiSha

[RPP63]

Moin!
Schaue Dir LINKS(), TEIL() und RECHTS() an, jeweils in Verbindung mit FINDEN(Trennzeichen, Text)

Wobei, da hier tricky, leiste ich mal für die Zeit Direkthilfe:

	A	B
19	59:53 18. BiXX & Roxanne Emery - Sound of The Alarm	0:59:53
20	1:03:38 19. Raz Nitzan & Maria Nayler - Echo of My Soul (Denis Kenzo Remix)	1:03:38

Zelle	Formel
B19	=LET(z;LINKS(A19;FINDEN(" ";A19)-1);WENN(LÄNGE(z)>5;--z;z/60))
B20	=LET(z;LINKS(A20;FINDEN(" ";A20)-1);WENN(LÄNGE(z)>5;--z;z/60))

Gruß Ralf

[maninweb]

Hallo,

eine Alternative, die den Bereich in einem Rutsch konvertiert. Setzt LET und dynamsiche Arrays voraus.
Und kann bestimmt noch ein bißchen optimiert werden.

Code:

=LET(Liste;A2:A26;X;
WAHL(SEQUENZ(1;5);1;FINDEN(" ";Liste);FINDEN(".";Liste);FINDEN("-";Liste);LÄNGE(Liste));
WAHL(SEQUENZ(1;4);
GLÄTTEN(TEIL(Liste;INDEX(X;0;1);INDEX(X;0;2)-INDEX(X;0;1)));
GLÄTTEN(TEIL(Liste;INDEX(X;0;2)+1;INDEX(X;0;3)-INDEX(X;0;2)-1));
GLÄTTEN(TEIL(Liste;INDEX(X;0;3)+1;INDEX(X;0;4)-INDEX(X;0;3)-1));
GLÄTTEN(TEIL(Liste;INDEX(X;0;4)+1;INDEX(X;0;5)-INDEX(X;0;4)))))

Gruß

[snb]

A UDF

Code:

Function F_snb(c00)
  F_snb = Split(Replace(c00, " ", "-", , 2), "-")
End Function

In B2 Array-Formel:

PHP-Code:

=F_snb(A2) 


Durziehen in B2:E26

[LCohen]

B2: =GLÄTTEN(TEIL(WECHSELN(WECHSELN(WECHSELN(WECHSELN(A2;" ";"#";1);". ";"#";1);" - ";"#");"#";WIEDERHOLEN(" ";299));{1.2.3.4}*299-298;299))

oder für altes oder jedes Excel manuell kopierend:

B2[:E2]: =GLÄTTEN(TEIL(WECHSELN(WECHSELN(WECHSELN(WECHSELN($A2;" ";"#";1);". ";"#";1);" - ";"#");"#";WIEDERHOLEN(" ";299));SPALTE(A2)*299-298;299))

[RPP63]

… wobei ich ja davon ausgehe, dass das Lineup "irgendwo" her kommt.
Daher sollte der Import per Power Query zielführender sein.

[PIVPQ]

Hallo

Oder wie der Fuchs von Ralf schon richtig gesagt hat.

[GaMiSha]

@maninweb

So hatte ich mir das vorgestellt..."in einem Rutsch"

Allerdings habe ich dabei Probleme mit den Leerzeichen und einigen Längen der Wörter.

Ich arbeite noch dran.

LG

---

@snb

WOW, sehr gute Lösung.
Für mich sind das allerdings noch böhmische Dörfer. ;)

Wo finde ich denn die Formeln dazu?

LG

---

@LCohen

So stell' ich mir das schon eher vor. Ohne VBA, nur die Formel....

LG

[snb]

Etwas weniger 'substitute':

PHP-Code:

=TRIM(MID(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE($A2;" ";"-";1);" ";"-";1);"-";REPT(" ";100));(COLUMN(A1)-1)*100+1;100))