Sprachproblem bei Formel?

[Hofer197]

Hallo liebes Forum!

Ich habe folgende Formel aus einer englischen Excel File, leider wird der Wert in AI23 falsch berechnet, es sollte hier 14,87 stehen. Kann es sein, dass es sich hierbei um ein Sprachproblem der Formel handelt? Wenn nicht, kann mir sonst bitte jemand helfen?

Vielen lieben Dank für die Hilfe im Voraus!

DANKE!

Liebe Grüße!

=LET(
b;$P$7:P7;
q;$AG$7:AG7;
p;$AH$7:AH7;
idx;SEQUENZ(ZEILEN(b));
lastSell;WENNFEHLER(XVERGLEICH("VERKAUF";_xlfn.DROP(b;-1);0;-1);0);

avgBuy;WENNFEHLER(
  SUMMENPRODUKT(FILTER(q;(b="KAUF")*(q<>"")*(idx>lastSell));
              FILTER(p;(b="KAUF")*(q<>"")*(idx>lastSell)))
  /SUMME(FILTER(q;(b="KAUF")*(q<>"")*(idx>lastSell)));0);

lastBuy;WENNFEHLER(XVERWEIS(1;(b="KAUF")*(q<>"");p;0;0;-1);0);

WENN(avgBuy=0; lastBuy; avgBuy)
)

[BoskoBiati]

Hallo,

einfach mal die Hilfe von Excel bemühen:

https://support.microsoft.com/de-de/offi...bb77fd5025

Die Funktion Drop gibt es in Deiner Version nicht:

WEGLASSEN-Funktion
Gilt für
Excel für Microsoft 365 Excel für Microsoft 365 für Mac Excel für das Web

[Egon12]

Hallo,

du brauchst für diese Formel wenigstens O2024.
Das ist keine englische Formel. WEGLASSEN() gibt es schlicht in O2021 noch nicht.
So müsste es funktionieren:

Code:

=LET(
    b; $P$7:P7;
    q; $AG$7:AG7;
    p; $AH$7:AH7;
    idx; SEQUENZ(ZEILEN(b));
    bOhneLetzte; INDEX(b; SEQUENZ(ZEILEN(b)-1));
    lastSell; WENNFEHLER(XVERGLEICH("VERKAUF"; bOhneLetzte; 0; -1);0);
    avgBuy; WENNFEHLER(SUMMENPRODUKT(FILTER(q; (b="KAUF")*(q<>"")*(idx>lastSell));FILTER(p; (b="KAUF")*(q<>"")*(idx>lastSell)))/ SUMME(FILTER(q; (b="KAUF")*(q<>"")*(idx>lastSell)));0);
    lastBuy; WENNFEHLER(XVERWEIS(1; (b="KAUF")*(q<>""); p; 0; 0; -1);0);
    WENN(avgBuy=0; lastBuy; avgBuy)
)

Gruß Uwe

[Hofer197]

Hallo ihr!

Vielen Dank für die Info! Ja, das war das Problem. Ich habe nur Office 2021. DANKE! Die Formel passt nun!

DANKE!

GLG

[Egon12]

hier für Interessierte mal noch eine spillende Version ab O2024.

  Hilfe.xlsx (Größe: 14,18 KB / Downloads: 8)

Gruß Uwe

[Egon12]

Hallo,

hier mal noch eine weitere Variante für O2021 aber deutlich effizienter:

Code:

=LET(
    b; $P$7:P8;
    q; $AG$7:AG8;
    p; $AH$7:AH8;
    idx;SEQUENZ(ZEILEN(b));
    lastSell;WENNFEHLER(XVERGLEICH("VERKAUF";b;0;-1);0);
    kaufFilter;(b="KAUF")*(q<>"")*(idx>lastSell);
    qF;WENNFEHLER(FILTER(q;kaufFilter);0);
    pF;WENNFEHLER(FILTER(p;kaufFilter);0);
    sumQ;SUMME(qF);
    avgBuy;WENN(sumQ=0;0;SUMMENPRODUKT(qF;pF)/sumQ);
    lastBuy;WENNFEHLER(XVERWEIS(1;(b="KAUF")*(q<>"");p;0;0;-1);0);
    WENN(avgBuy=0;lastBuy;avgBuy)
)

Gruß Uwe