Stöbern im Palettenkonto

[soddel]

Moin ihr Lieben.

Ich habe mich mit meinen bescheidenen Kenntnissen an der Gestaltung eines Palettenkontos gewagt.

Aufbau, siehe Tabelle.

Da wir im Laufe des Jahres bei max. 4 Kunden gut 1.000 Buchungen haben, tauchen schon mal Fragen zu den einzelnen Buchungen auf.
Nun würde ich gerne die angefragte Buchung über eine SUCHMASKE finden wollen.
Suchkriterium kann DATUM oder PAL-SCHEINNR. sein.

Es wäre sehr nett, wenn ihr mir da helfend zur Seite stehend würdet :05:


Bleibt gesund

[WillWissen]

Hi Peter,

genügt dir so etwas?

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G	H	I	J
8	Datum	Kunde	PAL-Scheinnr.	Bemerkungen	Anzahl	Anzahl	Rest		Buchungen	6
9	02.02.2020	Kunde 1	12345	Bemerkung 1	6	9	3
10	12.02.2020	Kunde 1	12346	Bemerkung 2	4	3	-1
11	22.02.2020	Kunde 2	25873	Bemerkung 3	6	8	2		Palettensch.	25873
12	02.03.2020	Kunde 3	26897	Bemerkung 4	12	19	7		Datum	22.02.2020
13	04.03.2020	Kunde 3	23898	Bemerkung 5	36	32	-4		Kunde	Kunde 2
14	11.03.2020	Kunde 3	23899	Bemerkung 6	25	12	-13		Bemerkung	Bemerkung 3
15									Buchungssatz	Zeile: 11
16

Zelle	Formel
J12	=INDEX(A:A;VERGLEICH($J$11;$C$1:$C$1000;0))
J13	=INDEX(B:B;VERGLEICH($J$11;$C$1:$C$1000;0))
J14	=SVERWEIS($J$11;$C$1:$D$1000;2;0)
J15	="Zeile: "& VERGLEICH($J$11;$C$1:$C$1000;0)

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

Eingabe ist ausschließlich die Palettenschein-Nummer.

[soddel]

Hi Günter.

Vielen Dank für Deine großartige Hilfe, bin schonmal einen Riesenschritt weiter!


Über beide Abfragemöglichkeiten geht dann wohl nur über VBA?

Aber ich glaube, ich kann mit diesem Ergebnis auch leben...


Bleib gesund

[WillWissen]

Hi Peter,

die Abfrage über das Datum habe ich deshalb nicht in Erwägung gezogen, weil ich davon ausgehe, dass es öfters vorkommen kann, während die Palettenscheinnummer wohl einmalig sein dürfte.

[soddel]

Hi Günter.

Grundsätzlich hast Du natürlich Recht!
Gelebte Praxis: Chef fragt irgendwann, was denn am xx.xx.xxxx gebucht wurde - es kommen mehrere Scheine pro Tag-

Da die Palettenscheine nach Eingang gebucht werden, kann es schon mal sein, dass diese nicht chronologisch gebucht werden
Jetzt macht die Abfrage nach DATUM Sinn!

[WillWissen]

Hi Peter,

damit du deinen Chef glücklich machen kannst :

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G	H	I	J
8	Datum	Kunde	PAL-Scheinnr.	Bemerkungen	Anzahl	Anzahl	Rest		Buchungen	7
9	02.02.2020	Kunde 1	12345	Bemerkung 1	6	9	3
10	12.02.2020	Kunde 1	12346	Bemerkung 2	4	3	-1
11	22.02.2020	Kunde 2	25873	Bemerkung 3	6	8	2		Palettensch.	25873
12	02.03.2020	Kunde 3	26897	Bemerkung 4	12	19	7		Datum	22.02.2020
13	04.03.2020	Kunde 3	23898	Bemerkung 5	36	32	-4		Kunde	Kunde 2
14	11.03.2020	Kunde 3	23899	Bemerkung 6	25	12	-13		Bemerkung	Bemerkung 3
15	22.02.2020	Kunde 4	12345	Bemerkung 7	12	10	-2		Buchungssatz	Zeile: 11
16
17									Abfrage nach Datum
18									22.02.2020
19										25873
20										12345
21
22

Zelle	Formel
J19	=WENNFEHLER(INDEX(C:C;AGGREGAT(15;6;ZEILE($C$9:$C$100)/($A$9:$A$100=$I$18);ZEILE(A1)));"")

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

Die Formel ziehst du soweit wie nötig herunter. Es werden alle Palettenscheinnummern vom gesuchten Datum angezeigt. Danach kannst du den Rest - wie oben beschrieben - auslesen.

[soddel]

herzlichen Dank, werde es morgen einbauen aber Du hast mich und meinen Chef sicherlich sehr glücklich gemacht

[soddel]

Hi Günter.

Es funktioniert absolut so, wie ich es wollte.
Nochmals herzlichen Dank für Deine Hilfe.

Nun würde ich gerne noch ein Schmankerl mit einbauen:

Um bei Deinem Beispiel zu bleiben

Palettensch.: 25873
Datum: 22.02.2020
Kunde: Kunde 2
Bemerkung: Bemerkung 2
Buchungssatz: Zeile 14
Anzahl: ? (L7)   =WENNFEHLER(SVERWEIS($L$2;$C$9:$E$1107;2;0);"")
Anzahl: ? (L8)   =WENNFEHLER(SVERWEIS($L$2;$C$9:$F$1107;2;0);"")

Mit den hier aufgezeigten Formeln kommt leider nur Quark heraus.

Kannst Du bitte nochmal rübergucken.

[WillWissen]

Moin,

so?

Arbeitsblatt mit dem Namen 'Tabelle1'
	I	J	K	L
10
11	Palettensch.	25873
12	Datum
13	Kunde	Kunde 2
14	Bemerkung	Bemerkung3
15	Buchungssatz	Zeile: 11
16
17
18	22.02.2020	Pal.-Schein	Anz. Sp. E	Anz. Sp. F
19		25873	6	8
20		23456	12	10
21
22

Zelle	Formel
J13	=INDEX(B:B;VERGLEICH($J$11;$C$1:$C$1000;0))
J14	=SVERWEIS($J$11;$C$1:$D$1000;2;0)
J15	="Zeile: "& VERGLEICH($J$11;$C$1:$C$1000;0)
J19	=WENNFEHLER(INDEX(C:C;AGGREGAT(15;6;ZEILE($C$9:$C$100)/($A$9:$A$100=$I$18);ZEILE(A1)));"")
K19	=SVERWEIS(J19;$C$9:$F$1000;3;0)
L19	=SVERWEIS(J19;$C$9:$F$1000;4;0)
J20	=WENNFEHLER(INDEX(C:C;AGGREGAT(15;6;ZEILE($C$9:$C$100)/($A$9:$A$100=$I$18);ZEILE(A2)));"")
K20	=SVERWEIS(J20;$C$9:$F$1000;3;0)
L20	=SVERWEIS(J20;$C$9:$F$1000;4;0)
J21	=WENNFEHLER(INDEX(C:C;AGGREGAT(15;6;ZEILE($C$9:$C$100)/($A$9:$A$100=$I$18);ZEILE(A3)));"")
J22	=WENNFEHLER(INDEX(C:C;AGGREGAT(15;6;ZEILE($C$9:$C$100)/($A$9:$A$100=$I$18);ZEILE(A4)));"")

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[soddel]

absolut perfekt und so wie ich es wollte.

:18:

Auf Grund Deiner Formel weiß ich nun auch, wo mein Denkfehler war.

Vielen Dank und schönen Restsonntag



Bleib gesund