Summe wenn Tag und Monat ohne Jahr zu erfassen

[gitmichi]

Hallo,

ich möchte gern aus einer Tabelle mit Datumswerten, hinter denen jeweils Zahlen stehen, die Summe errechnen die sich ergibt, wenn man alle Zahlen summiert und zählt die z.B am 02.01. eines jeden Jahres entstanden sind.
Ich habe in Spalte D Datumswerte untereinander aufgereit, die sollen eingentlich ohne das Jahr sein. Hab ich ausgebelendet.

So wie ich es reingeschrieben habe, soll hinter jedem Tag und Monat die Summe und daneben die Anzahl der Werte stehen, die in der benachbarten Tabelle drin stehen. 

Geht das mit Formel zu machen, mit Monat wäre es ja kein Problem aber für jeden Tag des Jahres, weiß ich nicht ob das geht??

Danke Euch

[steve1da]

Hola,

Code:

=SUMMENPRODUKT((TEXT($I$11:$I$22;"TTMM")=TEXT(D11;"TTMM"))*($J$11:$J$22))

und

Code:

=SUMMENPRODUKT((TEXT($I$11:$I$22;"TTMM")=TEXT(D11;"TTMM"))*1)

Gruß,
steve1da

[maninweb]

Hallo,

zum Beispiel wie folgt ...

Code:

E12=SUMME(FILTER($J$11:$J$22;(MONAT($I$11:$I$22)=MONAT(D12))*(TAG($I$11:$I$22)=TAG(D12));0))
F12=WENN(E12>0;ZEILEN(FILTER($J$11:$J$22;(MONAT($I$11:$I$22)=MONAT(D12))*(TAG($I$11:$I$22)=TAG(D12));0));0)

Gruß

[EA1950]

Hallo,

nur in Zelle E11 folgende Formel eingeben/kopieren:

PHP-Code:

=LET(
    tm; TEXT($D.:.$D; "TTMM");
    zl; $J.:.$J;
    dt; $I.:.$I;
    s; MAP(tm; LAMBDA(d; SUMME(FILTER(zl; d = TEXT(dt; "TTMM"); 0))));
    a; MAP(tm; LAMBDA(d; SUMME(FILTER((zl <> 0) * 1; d = TEXT(dt; "TTMM"); 0))));
    HSTAPELN(s; a)
)


[slowboarder]

Hi

das geht am einfachsten mit einer Hilfsspalte
in dieser lässt du dir das Datum als Text ausgeben mit der Funktion =Text(D1;"TT.MM.JJJJ")

dann kannst du SummeWenn verwenden:

=SummeWenns(WerteSpalte;Hilfsspalte;"02.01.*")

wenn du die Summe über jeden Januar bilden willst:

=SummeWenns(Wertespalte;Hilfsspalte;"??.01.????")

Gruß Daniel

[ws-53]

F12=WENN(E12>0;ZEILEN(FILTER($J$11:$J$22;(MONAT($I$11:$I$22)=MONAT(D12))*(TAG($I$11:$I$22)=TAG(D12));0));0)

Das geht mit ANZAHL ohne WENN:

=ANZAHL(FILTER($J$11:$J$22;(MONAT($I$11:$I$22)=MONAT(D12))*(TAG($I$11:$I$22)=TAG(D12))))

[RPP63]

Moin!
Viel einfacher wäre es doch mit einer Pivot.
• Hilfsspalte TextDat mit TEXT(Datum;"TT.MM.")
• Pivot: TextDat in Zeilen, Wert in Werte (Summe), Wert in Werte (Anzahl)

Gruß Ralf

[RPP63]

Pivot geht ja mittlerweile auch mit Formeln.
Ist aber etwas von hinten durch die Brust ins Auge, weil PIVOTMIT() nicht mit mehreren Aggregationen (hier Summe und Anzahl) zurechtkommt.
=LET(
    pv_1; PIVOTMIT(H.:.H; ; J.:.J; SUMME; ; 1);
    pv_2; PIVOTMIT(H.:.H; ; J.:.J; ANZAHL; ; 1);
    Data; HSTAPELN(pv_1; SPALTENWAHL(pv_2; 2));
    VSTAPELN({"Datum". "Summe". "Anzahl"}; Data)
)

	H	I	J	O	P	Q	R
10	TextDat	Datum	Wert		Datum	Summe	Anzahl
11	02.01.	02.01.2012	80		02.01.	90	2
12	05.01.	05.01.2023	25		05.01.	48	2
13	02.01.	02.01.2014	10		07.01.	15	1
14	11.01.	11.01.2015	2		11.01.	2	1
15	18.01.	18.01.2012	2		18.01.	2	1
16	07.01.	07.01.2023	15		Gesamt	157	7
17	05.01.	05.01.2012	23

Zelle	Formel
P10	=LET(pv_1;PIVOTMIT(H.:.H;;J.:.J;SUMME;;1); pv_2;PIVOTMIT(H.:.H;;J.:.J;ANZAHL;;1); Data;HSTAPELN(pv_1;SPALTENWAHL(pv_2;2)); VSTAPELN({"Datum"."Summe"."Anzahl"};Data))

[EA1950]

Hallo @Ralf,

..., weil PIVOTMIT() nicht mit mehreren Aggregationen (hier Summe und Anzahl) zurechtkommt.

=PIVOTMIT($I.:.$I; ; $J.:.$J; VSTAPELN(HSTAPELN(SUMME;ANZAHL2);{"Summen"."Anzahlen"});3; 1;;;;$I.:.$I<>"")
bzw.
=GRUPPIERENNACH($I.:.$I; $J.:.$J; VSTAPELN(HSTAPELN(SUMME;ANZAHL2);{"Summen"."Anzahlen"});3; 1;;$I.:.$I<>"")

Beide Funktionen haben Eigenschaften, die offensichtlich aktuell von Microsoft noch nicht dokumentiert wurden, wie man folgenden Videos entnehmen kann:
Excel's GROUPBY Function Has Hidden Features That Nobody Knows
The Excel team kept this SECRET... GROUPBY does more than we think!

[RPP63]

Sehr interessant!
Das mit den benutzerdefinierten Überschriften mittels Vektor in {} werde ich mal im Hinterkopf behalten.

Sehr viel wichtiger empfinde ich das mehrfache unterschiedliche Aggregieren der gleichen Werte (was dem "Werte zusammenfassen nach" in einer Pivot entspricht).

Als bewusst einfaches Beispiel, welches ich mir definitiv merken werde:

	A	B	C	D	E	F
1	Name	Wert			SUMME	ANZAHL
2	D	12		A	15	1
3	C	11		B	23	2
4	A	15		C	69	5
5	C	19		D	25	2
6	C	10		Gesamt	132	10
7	B	13
8	D	13
9	C	15
10	C	14
11	B	10

Zelle	Formel
D1	=PIVOTMIT(A:.A;;B:.B;HSTAPELN(SUMME;ANZAHL);1)

Ich hatte im Vorfeld zwar mit dem horizontalen Vektor der ETA-Lambdas mittels {SUMME.ANZAHL} experimentiert, aber dies klappt offensichtlich nur mittels HSTAPELN(SUMME;ANZAHL)

Ich finde Deinen Hinweis so wertvoll, dass er einen Platz im Beispielbereich verdient!
Magst Du?

Gruß Ralf