Spaltenbuchstabe ermitteln

[ahpzet]

Hallo Edgar

Danke für Deine kurze Formel im letzten Beitrag um 12:30 Uhr.
Zu Deinem ersten Beitrag zu meiner Frage kann ich nur folgendes sagen. 
Mit welchem EXCEL arbeitest Du? Also so gut wie in allen Formeln steht ein Spaltenbuchste(n) gefolgt mit einer Zahl wenn man den Inhalt einer Zelle für eine weitere Berechnung benötigt. In meinem Fall stehen unter den Datums Preise von denen ich jeweils die aktuellsten benötige und die stehen halt nun mal in der letzten Spalte. Da es sich also um eine immer wieder ändernde Tabelle handelt, muss die Formel für die weitere Auswertung dynamisch sein.
Es gibt immer mehrere Lösungsmöglichkeiten und jeder hat seinen Lösungstil und Deiner scheint also nicht der gleiche zu sein wie meiner und deshalb benötigst du nicht die Spaltenbezeichnung von der letzten belegten Spalte.

Ich hoffe ich habe Deine Frage  kein Mensch braucht den Spaltenbuchstaben. Was willst Du damit erreichen? klären können.

[BoskoBiati]

Hallo,

in Deiner Version kann man den Wert aus der letzten Spalte ganz einfach ermitteln, ohne den Buchstaben zu kennen. Das ging auch schon früher mit VERWEIS.
Hier mal ein Beispiel:


  letzte_Spalte.xlsx (Größe: 9,66 KB / Downloads: 12)

Du siehst, meine Frage hatte schon ihre Berechtigung!

[rate mit]

Hallo,

wenn du deine Formel etwas änderst, dann erhältst du direkt den Spaltenbuchstaben:

Code:

=ZELLE("ADRESSE";INDEX($A:$XFC;7;ANZAHL2(7:7)))

Wenn du nur bis XFC eingibst, dann bleiben die Buchstaben auch....

[ahpzet]

Hallo rate mit


Danke für die korigierte Formel aus dem Internet.

---

Hallo schauan

Der Test Deiner Formel bringt leider nicht den richtigen Spaltenbuchstaben.

---

Hallo an alle Helfer.

Danke an alle die auf meine Anfrage antworteten.

---

Hallo Edgar

Danke für Deine Beispiel Datei. Habe  sie gleich in meinen Beispiele Ordner übernommen

[EA1950]

Hallo,

an alle, die diese Funktion verwenden:

...ANZAHL2(7:7)...

Diese Formel muss zwangsläufig eine falsche Spalte/Spaltenbuchstaben liefern dann, wenn in der Zeile 7 Leerzellen eingebettet sind (Anzahl2(..) zählt die Zellen mit Inhalt). In diesem Fall wird nicht die letzte Spalte mit Inhalt geliefert, sondern eine davor liegende.

[rate mit]

Hallo,

an alle, die diese Funktion verwenden:

...ANZAHL2(7:7)...

Diese Formel muss zwangsläufig eine falsche Spalte/Spaltenbuchstaben liefern dann, wenn in der Zeile 7 Leerzellen eingebettet sind (Anzahl2(..) zählt die Zellen mit Inhalt). In diesem Fall wird nicht die letzte Spalte mit Inhalt geliefert, sondern eine davor liegende.

dann könnte man diese Formel verwenden:

Code:

=ADRESSE(MAX(WENN(A7:XFC7<>"";ZEILE(7:7)));MAX(WENN(A7:XFC7<>"";SPALTE(A:XFC)));4)

Adresse der letzten Zelle im benutzten Bereich

[RPP63]

Moin!
Edgar Formel ist doch kurz, knackig, gut!
(hier erweitert, um nur den/die Spaltenbuchstaben auszugeben)
=TEXTVOR(ADRESSE(1;MAX(SPALTE(7:.7));2);"$")

Arbeitsblatt mit dem Namen 'Tabelle3'
	A	B	C	D	E	F
7	ö	l	p		o
8
9
10
11
12	E
13	E
14	E7

Zelle	Formel
A12	=TEXTVOR(ADRESSE(1;MAX(WENN(7:.7<>"";SPALTE(7:.7)));2);"$")
A13	=TEXTVOR(ADRESSE(1;MAX(SPALTE(7:.7));2);"$")
A14	=ADRESSE(MAX(WENN(A7:XFC7<>"";ZEILE(7:7)));MAX(WENN(A7:XFC7<>"";SPALTE(A:XFC)));4)

Gruß Ralf

[BoskoBiati]

Hallo,

hier mal eine Zusammenfassung aller Formeln die zur Ermittlung der letzten belegten Spalte vorgestellt wurden:

Code:

=WECHSELN(ADRESSE(1;MAX(WENN(7:7<>"";SPALTE(7:7)));4);"1";"")
=TEXTVOR(ADRESSE(1;MAX(FILTER(SPALTE(1:1);1:1<>""));2;1);"$")
=WECHSELN(ADRESSE(1;MAX(SPALTE($7:.$7));4);"1";"")

=ADRESSE(1;MAX(SPALTE(7:.7)))
=WENNFEHLER(LET(zeile;7:7;col;VERWEIS(2;1/(zeile<>"");SPALTE(zeile));adr;ADRESSE(1;col;2;1);f;FINDEN("$";adr;1)-1;t;TEIL(adr;1;f);t);"Keine Daten")
=ADRESSE(MAX(WENN(A7:XFC7<>"";ZEILE(7:7)));MAX(WENN(A7:XFC7<>"";SPALTE(A:XFC)));4)
= WENNFEHLER( LET(xa;ADRESSE(1;VERWEIS(9;1/(1:1<>"");SPALTE(1:1));2);LINKS(xa;SUCHEN("$";xa)-1));"n.v.")

Dabei reicht für den Zweck, für den der TE das braucht, diese Formel:

Code:

=ÜBERNEHMEN(7:.7;;-1)

Die Antwort von Ralf habe ich erst jetzt gesehen, habe erst nach dem Frühstück abgeschickt.

[Elex]

Hey Edgar,

Wo kommt diese 7:.7 Bezugsangabe her, welche sich ja deutlich im Verhalten von der 7:7 unterscheidet.

Gruß Elex

[BoskoBiati]

Hi,

guckst Du:

https://support.microsoft.com/de-de/offi...fa9564f999