Summe jeweils wenn in Zelle nebenan ein X steht

[Mamamia]

Hallo Liebes Forum,

Ich bin mir sicher sehr einfach aber irgendwie will das bei mir so gar nicht funktionieren und suche viel zuweit.

In Spalte E stehen Tage welche addiert werden sollen bis und mit dem 1.x. danach summiere alle zahlen wieder 1 unterhalb x bis zum nächsten X oder bis zum Schluss ( MOnat 12)

 X gibt mir jeweils an dass hier ein Wechsel stattfindet.

Ich komme auf keinen grünen Zweig.

Wer kann mir helfen? Ich danke UEch jetzt schon 

Liebe Grüsse Mamamia

[slowboarder]

Hi

in Zelle H5 diese Formel:

=WENN(ODER(F5="x";E6="");SUMME(E$5:E5)-SUMME(H$4:H4);"")

ziehe dann Formel bis H16.

Gruß Daniel

[Egon12]

Hallo Mamamia,

du nutzt O365. Da kann man das spillend machen:

LET():

Code:

=LET(
    xA; Tbl[Anzahl Tage];
    xB; Tbl[Wechsel];
    xC; ZEILEN(xA);
    MAP(SEQUENZ(xC);LAMBDA(i;LET(xD; MAX(WENN((SEQUENZ(i-1)>=1)*(INDEX(xB;SEQUENZ(i-1))="x"); SEQUENZ(i-1); 0));xE; WENN(xD=0; 1; xD+1);xF;SUMME(INDEX(xA; SEQUENZ(i-xE+1;1;xE)));WENN(ODER(INDEX(xB;i)="x"; i=xC); xF; "")))))

oder als LAMBDA() im Namensmanager:

Name: ZwischenSummenX
Formel:

Code:

=LAMBDA(AnzTage;Wechsel;LET(xA;ZEILEN(AnzTage);MAP(SEQUENZ(xA);LAMBDA(i;LET(xB;MAX(WENN((SEQUENZ(i-1)>=1)*(INDEX(Wechsel;SEQUENZ(i-1))="x"); SEQUENZ(i-1); 0));xC; WENN(xB=0; 1; xB+1);xD;SUMME(INDEX(AnzTage; SEQUENZ(i-xC+1;1;xC)));WENN(ODER(INDEX(Wechsel;i)="x"; i=xA); xD;""))))))

Aufruf: =ZwischenSummenX(Tbl[Anzahl Tage];Tbl[Wechsel])

  Zweichensummen via X.xlsx (Größe: 11,87 KB / Downloads: 6)

Gruß Uwe

[EA1950]

Hallo,

oder auch folgende Formel in Zelle I5 (mit dynamischem Resultatbereich I5:I16 im Beispiel):

PHP-Code:

=LET(
    tg; Tbl[Anzahl_Tage];
    tw; Tbl[Wechsel];
    kz; "X";
    tgs; SCAN(
        0;
        SEQUENZ(ZEILEN(tg));
        LAMBDA(akk; i;
            LET(
                tgi; INDEX(tg; i);
                twiv; WENN(i = 1; kz; INDEX(tw; i - 1));
                (twiv <> kz) * akk + tgi
            )
        )
    );
    WENN(VSTAPELN(WEGLASSEN(tw; -1); kz) = kz; tgs; "")
)


[slowboarder]

Hi

in Zelle H5 diese Formel:

=WENN(ODER(F5="x";E6="");SUMME(E$5:E5)-SUMME(H$4:H4);"")

ziehe dann Formel bis H16.

Gruß Daniel

Hi
prinzipiell kannst du diese Formel auch als neue Spalte zur intelligenten Tabelle hinzufügen.
dann wird sie,  ähnlich wie beim Autospill auch, in der Tabelle automatisch bis zur letzten Zeile ausgefüllt.

Gruß Daniel

[Mamamia]

Vielen Dank IHr Lieben FÜR Eure tolle Hilfe,


Nun habe ich ein Überlegungsfehler begangen.
Ich muss eigentlich genau vor das erste x die Summe aller Zahlen wissen und dann ab x bis zum nächsten x oder bis zum Schluss.

Wenn aber nichts mehr drin steht da der Mitarbeiter bereits ausgetreten ist dann soll er nur bis zum letzten Eintrag zählen.

[slowboarder]

Hi
naja, nicht so schwer
einfach die Zelle anpassen, die schaut wo das x steht.

hier wieder die Formel für Zelle H5 deiner Beispieldatei, jetzt wird die Summe in der Zeile oberhalb des X gebildet:
die Änderung in rot:

=WENN(ODER(F6="x";E6="");SUMME(E$5:E5)-SUMME(H$4:H4);"")

wie gesagt, wenn du diese Formel als Teil der intelligenten Tabelle eingibst, wird sie auch automatisch nach unten ausgefüllt.

Gruß Daniel

[Mamamia]

Vielen Dank für die rasche Hilfe,

Nun habe ich das Ganze auch verstanden, und es ist genau das was ich gesucht habe.
Habe mich für die einfache Formel von slowboarder entschieden.

Ich wünsche Euch eine sonnige Restwoche.

Liebe Grüsse

Mammamia

[Rudi'S]

Hallo Mamamia

du wirst bestimmt beim Üben feststellen, dass das Ganze doch noch nicht so deinen Ansprüchen gerecht wird.
Wenn du den kleinen Fehler noch nicht gefunden haben solltest, In der Formel ist noch eine weitere Änderung notwendig:

Ich bin zwar sicher dass du das schon bemerkt hast, aber für alle Fälle .......

=WENN(ODER(F6="x";E6="");SUMME(E$5:E5)-SUMME(H$4:H5);"")

Oder zum Ende hin ganz genau mit dieser Formel
=WENN(UND(E6="";F6="";F5="");SUMME(E$4:E5)-SUMME(H$4:H4);WENN(ODER(F5="x";E6="");SUMME(E$4:E4)-SUMME(H$4:H4);WENN(UND(E6="";F6="");SUMME(E$4:E5)-SUMME(H$4:H4);"")))

Gruß Rudi'S

[slowboarder]

HI Rudi
wo siehst du da den Fehler?
hast du das getestet?
für welche Zelle ist deine Formel?
Gruß Daniel