Super Mario Cups auswerten

[LCohen]

F21: =SUMMENPRODUKT(--($B$5:$N$16=F20);$C$5:$O$16)
F23: =SUMMENPRODUKT(($B$5:$N$16=F20)*(REST(ZEILE($B$5:$N$16);8)=5))
F25: {=MAX(WENN($B$5:$N$16=F20;$C$5:$O$16))}
F27: {=MAX(WENN($B$5:$N$16=F20;$A$5:$M$16))}

Punkte in $A$5:$M$16 mit Strg-H entfernen, damit es Zahlen werden. Diese Zahlen sind trotzdem korrupt; überkopieren! Nicht überschreiben!
Leerzeichen am Namensende bereinigen (mehrfach gefunden!)
Formeln nach rechts ausfüllen

[schauan]

Hallöchen,

das wäre erst mal was für die Tagesauswertung. Allerdings bin ich bei Excel geblieben, ob das bei "ods" funktioniert, weiß ich nicht.
Denn Winner of the Day trägst Du manuell ein? Könnte ja sein, dass sich die Gewinne mal auf mehr als einem gleichmäßig verteilen...
Für die Platzierung in einem Cup hatte ich Dir ja schob deb Formelansatz geschrieben. Bekommst Du die Formeln für das Zusammenrechnen im "Gesamt Ergebnis" alleine hin?

Die "Platzierungen" hab ich übrigens bei mir in den Formeln bei Bedarf  in Zahlen umgewandelt. Machst Du die Einträge als Zahl, braucht man das nicht.

Die Formeln kannst Du in der ersten Auswertungsspalte eintragen und dann nach rechts kopieren.

LCohen hat die Formeln einfacher geschrieben - geht durch die gleichmäßige Verteilung der Matritzen für den Such - und Berechnungsbereich. Musst das auch so beibehalten - nicht irgendwann mal irgendwo in der Matrix eine einzelne Spalte einfügen ...

Arbeitsblatt mit dem Namen '19.03.18'
	A	B	C	D	E	F	G	H	I
20						Lars	Sani	Bastian	Besuch
21	Gesamt Punkte des Abends:					336	283	345	171
22
23	Gewonnene Cups des Abends:					4	1	3	0
24
25	Höchste Punktzahl im Cup:					60	56	60	39
26
27	schlechteste Platzierung des Abends:					4	12	10	13
28
29	Winner of the Day mit gewonnen Cups:					Lars

Zelle	Formel
F21	=SUMMEWENN($B$5:$B$16;F$20;$C$5:$C$16)+SUMMEWENN($F$5:$F$16;F$20;$G$5:$G$16)+SUMMEWENN($J$5:$J$16;F$20;$K$5:$K$16)+SUMMEWENN($N$5:$N$16;F$20;$O$5:$O$16)
F23	=SUMMENPRODUKT(($B$5:$B$16=F$20)*($A$5:$A$16="1."))+SUMMENPRODUKT(($F$5:$F$16=F$20)*($E$5:$E$16="1."))+SUMMENPRODUKT(($J$5:$J$16=F$20)*($I$5:$I$16="1."))+SUMMENPRODUKT(($N$5:$N$16=F$20)*($M$5:$M$16="1."))
F25	{=MAX(KGRÖSSTE(WENN($B$5:$B$16=F$20;$C$5:$C$16);1);KGRÖSSTE(WENN($F$5:$F$16=F$20;$G$5:$G$16);1);KGRÖSSTE(WENN($J$5:$J$16=F$20;$K$5:$K$16);1);KGRÖSSTE(WENN($N$5:$N$16=F$20;$O$5:$O$16);1))}
F27	{=MAX(KGRÖSSTE(WENN($B$5:$B$16=F$20;--(WECHSELN($A$5:$A$16;".";"")));1);KGRÖSSTE(WENN($F$5:$F$16=F$20;--(WECHSELN($E$5:$E$16;".";"")));1);KGRÖSSTE(WENN($J$5:$J$16=F$20;--(WECHSELN($I$5:$I$16;".";"")));1);KGRÖSSTE(WENN($N$5:$N$16=F$20;--(WECHSELN($M$5:$M$16;".";"")));1))}

Achtung, Matrixformel enthalten!

Die geschweiften Klammern{} werden nicht eingegeben.

Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[Ingenieurbüro Seifert]

Guten Morgen und vielen vielen Dank für die Tabelle,

allerdings habe ich Probleme die Formlen F25 und F27 einzufügen......die Tabelle spuckt dann immer "#WERT!" aus.
Wenn ich allerdings Strg + Umschlattaste + Enter drücke werden diese {} um die Formel gelegt, allerdings steht dann in z.B. F25 der Beginn der Formel: {MAX(KGRÖSS........usw.
Was mache ich falsch? :29: :29: :29: :29: :29:

[LCohen]

Du gibst vermutlich mit so dicken Fingern ein, dass Du das = beim Strg-Umsch-Enter "wegflexst".

Noch mal die dringende Ermahnung:

Leerzeichen in den Namen weg! Mit Datenüberprüfung wäre Dir das nicht passiert.
Zahlen für die Ränge säubern. Nur Punkt wegmachen reichte bei mir nicht; ich musste die Zahlen aus einer neuen Spalte drüberkopieren.

[Ingenieurbüro Seifert]

Guten Morgen LCohen,


ich habe Deine Vorschläge befolgt, dennoch geht es mit den letzten beiden Formeln nicht........ :92: :92: :92:

hier mal angehängt:  
  Mario Kart1.ods (Größe: 15,66 KB / Downloads: 2)

[LCohen]

Bei F25 hast Du die {} händisch hingemalt (befolgst Du die Anleitungen, die unter dem "Bamberg" stehen?),

bei F27 fehlt der Abschluß als {} ebenfalls.

Lies und verstehe hier (oben).

[Ingenieurbüro Seifert]

ich habe es hinbekommen.........hatte am Anfang Probleme mit diesen Klammern....aber Versuch macht kluchhhhhhh......

Vielen dank für Eure Hilfe.......... :15: :15: :15: :15: