Sverweis mit variablen Spaltenindex basierend auf 2 Bedingungen

[el-rettev]

Hallo zusammen,

ich möchte gerne einen Sverweis mit einem variablen Spaltenindex erstellen. Der Spaltenindex soll 2 variable Bedingungen in den Überschriften suchen und die Spalte nehmen in der diese 2 Bedingungen erfüllt sind.
Leider habe ich da aktuell ein Brett vor dem Kopf und komme einfach nicht weiter.
Würde mich über jede Hilfe freuen.
Vielen Dank.
Beispieldatei ist hochgeladen.

[steve1da]

Hola,
das könnte man mit Summenprodukt() erledigen.
Gruß,
steve1da

[el-rettev]

Hi Steve,

danke für deine Antwort. Hab es mit summenprodukt versucht, aber komme da nicht weiter. Die Funktion gibt mir aus wie viele Treffer es findet, aber ich bekomme dann den Bogen zur Spalte nicht hin.
Aber beim Tüfteln an der summenprodukt-Funktion bin ich auf folgendes gekommen:

=AGGREGAT(14;6;SPALTE($A$1:$I$1)*($A$1:$I$1=$B$16)*($A$2:$I$2=$B$17);1)

Die Aggregat-Funktion als Spaltenindex in den Sverweis eingefügt:
=SVERWEIS(A18;$A$3:$I$13;AGGREGAT(14;6;SPALTE($A$1:$I$1)*($A$1:$I$1=$B$16)*($A$2:$I$2=$B$17);1))

Damit scheint es zu klappen.
Ich hoffe das mit der Aggregat-Funktion ist nicht zu kompliziert gedacht von mir.

Vielen Dank!

[steve1da]

Mit Summenprodukt() ginge das so:

Code:

=SUMMENPRODUKT(($A$3:$A$12=A18)*($B$1:$I$1=$B$16)*($B$2:$I$2=$B$17)*($B$3:$I$12))

[WillWissen]

Moin,

Vorschlag mit INDEX/VERGLEICH():

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B
16		Spätschicht
17	Regal	08.03.2022
18	1	210
19	2	174
20	3	195
21	4	170
22	5	218
23	6	152
24	7	154
25	8	240
26	9	156
27	10	183
28	Summe	1852

Zelle	Formel
B18	=INDEX($A$3:$I$12;VERGLEICH($A18;$A$3:$A$12;0);VERGLEICH($B$16&$B$17;$A$1:$I$1&$A$2:$I$2;0))

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg