Tabelle umformen

[ingoros]

Hi, 
wie bekommt das hin?
Die Tabelle ist natürlich deutlich länger :(

   

Danke

[shift-del]

Moin

Pivot-Tabelle.

[UweD]

Hallo

Arbeitsblatt mit dem Namen 'Tabelle2' B C D E F G H I 4 Strom 04.01.2026 200 5 Versicherung 15.01.2026 100 6 Deutschlandticket 02.01.2026 60 7 Strom 04.02.2026 200 8 Deutschlandticket 02.02.2026 60 9 Strom 04.03.2026 200 10 Deutschlandticket 02.03.2026 60 11 12 13 Januar Februar März 14 Strom 200 4 200 4 200 4 15 Versicherung 100 15 0 15 0 15 16 Deutschlandticket 60 2 60 2 60 2
Zelle Format Wert D13 MMMM 01.01.2026	Zelle Formel G14 =E14 B14 =EINDEUTIG(B4:B10) D14 =SUMMEWENNS($D$4:$D$10;$B$4:$B$10;$B14#;$C$4:$C$10;">="&D$13;$C$4:$C$10;"<="&MONATSENDE(D$13;0)) F13 =EDATUM(D13;1)

Wobei mir die Bedeutung der Spalten E; G; I unklar sind
LG UweD

[EA1950]

Hallo @UweD,

Wobei mir die Bedeutung der Spalten E; G; I unklar sind

ich brauchte auch einige Zeit, bis ich es begriff: Das dürfte der Tag innerhalb des jeweiligen Monats sein, entnommen aus der Datumsspalte der Tabelle.

Die ganze Liste soll offenbar nur eine monats/tage-weise Auflistung der obigen Tabelle sein.
Was mir nicht klar ist: Was soll geschehen, wenn eine Aufwandsart mehrmals pro Monat vorkommen sollte.

Vielleicht passt folgende Formel:

PHP-Code:

=LET(
    m; $B$3:$D$10;
    art; INDEX(m; ; 1);
    dat; INDEX(m; ; 2);
    btr; INDEX(m; ; 3);
    mon; TEXT(dat; "MM:MMM");
    tg; TEXT(dat; "T");
    PIVOTMIT(art; mon; HSTAPELN(btr; tg); MATRIXZUTEXT; 3; 0; ; 0)
)


[ingoros]

Hallo!

Richtig, das sind die Tage des Monats.

Eine mehrfache Überweisung in einem Monat kommt eigentlich nicht vor.

Der erste Teil ist der Kontoauszug und hat eigentlich keine Bedeutung.

Erstellt werden soll eine Übersicht, welche Ausgaben in welchen Monat anstehen.
Insofern sind die Daten aus der obigen Tabelle eigentlich falsch, da es alte Daten sind und eigentlich zukünftige Daten dargestellt werden sollen.
Die Daten sind aber fast immer gleich, insofern können sie als Vorlage genutzt werden. Mitgliedsbeiträge und Versicherungszahlung bleiben eigentlich gleich und können dann bei Bedarf händisch korrigiert werden.

Danke!

[Egon12]

Hallo,

Wenn ich es richtig verstanden habe soll egal sein aus welchen Kalenderjahr die Rohdaten stammen. 

Dann vielleicht so?

Code:

=LET(xA;B4:D100;
  xB;EINDEUTIG(FILTER(INDEX(xA;;1);INDEX(xA;;1)<>""));
  WENNFEHLER(MATRIXERSTELLEN(ANZAHL2(xB)+1; 1+12*2;
      LAMBDA(z;sp;
        WENN( z=1; INDEX({"Anlass";"Januar";"Tag";"Februar";"Tag";"März";"Tag";"April";"Tag";"Mai";"Tag";"Juni";"Tag";"Juli";"Tag";"August";"Tag";"September";"Tag";"Oktober";"Tag";"November";"Tag";"Dezember";"Tag"};sp);
            LET(xC;INDEX(xB;z-1);
                WENN(sp=1;xC;
                LET( xD;AUFRUNDEN((sp-1)/2;0);
                    xE;REST(sp-1;2)=0;
                    WENN(
                        NICHT(xE);
                        SUMME(FILTER(INDEX(xA;;3);(INDEX(xA;;1)=xC)*(MONAT(INDEX(xA;;2))=xD)));
                        LET(xF;FILTER(INDEX(xA;;2);(INDEX(xA;;1)=xC)*(MONAT(INDEX(xA;;2))=xD));WENN(ANZAHL(xF)=0;"";TAG(INDEX(xF;1))))
                        )
                    ))
                )
            )
        )
    );"")
)

Es wird die komplette Liste nebst Überschriften für alle 12 Monate ausgegeben. Wo deine Rohdaten sind weißt du xA zu.

Gruß Uwe

[slowboarder]

Hi
am einfachsten mit einer Pivottabelle

hier mal die Einstellungen dazu.
   
die Spalte mit dem Datum solltest du für dein Wunschergebnis noch mit dem Zahlenformat "T" formatieren. (macht man in den Wertfeldeinstellungen im Kontextmenü)

Gruß Daniel

[RPP63]

Moin!
Auch ich bin Verfechter eines Pivot-Table.
Ich klinke mich hier nur kurz ein, weil …

Code:

={"Januar";"Februar";"März";"April";"Mai";"Juni";"Juli";"August";"September";"Oktober";"November";"Dezember"}

… könnte man ja auch so erzeugen:

Code:

=TEXT(DATUM(;SEQUENZ(12);1);"MMMM")

12-mal "Tag" untereinander z.B. so:

Code:

=INDEX("Tag";SEQUENZ(12;;;1/12))

Das Ganze im Wechsel dann statt:

Code:

={"Januar";"Tag";"Februar";"Tag";"März";"Tag";"April";"Tag";"Mai";"Tag";"Juni";"Tag";"Juli";"Tag";"August";"Tag";"September";"Tag";"Oktober";"Tag";"November";"Tag";"Dezember";"Tag"}

einfach so:

Code:

=ZUSPALTE(HSTAPELN(TEXT(DATUM(;SEQUENZ(12);1);"MMMM");INDEX("Tag";SEQUENZ(12;;;1/12))))

Ist vielleicht schlechter verständlich, schont aber die Sehnenscheiden.

Gruß Ralf

[HKindler]

Hi,

und hier nochmals eine Formel-Lösung...

   

=PIVOTMIT(A1:A7;WENN(ISTZAHL(C1:C7);DATUM(JAHR(C1:C7);MONAT(C1:C7);1);"Monat");B1:C7;HSTAPELN(SUMME;MIN);3;0;;0;2)

hier sind die Zellen F2:I2 mit "MMMM" und (G5:G7;I5:I7) mit "TT" formatiert.

Allerdings habe (noch) nicht herausgefunden, wie man die Zeile mit SUMME und MIN elegant weg bekommt.

[Egon12]

@Ralf,

da hast du natürlich WAHR. Ich hatte es einfach mal zwischen Tür und Angel zusammengeklebt und mir keine weiteren Gedanken gemacht.

Gruß Uwe