Registriert seit: 10.04.2014
Version(en): 2016 + 365
18.12.2014, 16:31
(Dieser Beitrag wurde zuletzt bearbeitet: 18.12.2014, 16:32 von Rabe.)
Hallo,
wie kann ich die Werte aus D in Spalte I summieren? Ich krieg's nicht hin. Ich habe es mit zwei Formeln versucht und mit SummeWennS kann ich die Formel nicht mal abschließen.
Daten | C | D | E | F | G | H | I |
3 | 02.01.2015 | 400 | 200 | 600 | | Jan 15 | 0 |
4 | 05.01.2015 | 164 | 14 | 178 | 3 | | #WERT! |
5 | 07.01.2015 | 154 | 41 | 195 | 3 | | |
6 | 08.01.2015 | | | 0 | | | |
7 | 09.01.2015 | 169 | 30 | 199 | 4 | | |
8 | 12.01.2015 | 236 | 69 | 305 | 4 | | |
9 | 13.01.2015 | 177 | 60 | 237 | 4 | | |
10 | 14.01.2015 | 211 | 98 | 309 | 3 | | |
11 | 15.01.2015 | 188 | 16 | 204 | 4 | | |
12 | 16.01.2015 | 56 | 35 | 91 | 3 | | |
13 | 19.01.2015 | 201 | 28 | 229 | 2 | | |
14 | 20.01.2015 | 99 | 70 | 169 | 3 | | |
15 | 21.01.2015 | 133 | 47 | 180 | 3 | | |
16 | 22.01.2015 | 103 | 25 | 128 | 4 | | |
17 | 23.01.2015 | 43 | 33 | 76 | 3 | | |
18 | 26.01.2015 | 121 | 13 | 134 | 3 | | |
19 | 27.01.2015 | 82 | 72 | 154 | 3 | | |
20 | 28.01.2015 | 120 | 49 | 169 | 3 | | |
21 | 29.01.2015 | 113 | 32 | 145 | 4 | | |
22 | 30.01.2015 | 76 | 21 | 97 | 3 | | |
23 | 02.02.2015 | 110 | 25 | 135 | 3 | | |
24 | 03.02.2015 | 119 | 28 | 147 | 3 | | |
25 | 04.02.2015 | 95 | 12 | 107 | 2 | Feb 15 | 2389 |
26 | 05.02.2015 | 46 | 48 | 94 | 2 | | |
verwendete Formeln | |
Zelle | Formel | Bereich | N/A |
I3 | =SUMMEWENN(D: D;MONAT(C:C)=MONAT($H$3);D: D) | | |
I4 | =SUMMENPRODUKT((MONAT(C:C)=MONAT(H3));D: D) | | |
H3,H25 | =C3 | | |
I25 | =SUMME(D25: D44) | | |
C3:C26 | =ARBEITSTAG(DATUM($A$1;1;1)-1;ZEILE(A1);Feiertage!$B$59:$B$87) | | |
F3:F26 | =D3+E3 | | |
Excel-Inn.de |
Hajo-Excel.de |
XHTML-Tabelle zur Darstellung in Foren, einschl. der neuen Funktionen ab Version 2007 |
Add-In-Version 18.19 einschl. 64 Bit |
Registriert seit: 12.04.2014
Version(en): Office 365
18.12.2014, 16:45
(Dieser Beitrag wurde zuletzt bearbeitet: 18.12.2014, 16:46 von Peter.)
Hallo,
ich würde hier eine Pivottabelle nehmen, aber alternativ sollte auch diese Summenproduktformel funktionieren:
=SUMMENPRODUKT((MONAT(C3:C26)=MONAT(H3))*(D3:D26))
wobei ich hier davon ausgehe, dass wir nur Werte aus dem Kalenderjahr 2015 in der Tabelle haben.
Gruß
Peter
Registriert seit: 04.11.2014
Version(en): Office 365 Beta
Hi Ralf,
=SUMMENPRODUKT(N(MONAT(C1:C100)=MONAT(H3));D1:D100)
Registriert seit: 10.04.2014
Version(en): Office 2019
Hallo Ralf, oder
=SUMMENPRODUKT((TEXT(C3:C100;"MJJ")=TEXT(H3;"MJJ"))*1;D3:D100)
oder
=SUMMENPRODUKT((TEXT(C3:C100;"M")=TEXT(H3;"M"))*1;D3:D100)
Gruß Jörg
stolzes Mitglied im ----Excel-Verein
Im Wort FEHLER steckt auch das Wort HELFER!
FEHLER helfen dir.
Nimm deine FEHLER an und lerne aus ihnen.
Wenn du es zulässt, dann werden sie dich stärken
Im Wort
Registriert seit: 13.04.2014
Version(en): 365
18.12.2014, 17:20
(Dieser Beitrag wurde zuletzt bearbeitet: 18.12.2014, 17:25 von BoskoBiati.)
Hallo,
SUMMEWENNS wäre auch möglich:
Code:
=SUMMEWENNS(D:D;C:C;">"&H3-TAG(H3);C:C;"<="&MONATSENDE(H3;0))
Arbeitsblatt mit dem Namen 'Tabelle1' |
| C | D | E | F | G | H | I | J | K |
2 | 2015 | | | | | | | | |
3 | 02.01.2015 | 400 | 200 | 600 | | Jan 15 | 2846 | | 01.01.2015 |
4 | 05.01.2015 | 164 | 14 | 178 | 3 | | | | 06.01.2015 |
5 | 07.01.2015 | 154 | 41 | 195 | 3 | | | | |
6 | 08.01.2015 | | | 0 | | | | | |
Zelle | Format | Wert |
C2 | JJJJ | 01.01.2015 |
Name | Bezug |
FT | =Tabelle1!$K$3:$K$4 |
Zelle | Formel |
C3 | =ARBEITSTAG(C2;1;FT) |
I3 | =SUMMEWENNS(D:D;C:C;">"&H3-TAG(H3);C:C;"<="&MONATSENDE(H3;0)) |
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
Gruß
Edgar
Meine Antworten sind freiwillig und ohne Gewähr!
Über Rückmeldungen würde ich mich freuen.