Spezielle Formel

[Rainer]

Es ist schon fast eine Herausforderung meine Frage wenigstens einigermaßen verständlich zu formulieren…, daher auch der nicht sonderlich aussagekräftige Titel, den die Moderation jederzeit gerne ändern darf…
 
Ich möchte die Werte in Spalte B summieren, zu denen in Spalte A jeweils die Werte in 5er-Schritten (30-35, 36-40, 41-45 usw.) gehören und durch deren Anzahl dividieren.
 
Beispiel: Spalte A, Anzahl Werte zwischen 41 und 45 = 4. Die Summe der jeweils dazugehörigen Werte in Spalte B ist 7,0+6,9+6,6+6,5=27,0.
 
Rechnung: 27 / 4 = 6,75
 
Lässt sich so etwas direkt in eine Formel “gießen“…?

[Gastlich]

Hallo,

so z. B.

Code:

=WENNFEHLER(SUMMEWENNS(B$1:B$14;A$1:A$14;">="&E1;A$1:A$14;"<="&F1)/ ZÄHLENWENNS(A$1:A$14;">="&E1;A$1:A$14;"<="&F1);"")

In den Zellbereich E1:F3 sind die 5 Schritt Kriterien.

Gruß Gastlich

[{Boris}]

Hi,

aus Spaß (und zu Übungszwecken) noch eine Spill-Variante mit NACHZEILE i.V.m. LAMBDA - bezogen auf die Datei von Gastlich:

=NACHZEILE(E1:F3;LAMBDA(a;LET(x;INDEX(a;1);y;INDEX(a;2);WENNFEHLER(SUMMEWENNS(B1:B14;A1:A14;">="&x;A1:A14;"<="&y)/ZÄHLENWENNS(A1:A14;">="&x;A1:A14;"<="&y);""))))

Auch ohne LAMBDA/NACHZEILE kann man die Formel schön spillen lassen - man muss nur E1 durch E1:E3 und F1 durch F1:F3 ersetzen:

=WENNFEHLER(SUMMEWENNS(B1:B14;A1:A14;">="&E1:E3;A1:A14;"<="&F1:F3)/ ZÄHLENWENNS(A1:A14;">="&E1:E3;A1:A14;"<="&F1:F3);"")

[BoskoBiati]

Hi,

da genügt doch einfach das:

Code:

=WENNFEHLER(MITTELWERTWENNS($B$1:$B$14;$A$1:$A$14;">"&ZEILE(A5)*5;$A$1:$A$14;"<="&ZEILE(A6)*5);"")

geht von 26 bis 30, nach unten ziehen, wird in 5er-Schritten erhöht.

[Cadmus]

In diesem Fall wäre auch eine Auswertung per Pivot möglich.

[Rainer]

Vielen Dank euch allen für eure Ansätze!

Das muss ich alles mal in einer ruhigen Minute testen und versuchen umzusetzen...

[Rainer]

Hallo,

so z. B.

Code:

=WENNFEHLER(SUMMEWENNS(B$1:B$14;A$1:A$14;">="&E1;A$1:A$14;"<="&F1)/ ZÄHLENWENNS(A$1:A$14;">="&E1;A$1:A$14;"<="&F1);"")

In den Zellbereich E1:F3 sind die 5 Schritt Kriterien.

Gruß Gastlich

Ich habe mich jetzt mal mit dieser Lösung beschäftigt, die Formel in meine Hauptdatei (also die eigentliche Datei) übertragen und entsprechend angepasst. Das Problem ist, es wird kein Ergebnis angezeigt, aber auch keine Fehlermeldung...

Ich habe mal in meiner Hauptdatei alles drum herum gelöscht so dass nur noch die relevanten Inhalte übrig sind. Hat jemand eine Idee warum das nicht funktioniert?

[BoskoBiati]

Hallo,

da würde ich doch mal die Formel überprüfen, die enthält einen Fehler!
Trotzdem ist der einfachste Weg dieser:

Code:

=WENNFEHLER(MITTELWERTWENNS(W:W;V:V;">="&X149;V:V;"<="&Y149);"")

[Rainer]

da würde ich doch mal die Formel überprüfen, die enthält einen Fehler!

Verrätst du ihn mir? (Ich habe die Formel sicher 5 Mal geprüft)

[Gastlich]

Hallo,

es wurden 2 Spalten der Kriterien der SUMMEWENNS() Formel verwendet.

WENNFEHLER(SUMMEWENNS(W$37:W$172;V$37:W$172;">="&X149;V$37:V$172;"<="&Y149)/ZÄHLENWENNS(V$37:V$172;">="&X149;V$37:V$172;"<="&Y149);"")

Gastlich