Summenprodukt-summewenns

[Stefan_M]

Hallo zusammen, 

ich möchte Summen bilden nach mehreren Kriterien. Nur in zwei Spalten sind je zwei Kriterien. Summewenns fällt somit raus (glaube ich).

Beim Summenprodukt komme ich nicht weiter. 

Spalte H hat die Summen. 

 Kriterien.
>250.000

Spalte J.
Kriterien: In Bearbeitung und Offen

Spalte K
Kriterien: In und Best

wie könnte die Formel aussehen? 

Viele Grüße 
Stefan

[steve1da]

Hola,

Code:

=SUMMENPRODUKT((H2:H9)*(H2:H9>250000)*((J2:J9="in bearbeitung")+(J2:J9="offen"))*((K2:K9="in")+(K2:K9="best")))

Gruß,
steve1da

[Stefan_M]

super. danke! Das hat perfekt geklappt. 

Jetzt möchte ich noch zwischen 5000€ und 20.000€ das erste Kriterium erweitern. 
Wie mache ich das?

[steve1da]

Code:

=SUMMENPRODUKT((H2:H9)*(H2:H9>=5000)*(H2:H9<=20000)*((J2:J9="in bearbeitung")+(J2:J9="offen"))*((K2:K9="in")+(K2:K9="best")))

[Stefan_M]

danke ;)

---

super. danke! Das hat perfekt geklappt. 

Jetzt möchte ich noch zwischen 5000€ und 20.000€ das erste Kriterium erweitern. 
Wie mache ich das?

Code:

=SUMMENPRODUKT((H2:H9)*(H2:H9>=5000)*(H2:H9<=20000)*((J2:J9="in bearbeitung")+(J2:J9="offen"))*((K2:K9="in")+(K2:K9="best")))

danke. Das klappt alles super. Nur jetzt soll ich auch noch die Anzahl anzeigen. Also wie viel es sind zwischen 5.000 - 20.000€

[slowboarder]

Hi
Summewenns ist nicht unbedingt raus, wird aber etwas komplizierter

=SUMMENPRODUKT(SUMMEWENNS($H$2:$H$6;$H$2:$H$6;">250000";$J$2:$J$6;{"in bearbeitung";"in bearbeitung";"offen";"offen"};$K$2:$K$6;{"in";"best";"in";"best"}))

bzw für die zweite Anforderung:

=SUMMENPRODUKT(SUMMEWENNS($H$2:$H$6;$H$2:$H$6;">=5000";$H$2:$H$6;"<=20000" ;$J$2:$J$6;{"in bearbeitung";"in bearbeitung";"offen";"offen"};$K$2:$K$6;{"in";"best";"in";"best"}))



wenn du die Anzahl benötigst, nimm Zählenwenns oder in der Lösung von Steve, lass einfach das  (H2:H9)*  weg.

Gruß Daniel

[Jockel]

Hallo zusammen, 

ich möchte Summen bilden nach mehreren Kriterien. 

Kennst du DBSUMME()?

[BoskoBiati]

Hi,

zur ersten Frage, da sollte eigentlich auch das reichen:

Code:

=SUMME(SUMMEWENNS(H2:H7;J2:J7;{"in*";"Off*"};K2:K7;{"in*"."Best*"}))

zur zweiten Frage, gleiches Prozedere:

Code:

=SUMME(SUMMEWENNS($H$2:$H$6;$H$2:$H$6;">=5000";$H$2:$H$6;"<=20000";$J$2:$J$6;{"in*";"Off*"};$K$2:$K$6;{"in*"."Best*"}))

[slowboarder]

Hi Edgar
ob es reicht, kommt darauf an.
Excel durchläuft eine Matrix immer nur in einer einfachen Schleife und macht keine Kombinatorik.
deine Variante würde eine Zeile, in der in Spalte J "in*" steht und in Spalte K "Best*" nicht summieren sondern nur die Kombiationen "in*"-"in*" und "Off*"-"Best*", aber nicht "in*"-"Best*" und "Off*"-"in*"

und das wäre dann nicht der beschriebene Summenproduktfaktor
((J2:J9="in bearbeitung")+(J2:J9="offen"))*((K2:K9="in")+(K2:K9="best"))
sondern dieser:
(J2:J9="in bearbeitung")*(K2:K9="in")+(J2:J9="offen")*(K2:K9="best")


und ob am Anfang jetzt "Summe" oder "Summenprodukt" steht, ist eine Versionsfrage.
Ab Excel 2022 reicht "Summe", davor "Summenprodukt" oder "Summe"+Matrixformelabschluss.

Gruß Daniel

[BoskoBiati]

HalloDaniel,

deine Variante würde eine Zeile, in der in Spalte J "in*" steht und in Spalte K "Best*" nicht summieren sondern nur die Kombiationen "in*"-"in*" und "Off*"-"Best*", aber nicht "in*"-"Best*" und "Off*"-"in*

Kannst Du das beweisen? Ich glaube Dir da nicht!