Terminliste 2.0

[Heiko*]

Hallo

ich möchte eine Terminliste erstellen. dazu möchte ich für die Arbeitstage die Arbeitstage.intl Funktion nutzen. zur Berechnung der zeit gerne Sequenz. die liste soll komplett dynamisch sein. zur Erklärung füge ich eine Datei ein. ich probiere schon ne ganze weile rum komme aber zu keinem Ergebnis. KI habe ich auch schon gefragt. da bekomme ich nicht das richtige Ergebnis.

vielen dank heiko

[BoskoBiati]

Hi,

und wie soll die Liste nach Deinen Vorstellungen aussehen?

[Heiko*]

Hallo

Das siehst du in den Zellen unter Ausgabe. So soll das aussehen.

[snb]

08.00 fehlt in Dienstag 03-06-2025 unter Ausgabe ?

[Blaukraut05]

Hallo Heiko, 

kannst du nochmal genau sagen was das Ergebnis sein soll. Und soll das wirklich so stehen bleiben wie es in Deinem Beispiel ist? Das wird ziemlich unübersichtlich, oder ? Wer arbeitet denn damit, Du alleine?

Und noch eine Frage, die blaue Tabelle (A14:C130) ist nur zur Information/Uebersicht an welchen Tagen gearbeitet wird ?

Viele Grüße 
Michael

[Gast 123]

Hallo

mir ist etwas interessantes aufgefallen, diese Liste funktioniert ja bereits.  Nur umgekehrt!!

Klickt man in Spalte G die Wochentage an, werden alle Tage angezeigt, -AUSSER- dem angeklickten!
Das liegt in der Wahr/Falsch Auswertung in Spalte H.  Verstehe aber noch nicht wieso die funktioniert??
Vielleicht findet ein Kollege heraus wie der TA das gemacht hat??  Ich sehe kein Makro für den Effekt.

Alle CheckBoxen sind mit einer Zelle in H verknüpft.  Dort sieht man Wahr/Falsch.
Nur aus Neugier habe ich mit meinem Makro mal die Auswertung genau umgedreht!
Damit bekommt man jetzt eine exakte Tagesauswahl.. Das müsste aber einfacher gehen, oder???

mfg Gast 123

---

Ich habe immer nch nicht verstanden, wie die Auswahl einen Einfluß auf den Autofilter der Tabelle hat??
Weiß ein Kollege wie das funktioniert?  Würde mich rein technisch interessieren.

[Heiko*]

Hallo

Die Blaue Tabelle ist die Tabelle mit der ich arbeiten möchte. Spalte E und F zeigt nur wie ich das Ergebnis haben möchte. Die Arbeitstage 0 und Wochenenden 1 (kontrollkästchen) möchte ich  in der Blauen Tabelle nutzen da ich die Arbeiten eben manchmal montag-donnerstag, monta bis dienstag das möchte ich nicht den kontrollkästchen erreichen.

[EA1950]

Hallo,

in der beiliegenden Datei habe ich im Arbeitsblatt "Tabelle1" in Zelle J15 folgende Formel eingefügt:

=LET(Startdatum; $C$1; Tagesanzahl; $C$2; WochenEnde; $G$9; Dauer; $E$1; tg; ARBEITSTAG.INTL(Startdatum; SEQUENZ(Tagesanzahl); WochenEnde; Feiertag[Datum]); r; REDUCE({0.0}; tg; LAMBDA(Akk;dt; LET(wotg; TEXT(dt; "TTTT"); spWotg; XVERGLEICH(wotg; Wochentage[#Kopfzeilen]; 0); start; INDEX(Wochentage; 1; spWotg); ende; INDEX(Wochentage; 2; spWotg); tgTerm; SEQUENZ((ende - start) / Dauer; 1; start; Dauer); tgTermCt; ZEILEN(tgTerm); VSTAPELN(Akk; HSTAPELN(ERWEITERN(dt; tgTermCt; 1; dt); tgTerm))))); VSTAPELN({"Datum"."Termin"}; WEGLASSEN(r; 1)))

Diese Formel erstellt deine gewünschte Auflistung an Tagen und Uhrzeiten. Dazu benötigt sie die fett geschriebenen Zellen und Tabellen für die Berechnung. Nicht benötigt wird dagegen deine intelligente Tabelle "Tabelle1" mit der Tagesauflistung.

Die Tabelle "Wochentage" muss natürlich soweit ausgefüllt sein, wie es die Checkboxen "Auswahl Wochentag" erfordern - sonst erhältst du bloß eine Fehlermeldung als Resultat.
Ferner habe ich die Zelle C2 mit der Anzahl der Tage, die in der Auflistung enthalten sein sollen, hinzugefügt - da du die Funktion "ARBEITSTAG.INTL" einsetzen wolltest.

Die Formel sei im Folgenden nochmals in strukturierter Form aufgelistet, um sie besser verständlich zu machen:

Code:

=LET(
    Startdatum; $C$1;
    Tagesanzahl; $C$2;
    WochenEnde; $G$9;
    Dauer; $E$1;
    tg; ARBEITSTAG.INTL(Startdatum; SEQUENZ(Tagesanzahl); WochenEnde; Feiertag[Datum]);
    r; REDUCE(
        {0. 0};
        tg;
        LAMBDA(Akk; dt;
            LET(
                wotg; TEXT(dt; "TTTT");
                spWotg; XVERGLEICH(wotg; Wochentage[#Kopfzeilen]; 0);
                start; INDEX(Wochentage; 1; spWotg);
                ende; INDEX(Wochentage; 2; spWotg);
                tgTerm; SEQUENZ((ende - start) / Dauer; 1; start; Dauer);
                tgTermCt; ZEILEN(tgTerm);
                VSTAPELN(Akk; HSTAPELN(ERWEITERN(dt; tgTermCt; 1; dt); tgTerm))
            )
        )
    );
    VSTAPELN({"Datum". "Termin"}; WEGLASSEN(r; 1))
)

[rate mit]

Hallo EA1950,

wieso ist der 16.06.2025 nicht dabei?

---

Hallo,

hier mal ein anderer Ansatz...

[BoskoBiati]

Hi,

wieso ist der 16.06.2025 nicht dabei?

Weil der in der Feiertagsliste als "meins" aufgeführt ist!