Summewenns/Summenprodukt mit Text als Kriterium

[Elex]

Hi

Alles mit Bezug auf deine Bsp.Datei in #7.
Im Blatt Rohdaten in E3 die Formel und runterziehen bis E27.

Code:

=LET(D;VERWEIS(2;1/(ISTZAHL(SUCHEN(Kriterien!$A$2:$A$10;B3)));Kriterien!$B$2:$B$10);H;WENN(D="Miete";D&TEXT(TEIL(B3;2;10);" MMMM JJJJ");WENN(LINKS(D;3)="Neb";D&TEXT(TEIL(B3;2;10);" JJJJ");D));H)

In O3 die Formel. (nicht runterziehen.)

Code:

=LET(D;EINDEUTIG(FILTER(INDEX(A3:E27;SEQUENZ(ZEILEN(A3:A27));{1.5});LINKS(E3:E27;3)="Mie"));MATRIXERSTELLEN(ZEILEN(D);4;LAMBDA(r;c;WENN(c<3;INDEX(D;r;c);WENN(c=3;SUMMEWENN(E3:E27;INDEX(D;r;2);C3:C27)-SUMMEWENN(E3:E27;INDEX(D;r;2);D3:D27);"")))))

In T3 die Formel. (nicht runterziehen.)

Code:

=LET(D;EINDEUTIG(FILTER(INDEX(A3:E27;SEQUENZ(ZEILEN(A3:A27));{1.5});LINKS(E3:E27;3)="Neb"));MATRIXERSTELLEN(ZEILEN(D);4;LAMBDA(r;c;WENN(c<3;INDEX(D;r;c);WENN(c=3;MAX(0;SUMMEWENN(E3:E27;INDEX(D;r;2);C3:C27)-SUMMEWENN(E3:E27;INDEX(D;r;2);D3:D27));MAX(0;SUMMEWENN(E3:E27;INDEX(D;r;2);D3:D27)-SUMMEWENN(E3:E27;INDEX(D;r;2);C3:C27)))))))

In Y3 die Formel. (nicht runterziehen.)

Code:

=FILTER(INDEX(A3:E27;SEQUENZ(ZEILEN(A3:A27));{1.5.3.4});E3:E27="Zahlungseingang")

In G3 die Formel. (nicht runterziehen.)

Code:

=SORTIEREN(VSTAPELN(O3#;T3#;Y3#);1)

Testen und dann sieht man weiter.
Eine Lösung mit Powerquery wäre hier auch Sinnvoll.

Gruß Elex

[Johannes792]

Danke für die Antwort. Versuche ich heute gleich einmal in ein paar ruhigen Stunden.
Mit Powerquery kenne ich mich gar nicht aus, werde mich heute aber mal einlesen, vielleicht bietet dass auch zukünftige Lösungen :) 

Vielen Dank nochmal

[Johannes792]

Guten Morgen,

also es funktioniert bei mir zu Hause sehr gut. Jedoch kann ich es derzeit nicht auf Arbeit anwenden, da wir dort noch Excel 2016 haben und mir dort die LAMBDA und VSTAPELN- Formeln fehlen.
Ich wollte aber nochmal die Formel auseinander nehmen weil ich eventuell noch eine Rückfrage hätte.

Ich wollte nämlich den Rohdaten was hinzufügen, habe die Formel für T3 entsprechend angepasst, jedoch einen Fehler bekommen.

Wenn es sich nicht lösen lässt, würde ich mich melden

[Elex]

Hi

für ältere Excel oder mit PQ.